view lisp/talk.el @ 51209:880539128b51

Make (many) trivial substitutions for renamed and new macros in dispextern.h, frame.h and window.h. (window_box_width): Adapt to per-window fringes and scroll bars, and new fringe vs. display margin position. Note that returned value is no longer guaranteed to be a whole multiple of the frame column width, since per-window fringes may now be any width. (window_box_left_offset): New function like window_box_left, but value is relative to left border of window (rather than frame). (window_box_right_offset): New function like window_box_right, but value is relative to left border of window. (window_box_left): Adapt to per-window fringes and scroll bars, and new fringe vs. display margin position. Simplify by using WINDOW_LEFT_EDGE_X and window_box_left_offset. (window_box): Allow null args for unnecessary return values; change/simplify relevant callers. (x_y_to_hpos_vpos): Adapt to per-window fringes and scroll bars, and new fringe vs. display margin position. Use window_box_left_offset and window_box_right_offset (get_glyph_string_clip_rect): Adapt to per-window fringes and scroll bars, and new fringe vs. display margin position. Use WINDOW_LEFT_EDGE_X and WINDOW_TOTAL_WIDTH. (draw_fringe_bitmap): Rework to handle per-window fringes and new fringe vs. display margin position. (hscroll_window_tree): Use window_box_width instead of window_box. (redisplay_window): Adapt to per-window scroll bars. (draw_glyphs): Rework to handle per-window fringes and scroll bars, and new fringe vs. display margin position. Use WINDOW_LEFT_EDGE_X, WINDOW_TOTAL_WIDTH, and window_box_left. (x_clear_end_of_line): Adapt to per-window fringes and scroll bars, and new fringe vs. display margin position. Fix bug which increased total width of full_width rows by width of scroll bars although window's total width already includes that. (x_fix_overlapping_area): Simplify using window_box_left_offset. (expose_area): Simplify using window_box_left_offset. (x_draw_vertical_border): Handle per-window scroll bar settings, mixing windows with left, right and no scroll bars.

;;; talk.el --- allow several users to talk to each other through Emacs

;; Copyright (C) 1995 Free Software Foundation, Inc.

;; Maintainer: FSF
;; Keywords: comm, frames

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
;; Boston, MA 02111-1307, USA.

;;; Commentary:

;; This is a multi-user talk package that runs in Emacs.
;; Use talk-connect to bring a new person into the conversation.

;;; Code:

(defvar talk-display-alist nil
  "Alist of displays on which Emacs talk is now running.
Each element has the form (DISPLAY FRAME BUFFER).")

;;;###autoload
(defun talk-connect (display)
  "Connect to display DISPLAY for the Emacs talk group."
  (interactive "sTalk to display: ")
  ;; Make sure we have an entry for the current display.
  (let ((mydisp (cdr (assq 'display (frame-parameters (selected-frame))))))
    (talk-add-display mydisp))
  ;; Make sure we have an entry for the specified display.
  (talk-add-display display)
  ;; Add the new buffers to all talk frames.
  (talk-update-buffers))

(defun talk-add-display (display)
  (let* ((elt (assoc display talk-display-alist))
	 (name (concat "*talk-" display "*"))
	 buffer frame)
    (if (not (and elt (frame-live-p (setq frame (nth 1 elt)))))
	(setq frame (make-frame-on-display display (list (cons 'name name)))))
    (if (not (and elt (buffer-name (get-buffer (setq buffer (nth 2 elt))))))
	(setq buffer (get-buffer-create name)))
    (setq talk-display-alist
	  (cons (list display frame buffer) (delq elt talk-display-alist)))))

(defun talk-disconnect ()
  "Disconnect this display from the Emacs talk group."
  (interactive)
  (let* ((mydisp (cdr (assq 'display (frame-parameters (selected-frame)))))
	 (elt (assoc mydisp talk-display-alist)))
    (delete-frame (nth 1 elt))
    (kill-buffer (nth 2 elt))
    (setq talk-display-alist (delq elt talk-display-alist))
    (talk-update-buffers)))

(defun talk-update-buffers ()
  "Update all the talk frames so that each shows all the talk buffers."
  (let ((tail talk-display-alist))
    (while tail
      (let ((frame (nth 1 (car tail)))
	    (this-buffer (nth 2 (car tail)))
	    (buffers
	     (mapcar (function (lambda (elt) (nth 2 elt)))
		     talk-display-alist)))
	;; Put this display's own talk buffer
	;; at the front of the list.
	(setq buffers (cons this-buffer (delq this-buffer buffers)))
	(talk-split-up-frame frame buffers))
      (setq tail (cdr tail)))))

(defun talk-split-up-frame (frame buffers)
  "Split FRAME into equal-sized windows displaying the buffers in BUFFERS.
Select the first of these windows, displaying the first of the buffers."
  (let ((lines-per-buffer (/ (frame-height frame) (length buffers)))
	(old-frame (selected-frame)))
    (unwind-protect
	(progn
	  (select-frame frame)
	  (select-window (frame-first-window frame))
	  (delete-other-windows)
	  (while (progn
		   (switch-to-buffer (car buffers))
		   (setq buffers (cdr buffers)))
	    (split-window-vertically lines-per-buffer)
	    (other-window 1))
	  (select-window (frame-first-window frame)))
      (select-frame old-frame))))

(provide 'talk)

;;; talk.el ends here