view lisp/play/studly.el @ 76267:96573486524e

Merge from gnus--rel--5.10 Patches applied: * gnus--rel--5.10 (patch 203-205) - Merge from emacs--devo--0 - Update from CVS 2007-02-28 Katsumi Yamaoka <[e-mail]> * lisp/gnus/message.el (message-make-in-reply-to): Quote name containing non-ASCII characters. It will make the RFC2047 encoder cause an error if there are special characters. Reported by NAKAJI Hiroyuki <[e-mail]>. 2007-02-27 Katsumi Yamaoka <[e-mail]> * lisp/gnus/nntp.el (nntp-never-echoes-commands) (nntp-open-connection-functions-never-echo-commands): New variables. (nntp-send-command): Use them. 2007-02-27 Katsumi Yamaoka <[e-mail]> * man/gnus.texi (NNTP): Mention nntp-never-echoes-commands and nntp-open-connection-functions-never-echo-commands. Revision: [e-mail]/emacs--devo--0--patch-658

;;; studly.el --- StudlyCaps (tm)(r)(c)(xxx)

;;; This is in the public domain, since it was distributed
;;; by its author without a copyright notice in 1986.

;; This file is part of GNU Emacs.

;; Maintainer: FSF
;; Keywords: games

;;; Commentary:

;; Functions to studlycapsify a region, word, or buffer.  Possibly the
;; esoteric significance of studlycapsification escapes you; that is,
;; you suffer from autostudlycapsifibogotification.  Too bad.

;;; Code:

;;;###autoload
(defun studlify-region (begin end)
  "Studlify-case the region."
  (interactive "*r")
  (save-excursion
    (goto-char begin)
    (setq begin (point))
    (while (and (<= (point) end)
		(not (looking-at "\\W*\\'")))
      (forward-word 1)
      (backward-word 1)
      (setq begin (max (point) begin))
      (forward-word 1)
      (let ((offset 0)
	    (word-end (min (point) end))
	    c)
	(goto-char begin)
	(while (< (point) word-end)
	  (setq offset (+ offset (following-char)))
	  (forward-char 1))
	(setq offset (+ offset (following-char)))
	(goto-char begin)
	(while (< (point) word-end)
	  (setq c (following-char))
	  (if (and (= (% (+ c offset) 4) 2)
		   (let ((ch (following-char)))
		     (or (and (>= ch ?a) (<= ch ?z))
			 (and (>= ch ?A) (<= ch ?Z)))))
	      (progn
		(delete-char 1)
		(insert (logxor c ? ))))
	  (forward-char 1))
	(setq begin (point))))))

;;;###autoload
(defun studlify-word (count)
  "Studlify-case the current word, or COUNT words if given an argument."
  (interactive "*p")
  (let ((begin (point)) end rb re)
    (forward-word count)
    (setq end (point))
    (setq rb (min begin end) re (max begin end))
    (studlify-region rb re)))

;;;###autoload
(defun studlify-buffer ()
  "Studlify-case the current buffer."
  (interactive "*")
  (studlify-region (point-min) (point-max)))

(provide 'studly)

;;; arch-tag: 0dbf5a60-d2e6-48c2-86ae-77fc8575ac67
;;; studly.el ends here