view lisp/delsel.el @ 19704:974a890c1d12

Include stddef.h. (getwd): Delete macro. (startup_dir): New variable. (getwd): Return directory in which Emacs started. (init_user_info): Set SHELL environment variable if not set. (parse_root, get_long_basename, w32_get_long_filename): New functions. (init_environment): Look for CMDPROXY. Make sure that PATH and COMSPEC are capitalized in the environment. Record startup directory. (get_emacs_configuration, sys_rename): Use OS_WIN95. (map_w32_filename): Calculate returned string correctly. (sys_fopen): Use _fdopen. (sys_link): Support NTFS links. (sys_rename): Use a long file name for temporary name. (sys_pipe): Make pipes binary and non-inheritable. (sys_read, sys_write): Spoof text mode translation for pipes and sockets. (hashval): Simplify. (generate_inode_val): Use long file name version of file. (stat): Optimize by using active readdir info. Set fake_inode to 0 for directories. Set fake_inode to xor of file indexes for files. Don't use generate_inode_val to set inode value. (volume_info_data): Renamed from volume_info. (volume_info, fixed_drives, volume_cache): New variables. (DRIVE_INDEX, VOLINFO_STILL_VALID): New macros. (lookup_volume_info, add_volume_info, GetCachedVolumeInformation): New functions. (get_volume_info): Use volume_info_data. Use GetCachedVolumeInformation. (init_ntproc): No longer restrict to one DOS subprocess. Use CRT _open and _fdopen. Cache fixed drive information.

;;; delsel.el --- delete selection if you insert

;; Copyright (C) 1992, 1997 Free Software Foundation, Inc.

;; Author: Matthieu Devin <[e-mail]>
;; Maintainer: FSF
;; Created: 14 Jul 92

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
;; Boston, MA 02111-1307, USA.

;;; Commentary:

;; This file makes the active region be pending delete, meaning that
;; text inserted while the region is active will replace the region contents.
;; This is a popular behavior of personal computers text editors.

;;; Code:

(eval-when-compile
  (require 'cl))

;;;###autoload
(defalias 'pending-delete-mode 'delete-selection-mode)

;;;###autoload
(defun delete-selection-mode (&optional arg)
  "Toggle Delete Selection mode.
With prefix ARG, turn Delete Selection mode on if and only if ARG is positive.

When Delete Selection mode is enabled, Transient Mark mode is also enabled and
typed text replaces the selection if the selection is active.  Otherwise, typed
text is just inserted at point regardless of any selection."
  (interactive "P")
  (setq delete-selection-mode (if arg
				  (> (prefix-numeric-value arg) 0)
				(not delete-selection-mode)))
  (if (not delete-selection-mode)
      (remove-hook 'pre-command-hook 'delete-selection-pre-hook)
    (add-hook 'pre-command-hook 'delete-selection-pre-hook)
    (transient-mark-mode t)))

;;;###autoload
(defcustom delete-selection-mode nil
  "Toggle Delete Selection mode.
When Delete Selection mode is enabled, Transient Mark mode is also enabled and
typed text replaces the selection if the selection is active.
You must modify via \\[customize] for this variable to have an effect."
  :set (lambda (symbol value)
	 (delete-selection-mode (or value 0)))
  :initialize 'custom-initialize-default
  :type 'boolean
  :group 'editing-basics
  :require 'delsel)

(defun delete-active-region (&optional killp)
  (if killp
      (kill-region (point) (mark))
    (delete-region (point) (mark)))
  (setq mark-active nil)
  (run-hooks 'deactivate-mark-hook)
  t)

(defun delete-selection-pre-hook ()
  (when (and delete-selection-mode transient-mark-mode mark-active
	     (not buffer-read-only))
    (let ((type (and (symbolp this-command)
		     (get this-command 'delete-selection))))
      (cond ((eq type 'kill)
	     (delete-active-region t))
	    ((eq type 'yank)
	     ;; Before a yank command,
	     ;; make sure we don't yank the same region
	     ;; that we are going to delete.
	     ;; That would make yank a no-op.
	     (when (string= (buffer-substring-no-properties (point) (mark))
			    (car kill-ring))
	       (current-kill 1))
	     (delete-active-region nil))
	    ((eq type 'supersede)
	     (when (delete-active-region nil)
	       (setq this-command '(lambda () (interactive)))))
	    (type
	     (delete-active-region nil))))))

(put 'self-insert-command 'delete-selection t)
(put 'self-insert-iso 'delete-selection t)

(put 'yank 'delete-selection 'yank)
(put 'clipboard-yank 'delete-selection 'yank)
(put 'insert-register 'delete-selection t)

(put 'delete-backward-char 'delete-selection 'supersede)
(put 'backward-delete-char-untabify 'delete-selection 'supersede)
(put 'delete-char 'delete-selection 'supersede)

(put 'newline-and-indent 'delete-selection 't)
(put 'newline 'delete-selection t)
(put 'open-line 'delete-selection t)

;; This is very useful for cancelling a selection in the minibuffer without 
;; aborting the minibuffer.
(defun minibuffer-keyboard-quit ()
  "Abort recursive edit.
In Delete Selection mode mode, if the mark is active, just deactivate it;
then it takes a second C-g to abort the minibuffer."
  (interactive)
  (if (and delete-selection-mode transient-mark-mode mark-active)
      (setq deactivate-mark t)
    (abort-recursive-edit)))

(define-key minibuffer-local-map "\C-g" 'minibuffer-keyboard-quit) 
(define-key minibuffer-local-ns-map "\C-g" 'minibuffer-keyboard-quit) 
(define-key minibuffer-local-completion-map "\C-g" 'minibuffer-keyboard-quit) 
(define-key minibuffer-local-must-match-map "\C-g" 'minibuffer-keyboard-quit) 
(define-key minibuffer-local-isearch-map "\C-g" 'minibuffer-keyboard-quit) 

(provide 'delsel)

;; This is the standard way mechanism to put the mode into effect
;; if delete-selection-mode has already been set to t
;; when this file is loaded.
(when delete-selection-mode
  (delete-selection-mode t))

;;; delsel.el ends here