view msdos/sed1.inp @ 18301:a4da36c7bb08

Define describe-coding-system instead of describe-current-coding-system in help-map and mule-menu-keymap. In mule-menu-keymap, enable set-buffer-process-coding-system only when the current buffer has been associated with some subprocess. (set-language-info): Doc-string modified because input-method is not a valid KEY argument now. (leim-list-file-name, leim-list-header, leim-list-entry-regexp): New variables. (update-leim-list-file, update-all-leim-list-files): New functions. (current-input-method): Doc-string modified because the value is now input method name. (defualt-input-method, previous-input-method): Likewise. (current-input-method-title): Doc-string modified because now each input method does not have to set this variable. (input-method-alist): New variable. (register-input-method): Register input method in input-method-alist. (read-language-and-input-method-name): Deleted. (read-input-method-name): New function. (activate-input-method, select-input-method, toggle-input-method): Modified for the above change. (read-multilingual-string): Likewise. (describe-current-input-method): Renamed from describe-input-method. (describe-input-method): New function. (describe-language-environment): Do not put a vacant line at the top of *Help* buffer. Show a title string of each input method.

# -sed1.inp-------------------------------------------------------------
# Configuration script for src/makefile
# ----------------------------------------------------------------------
#
# In case src/Makefile needs to rebuild `make-doc.exe' (might happen under
# Windows 95), make sure it gets built with commands that DOS
# understands (one command per line).
s/^#.*//
s/^[ \f\t][ \f\t]*$//
s/^ /	/
s/\.h\.in/.h-in/
s!^	\./temacs!	go32 temacs!
s!/bin/sh!command.com!
/^MAKE *=/s/^/# /
/^SHELL *=/s/^/# /
/^srcdir *=/s/@[^@\n]*@/./
/^VPATH *=/s/@[^@\n]*@/./
/^CC *=/s/@[^@\n]*@/gcc/
/^CPP *=/s/@[^@\n]*@/gcc -e/
/^CFLAGS *=/s/@[^@\n]*@/-O2 -g/
/^LN_S *=/s/@[^@\n]*@/ln -s/
/^M_FILE *=/s!@[^@\n]*@!m/intel386.h!
/^S_FILE *=/s!@[^@\n]*@!s/msdos.h!
/^@SET_MAKE@$/s/@SET_MAKE@//
/^.\${libsrc}make-docfile.*>/s!make-docfile!make-doc.exe -o ../etc/DOC!
/^.\${libsrc}make-doc/s!>.*$!!
/^\${libsrc}make-docfile:/c\
${libsrc}make-doc.exe:\
	cd ..\
	cd lib-src\
	$(MAKE) ${MFLAGS} make-docfile -W make-docfile.c\
	cd ..\
	cd src
/^	cd \${libsrc}; \${MAKE} \${MFLAGS} make-docfile/d
/\${libsrc}make-docfile/s/-docfile[ 	]/-doc.exe /
/^[ 	]*$/d
/^temacs:/s/prefix-args//
/^	#/d