view lisp/gnus/gnus-sieve.el @ 99139:8fa7ef477c04

2008-10-26 Carsten Dominik <[e-mail]> * org-agenda.el (org-format-agenda-item) (org-agenda-filter-make-matcher): Make sure tags are stored and compared donwcased. 2008-10-26 Carsten Dominik <[e-mail]> * org.el (org-insert-todo-heading): Fix bug with force-heading argument. 2008-10-26 Carsten Dominik <[e-mail]> * org-exp.el (org-export-as-ascii): Handle the case that we are bulishing from an indirect buffer. * org-table.el (org-table-copy-down): Fix bug with time stamp increment. * org-mouse.el (org-mouse-features): New option. (org-mode-hook): Turn on features depending on `org-mouse-features'. * org.el (org-insert-heading-respect-content): Force heading creation. (org-insert-heading): keep the folding state of the heading before the inserted one. 2008-10-26 Carsten Dominik <[e-mail]> * org-archive.el (org-archive-to-archive-sibling): Handle top level headlines better. 2008-10-26 Bastien Guerry <[e-mail]> * org-export-latex.el (org-export-latex-classes): Added \usepackage{graphicx} to the default list of packages. 2008-10-26 Carsten Dominik <[e-mail]> * org-agenda.el (org-agenda-filter): Renamed from `org-agenda-filter-tags'. 2008-10-26 Carsten Dominik <[e-mail]> * org.el (org-entry-properties): Add CATEGORY property, iven if it is not defined as a property in this entry. (org-add-log-note): Mask prefix argument when immediately storing the note. * org-agenda.el (org-agenda-filter-effort-default-operator): New option. 2008-10-26 James TD Smith <[e-mail]> * org.el (org-add-log-setup): Bugfix; code to find insertion point after drawers was skipping ahead one line too many, so notes were inserted after the first note instead of before it. 2008-10-26 Carsten Dominik <[e-mail]> * org-agenda.el (org-agenda-filter-tags,org-agenda-filter-form): New variables. (org-prepare-agenda): Reset the filter tags. (org-agenda-filter-by-tag, org-agenda-filter-by-tag-show-all): Show filter tags in mode line. * org-table.el (orgtbl-to-html): Bind `html-table-tag' for the formatter. * org-export-latex.el (org-latex-entities-regexp): New constant. (org-export-as-pdf): Use two calls to `shell-command'. 2008-10-26 Carsten Dominik <[e-mail]> * org-export-latex.el (org-export-latex-treat-sub-super-char): Honor the {} value of the subsuperscript setting. Make sure that longer subsuperscripts are typeset in a roman font. * org.el (org-clock-update-time-maybe): Compute negative clock intervals correctly. 2008-10-26 Carsten Dominik <[e-mail]> * org.el (org-add-log-setup): Respect `org-log-state-notes-insert-after-drawers'. (org-log-state-notes-insert-after-drawers): New option. (org-todo-trigger-tag-changes): New function. (org-todo): Call `org-todo-trigger-tag-changes'. 2008-10-26 James TD Smith <[e-mail]> * org.el (org-add-log-setup): Only skip drawers if the are immediately after the scheduling keywords. * org-clock.el (org-clock-in-switch-to-state): Allow this to be a function (org-clock-in): If `org-clock-in-switch-to-state' is a function, call it with the current todo state to get the state to switch to when clocking in. (org-clock-in): Use org-indent-line-function to indent clock lines. (org-clock-find-position): Fix indentation of empty clock drawers. 2008-10-26 Carsten Dominik <[e-mail]> * org-publish.el (org-publish-org-to): Handle case when org-export-to-pdf does return a file name, not a buffer. (org-publish-org-to-pdf): New function. * org-export-latex.el (org-export-as-pdf) (org-export-as-pdf-and-open): New commands. * org-table.el (org-table-eval-formula): Avoid parsing Calc's HMS forms as ranges. * org-export-latex.el (org-export-latex-lists): Ignore lists-like things in protexted regions. 2008-10-26 Carsten Dominik <[e-mail]> * org-export-latex.el (org-export-latex-preprocess): Improve quoting of LaTeX environments.

;;; gnus-sieve.el --- Utilities to manage sieve scripts for Gnus

;; Copyright (C) 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.

;; Author: NAGY Andras <[e-mail]>,
;;	Simon Josefsson <[e-mail]>

;; This file is part of GNU Emacs.

;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:

;; Gnus glue to generate complete Sieve scripts from Gnus Group
;; Parameters with "if" test predicates.

;;; Code:

(require 'gnus)
(require 'gnus-sum)
(require 'format-spec)
(autoload 'sieve-mode "sieve-mode")
(eval-when-compile
  (require 'sieve))

;; Variables

(defgroup gnus-sieve nil
  "Manage sieve scripts in Gnus."
  :group 'gnus)

(defcustom gnus-sieve-file "~/.sieve"
  "Path to your Sieve script."
  :type 'file
  :group 'gnus-sieve)

(defcustom gnus-sieve-region-start "\n## Begin Gnus Sieve Script\n"
  "Line indicating the start of the autogenerated region in
your Sieve script."
  :type 'string
  :group 'gnus-sieve)

(defcustom gnus-sieve-region-end "\n## End Gnus Sieve Script\n"
  "Line indicating the end of the autogenerated region in
your Sieve script."
  :type 'string
  :group 'gnus-sieve)

(defcustom gnus-sieve-select-method nil
  "Which select method we generate the Sieve script for.

For example: \"nnimap:mailbox\""
  :group 'gnus-sieve)

(defcustom gnus-sieve-crosspost t
  "Whether the generated Sieve script should do crossposting."
  :type 'boolean
  :group 'gnus-sieve)

(defcustom gnus-sieve-update-shell-command "echo put %f | sieveshell %s"
  "Shell command to execute after updating your Sieve script.  The following
formatting characters are recognized:

%f    Script's file name (gnus-sieve-file)
%s    Server name (from gnus-sieve-select-method)"
  :type 'string
  :group 'gnus-sieve)

;;;###autoload
(defun gnus-sieve-update ()
  "Update the Sieve script in gnus-sieve-file, by replacing the region
between gnus-sieve-region-start and gnus-sieve-region-end with
\(gnus-sieve-script gnus-sieve-select-method gnus-sieve-crosspost\), then
execute gnus-sieve-update-shell-command.
See the documentation for these variables and functions for details."
  (interactive)
  (gnus-sieve-generate)
  (save-buffer)
  (shell-command
   (format-spec gnus-sieve-update-shell-command
		(format-spec-make ?f gnus-sieve-file
				  ?s (or (cadr (gnus-server-get-method
						nil gnus-sieve-select-method))
					 "")))))

;;;###autoload
(defun gnus-sieve-generate ()
  "Generate the Sieve script in gnus-sieve-file, by replacing the region
between gnus-sieve-region-start and gnus-sieve-region-end with
\(gnus-sieve-script gnus-sieve-select-method gnus-sieve-crosspost\).
See the documentation for these variables and functions for details."
  (interactive)
  (require 'sieve)
  (find-file gnus-sieve-file)
  (goto-char (point-min))
  (if (re-search-forward (regexp-quote gnus-sieve-region-start) nil t)
      (delete-region (match-beginning 0)
		     (or (re-search-forward (regexp-quote
					     gnus-sieve-region-end) nil t)
			 (point)))
    (insert sieve-template))
  (insert gnus-sieve-region-start
	  (gnus-sieve-script gnus-sieve-select-method gnus-sieve-crosspost)
	  gnus-sieve-region-end))

(defun gnus-sieve-guess-rule-for-article ()
  "Guess a sieve rule based on RFC822 article in buffer.
Return nil if no rule could be guessed."
  (when (message-fetch-field "sender")
    `(sieve address "sender" ,(message-fetch-field "sender"))))

;;;###autoload
(defun gnus-sieve-article-add-rule ()
  (interactive)
  (gnus-summary-select-article nil 'force)
  (with-current-buffer gnus-original-article-buffer
    (let ((rule (gnus-sieve-guess-rule-for-article))
	  (info (gnus-get-info gnus-newsgroup-name)))
      (if (null rule)
	  (error "Could not guess rule for article")
	(gnus-info-set-params info (cons rule (gnus-info-params info)))
	(message "Added rule in group %s for article: %s" gnus-newsgroup-name
		 rule)))))

;; Internals

;; FIXME: do proper quoting of " etc
(defun gnus-sieve-string-list (list)
  "Convert an elisp string list to a Sieve string list.

For example:
\(gnus-sieve-string-list '(\"to\" \"cc\"))
  => \"[\\\"to\\\", \\\"cc\\\"]\"
"
  (concat "[\"" (mapconcat 'identity list "\", \"") "\"]"))

(defun gnus-sieve-test-list (list)
  "Convert an elisp test list to a Sieve test list.

For example:
\(gnus-sieve-test-list '((address \"sender\" \"[e-mail]\") (size :over 4K)))
  => \"(address \\\"sender\\\" \\\"[e-mail]\\\", size :over 4K)\""
  (concat "(" (mapconcat 'gnus-sieve-test list ", ") ")"))

;; FIXME: do proper quoting
(defun gnus-sieve-test-token (token)
  "Convert an elisp test token to a Sieve test token.

For example:
\(gnus-sieve-test-token 'address)
  => \"address\"

\(gnus-sieve-test-token \"sender\")
  => \"\\\"sender\\\"\"

\(gnus-sieve-test-token '(\"to\" \"cc\"))
  => \"[\\\"to\\\", \\\"cc\\\"]\""
  (cond
   ((symbolp token)            ;; Keyword
    (symbol-name token))

   ((stringp token)            ;; String
    (concat "\"" token "\""))

   ((and (listp token)         ;; String list
	 (stringp (car token)))
    (gnus-sieve-string-list token))

   ((and (listp token)         ;; Test list
	 (listp (car token)))
    (gnus-sieve-test-list token))))

(defun gnus-sieve-test (test)
  "Convert an elisp test to a Sieve test.

For example:
\(gnus-sieve-test '(address \"sender\" \"[e-mail]\"))
  => \"address \\\"sender\\\" \\\"[e-mail]\\\"\"

\(gnus-sieve-test '(anyof ((header :contains (\"to\" \"cc\") \"[e-mail]\")
			  (size :over 100K))))
  => \"anyof (header :contains [\\\"to\\\", \\\"cc\\\"] \\\"[e-mail]\\\",
	     size :over 100K)\""
  (mapconcat 'gnus-sieve-test-token test " "))

(defun gnus-sieve-script (&optional method crosspost)
  "Generate a Sieve script based on groups with select method METHOD
\(or all groups if nil\).  Only groups having a `sieve' parameter are
considered.  This parameter should contain an elisp test
\(see the documentation of gnus-sieve-test for details\).  For each
such group, a Sieve IF control structure is generated, having the
test as the condition and { fileinto \"group.name\"; } as the body.

If CROSSPOST is nil, each conditional body contains a \"stop\" command
which stops execution after a match is found.

For example: If the INBOX.list.sieve group has the

  (sieve address \"sender\" \"[e-mail]\")

group parameter, (gnus-sieve-script) results in:

  if address \"sender\" \"[e-mail]\" {
          fileinto \"INBOX.list.sieve\";
  }

This is returned as a string."
  (let* ((newsrc (cdr gnus-newsrc-alist))
	 script)
    (dolist (info newsrc)
      (when (or (not method)
		(gnus-server-equal method (gnus-info-method info)))
	(let* ((group (gnus-info-group info))
	       (spec (gnus-group-find-parameter group 'sieve t)))
	  (when spec
	    (push (concat "if " (gnus-sieve-test spec) " {\n"
			  "\tfileinto \"" (gnus-group-real-name group) "\";\n"
			  (if crosspost
			      ""
			    "\tstop;\n")
			  "}")
		  script)))))
    (mapconcat 'identity script "\n")))

(provide 'gnus-sieve)

;; arch-tag: 3b906527-c7f3-4c86-9e82-62e2697998a3
;;; gnus-sieve.el ends here