view msdos/sed1.inp @ 65689:96187e7edd1b

2005-09-25 Romain Francoise <[e-mail]> * dired-aux.el (dired-copy-file-recursive): * dired.el (dired-delete-file): * ediff-mult.el (ediff-dir-diff-copy-file): * ediff-util.el (ediff-test-save-region): * forms.el (forms-mode): * ido.el (ido-file-internal, ido-delete-file-at-head): * log-edit.el (log-edit-done): * ses.el (ses-yank-resize): * play/gomoku.el (gomoku-human-plays, gomoku) (gomoku-human-resigns, gomoku-prompt-for-other-game) (gomoku-offer-a-draw): * play/landmark.el (lm-human-resigns, lm): * net/eudcb-ldap.el (eudc-ldap-check-base): * play/mpuz.el (mpuz-offer-abort, mpuz-try-letter, mpuz-close-game): * progmodes/ebrowse.el (ebrowse-find-pattern): * progmodes/idlw-shell.el (idlwave-shell-set-bp-check): * textmodes/reftex-index.el (reftex-index-initialize-phrases-buffer): End `yes-or-no-p' and `y-or-n-p' prompts with question mark and space. * vc.el (vc-delete-file): * play/gomoku.el (gomoku-terminate-game, gomoku) (gomoku-prompt-for-move, gomoku-human-takes-back): * play/landmark.el (lm-human-takes-back, lm-prompt-for-move) (lm-start-robot, lm-human-plays): Remove extraneous spaces in messages.

# -sed1.inp-------------------------------------------------------------
# Configuration script for src/makefile
# ----------------------------------------------------------------------
#
# Copyright (C) 1993, 1994, 1995, 1996, 1997, 2000, 2002, 2003, 2004,
#   2005 Free Software Foundation, Inc.
#
# This file is part of GNU Emacs.
#
# This file is free software; as a special exception, the author gives
# unlimited permission to copy and/or distribute it, with or without
# modifications, as long as this notice is preserved.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
#
# ----------------------------------------------------------------------
# In case src/Makefile needs to rebuild `make-doc.exe' (might happen under
# Windows 95), make sure it gets built with commands that DOS
# understands (one command per line).
s/^#.*//
s/^[ \f\t][ \f\t]*$//
s/^ /	/
s/\.h\.in/.h-in/
s!^	\./temacs!	go32 temacs!
s!/bin/sh!command.com!
/^MAKE *=/s/^/# /
/^SHELL *=/s/^/# /
/^srcdir *=/s/@[^@\n]*@/./
/^VPATH *=/s/@[^@\n]*@/./
/^CC *=/s/@[^@\n]*@/gcc/
/^CPP *=/s/@[^@\n]*@/gcc -e/
/^CFLAGS *=/s/@[^@\n]*@/-O2 -g/
/^LIBS *=/s/@[^@\n]*@//
/^LIBOBJS *=/s/@[^@\n]*@//
/^LN_S *=/s/@[^@\n]*@/ln -s/
/^M_FILE *=/s!@[^@\n]*@!m/intel386.h!
/^S_FILE *=/s!@[^@\n]*@!s/msdos.h!
/^@SET_MAKE@$/s/@SET_MAKE@//
/^.\${libsrc}make-docfile.*>/s!make-docfile!make-doc.exe -o ../etc/DOC!
/^.\${libsrc}make-doc/s!>.*$!!
/^\${libsrc}make-docfile:/c\
${libsrc}make-doc.exe:\
	cd ..\
	cd lib-src\
	$(MAKE) ${MFLAGS} make-docfile -W make-docfile.c\
	cd ..\
	cd src
/^	cd \${libsrc}; \${MAKE} \${MFLAGS} make-docfile/d
/\${libsrc}make-docfile/s/-docfile[ 	]/-doc.exe /
/^[ 	]*$/d
/^temacs:/s/prefix-args//
/^temacs:/s/stamp-oldxmenu//
/^	#/d

# arch-tag: 246725c1-79de-4d03-a080-8f19329fa35e