view lisp/talk.el @ 28230:8e330f701881

(Qx_charset_registry, Vface_default_registry): Variables removed. (clear_font_table, frame_update_line_height, load_face_font): Adjusted for the change of fontset implementation. (load_face_fontset_font): Function removed. (pixel_point_size): New function. (font_list): Argument type changed. Caller changed. (LFACE_FONT): New macro. (check_lface_attrs): Check attr[LFACE_FONT_INDEX]. (set_lface_from_font_name): Type of arg FONTNAME is changed to Lisp_Object. Determine the font name by actually loading a font by the specified pattern. Set LFACE_FONT (lface) to the specified pattern. Even if a font is not found, don't try alternatives. (Finternal_set_lisp_face_attribute): Handle `font' slot in lface. (set_font_frame_param): If `font' is specified in lface, use it. (Finternal_get_lisp_face_attribute): Handle `font' slot in lface. (lface_same_font_attributes_p): Likewise. (make_realized_face): Arguent changed. Caller changed. Set face->ascii_face to face itself. (free_realized_face): Free face->fontset if face is for ASCII. (face_suitable_for_iso8859_1_p, face_suitable_for_charset_p, deduce_unibyte_registry, x_charset_registry): Functions removed. (free_realized_multibyte_face): New function. (lookup_face, lookup_named_face, lookup_derived_face): Argument changed. Caller changed. (try_font_list): Argument type changed. (face_fontset): Check `font' slot of ATTRS, not `family' slot. (choose_face_font): Argument changed. Handle fontset properly. (choose_face_fontset_font): Function removed. (realize_default_face, realize_named_face): Don't remove the former face here. (realize_face): Argument changed. Caller changed. Remove face with the arg former_face_id in advance. Load font for the new face. (realize_x_face): Argument changed. Caller changed. For a multibyte character, share fontset with base_face. For a single byte character, make a new realized fontset. Don't load a font here. (realize_tty_face): Argument changed. Caller changed. (compute_char_face): Call FACE_FOR_CHAR, not FACE_FOR_CHARSET. (face_at_buffer_position): Don't check multibyte_p for returning DEFAULT_FACE_ID. (face_at_string_position): Call FACE_SUITABLE_FOR_CHAR_P, not FACE_SUITABLE_FOR_CHARSET_P. (syms_of_xfaces): Remove code for Qx_charset_registry and Vface_default_registry.

;;; talk.el --- Allow several users to talk to each other through Emacs.

;; Copyright (C) 1995 Free Software Foundation, Inc.

;; Keywords: comm, frames

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
;; Boston, MA 02111-1307, USA.

;;; Commentary:

;; This is a multi-user talk package that runs in Emacs.
;; Use talk-connect to bring a new person into the conversation.

;;; Code:

(defvar talk-display-alist nil
  "Alist of displays on which Emacs talk is now running.
Each element has the form (DISPLAY FRAME BUFFER).")

;;;###autoload
(defun talk-connect (display)
  "Connect to display DISPLAY for the Emacs talk group."
  (interactive "sTalk to display: ")
  ;; Make sure we have an entry for the current display.
  (let ((mydisp (cdr (assq 'display (frame-parameters (selected-frame))))))
    (talk-add-display mydisp))
  ;; Make sure we have an entry for the specified display.
  (talk-add-display display)
  ;; Add the new buffers to all talk frames.
  (talk-update-buffers))

(defun talk-add-display (display)
  (let* ((elt (assoc display talk-display-alist))
	 (name (concat "*talk-" display "*"))
	 buffer frame)
    (if (not (and elt (frame-live-p (setq frame (nth 1 elt)))))
	(setq frame (make-frame-on-display display (list (cons 'name name)))))
    (if (not (and elt (buffer-name (get-buffer (setq buffer (nth 2 elt))))))
	(setq buffer (get-buffer-create name)))
    (setq talk-display-alist
	  (cons (list display frame buffer) (delq elt talk-display-alist)))))

(defun talk-disconnect ()
  "Disconnect this display from the Emacs talk group."
  (interactive)
  (let* ((mydisp (cdr (assq 'display (frame-parameters (selected-frame)))))
	 (elt (assoc mydisp talk-display-alist)))
    (delete-frame (nth 1 elt))
    (kill-buffer (nth 2 elt))
    (setq talk-display-alist (delq elt talk-display-alist))
    (talk-update-buffers)))

(defun talk-update-buffers ()
  "Update all the talk frames so that each shows all the talk buffers."
  (let ((tail talk-display-alist))
    (while tail
      (let ((frame (nth 1 (car tail)))
	    (this-buffer (nth 2 (car tail)))
	    (buffers
	     (mapcar (function (lambda (elt) (nth 2 elt)))
		     talk-display-alist)))
	;; Put this display's own talk buffer
	;; at the front of the list.
	(setq buffers (cons this-buffer (delq this-buffer buffers)))
	(talk-split-up-frame frame buffers))
      (setq tail (cdr tail)))))

(defun talk-split-up-frame (frame buffers)
  "Split FRAME into equal-sized windows displaying the buffers in BUFFERS.
Select the first of these windows, displaying the first of the buffers."
  (let ((lines-per-buffer (/ (frame-height frame) (length buffers)))
	(old-frame (selected-frame)))
    (unwind-protect
	(progn
	  (select-frame frame)
	  (select-window (frame-first-window frame))
	  (delete-other-windows)
	  (while (progn
		   (switch-to-buffer (car buffers))
		   (setq buffers (cdr buffers)))
	    (split-window-vertically lines-per-buffer)
	    (other-window 1))
	  (select-window (frame-first-window frame)))
      (select-frame old-frame))))

(provide 'talk)

;;; talk.el ends here