view lisp/language/tv-util.el @ 110523:a5ad4f188e19

Synch Semantic to CEDET 1.0. Move CEDET ChangeLog entries to new file lisp/cedet/ChangeLog. * semantic.el (semantic-version): Update to 2.0. (semantic-mode-map): Add "," and "m" bindings. (navigate-menu): Update. * semantic/symref.el (semantic-symref-calculate-rootdir): New function. (semantic-symref-detect-symref-tool): Use it. * semantic/symref/grep.el (semantic-symref-grep-shell): New var. (semantic-symref-perform-search): Use it. Calculate root dir with semantic-symref-calculate-rootdir. (semantic-symref-derive-find-filepatterns): Improve error message. * semantic/symref/list.el (semantic-symref-results-mode-map): New bindings. (semantic-symref-auto-expand-results): New option. (semantic-symref-results-dump): Obey auto-expand. (semantic-symref-list-expand-all, semantic-symref-regexp) (semantic-symref-list-contract-all) (semantic-symref-list-map-open-hits) (semantic-symref-list-update-open-hits) (semantic-symref-list-create-macro-on-open-hit) (semantic-symref-list-call-macro-on-open-hits): New functions. (semantic-symref-list-menu-entries) (semantic-symref-list-menu): New vars. (semantic-symref-list-map-open-hits): Move cursor to beginning of match before calling the mapped function. * semantic/doc.el (semantic-documentation-comment-preceeding-tag): Do nothing if the mode doesn't provide comment-start-skip. * semantic/scope.el (semantic-analyze-scope-nested-tags-default): Strip duplicates. (semantic-analyze-scoped-inherited-tag-map): Take the tag we are looking for as part of the scoped tags list. * semantic/html.el (semantic-default-html-setup): Add senator-step-at-tag-classes. * semantic/decorate/include.el (semantic-decoration-on-unknown-includes): Change light bgcolor. (semantic-decoration-on-includes-highlight-default): Check that the include tag has a postion. * semantic/complete.el (semantic-collector-local-members): (semantic-complete-read-tag-local-members) (semantic-complete-jump-local-members): New class and functions. (semantic-complete-self-insert): Save excursion before completing. * semantic/analyze/complete.el (semantic-analyze-possible-completions-default): If no completions are found, return the raw by-name-only completion list. Add FLAGS arguments. Add support for 'no-tc (type constraint) and 'no-unique, or no stripping duplicates. (semantic-analyze-possible-completions-default): Add FLAGS arg. * semantic/util-modes.el (semantic-stickyfunc-show-only-functions-p): New option. (semantic-stickyfunc-fetch-stickyline): Don't show stickytext for the very first line in a buffer. * semantic/util.el (semantic-hack-search) (semantic-recursive-find-nonterminal-by-name) (semantic-current-tag-interactive): Deleted. (semantic-describe-buffer): Fix expand-nonterminal. Add lex-syntax-mods, type relation separator char, and command separation char. (semantic-sanity-check): Only message if called interactively. * semantic/tag.el (semantic-tag-deep-copy-one-tag): Copy the :filename property and the tag position. * semantic/lex-spp.el (semantic-lex-spp-lex-text-string): Add recursion limit. * semantic/imenu.el (semantic-imenu-bucketize-type-members): Make this buffer local, not the obsoleted variable. * semantic/idle.el: Add breadcrumbs support. (semantic-idle-summary-current-symbol-info-default) (semantic-idle-tag-highlight) (semantic-idle-completion-list-default): Use semanticdb-without-unloaded-file-searches for speed, and to conform to the controls that specify if the idle timer is supposed to be parsing unparsed includes. (semantic-idle-symbol-highlight-face) (semantic-idle-symbol-maybe-highlight): Rename from *-summary-*. Callers changed. (semantic-idle-work-parse-neighboring-files-flag): Default to nil. (semantic-idle-work-update-headers-flag): New var. (semantic-idle-work-for-one-buffer): Use it. (semantic-idle-local-symbol-highlight): Rename from semantic-idle-tag-highlight. (semantic-idle-truncate-long-summaries): New option. * semantic/ia.el (semantic-ia-cache) (semantic-ia-get-completions): Deleted. Callers changed. (semantic-ia-show-variants): New command. (semantic-ia-show-doc): If doc is empty, don't make a temp buffer. (semantic-ia-show-summary): If there isn't anything to show, say so. * semantic/grammar.el (semantic-grammar-create-package): Save the buffer even in batch mode. * semantic/fw.el (semanticdb-without-unloaded-file-searches): New macro. * semantic/dep.el (semantic-dependency-find-file-on-path): Fix case dereferencing ede-object when it is a list. * semantic/db-typecache.el (semanticdb-expand-nested-tag) (semanticdb-typecache-faux-namespace): New functions. (semanticdb-typecache-file-tags) (semanticdb-typecache-merge-streams): Use them. (semanticdb-typecache-file-tags): When deriving tags from a file, give the mode a chance to monkey with the tag copy. (semanticdb-typecache-find-default): Wrap find in save-excursion. (semanticdb-typecache-find-by-name-helper): Merge found names down. * semantic/db-global.el (semanticdb-enable-gnu-global-in-buffer): Don't show messages if GNU Global is not available and we don't want to throw an error. * semantic/db-find.el (semanticdb-find-result-nth-in-buffer): When trying to normalize the tag to a buffer, don't error if set-buffer method doesn't exist. * semantic/db-file.el (semanticdb-save-db): Simplify msg. * semantic/db.el (semanticdb-refresh-table): If forcing a refresh on a file not in a buffer, use semantic-find-file-noselect and delete the buffer after use. (semanticdb-current-database-list): When calculating root via hooks, force it through true-filename and skip the list of possible roots. * semantic/ctxt.el (semantic-ctxt-imported-packages): New. * semantic/analyze/debug.el (semantic-analyzer-debug-insert-tag): Reset standard output to current buffer. (semantic-analyzer-debug-global-symbol) (semantic-analyzer-debug-missing-innertype): Change "prefix" to "symbol" in messages. * semantic/analyze/refs.el: (semantic-analyze-refs-impl) (semantic-analyze-refs-proto): When calculating value, make sure the found tag is 'similar' to the originating tag. (semantic--analyze-refs-find-tags-with-parent): Attempt to identify matches via imported symbols of parents. (semantic--analyze-refs-full-lookup-with-parents): Do a deep search during the brute search. * semantic/analyze.el (semantic-analyze-find-tag-sequence-default): Be robust to calculated scopes being nil. * semantic/bovine/c.el (semantic-c-describe-environment): Add project macro symbol array. (semantic-c-parse-lexical-token): Add recursion limit. (semantic-ctxt-imported-packages, semanticdb-expand-nested-tag): New overrides. (semantic-expand-c-tag-namelist): Split a full type from a typedef out to its own tag. (semantic-expand-c-tag-namelist): Do not split out a typedef'd inline type if it is an anonymous type. (semantic-c-reconstitute-token): Use the optional initializers as a clue that some function is probably a constructor. When defining the type of these constructors, split the parent name, and use only the class part, if applicable. * semantic/bovine/c-by.el: * semantic/wisent/python-wy.el: Regenerate.

;;; tv-util.el --- support for Tai Viet			-*- coding: utf-8 -*-

;; Copyright (C) 2007, 2008, 2009, 2010
;;   National Institute of Advanced Industrial Science and Technology (AIST)
;;   Registration Number H13PRO009

;; Keywords: multilingual, Tai Viet, i18n

;; This file is part of GNU Emacs.

;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.

;;; Code

;; Regexp matching with a sequence of Tai Viet characters.
(defconst tai-viet-re
  (format "[\xaa80-\xaac2\xaadb-\xaadf-]+"))

;; Char-table of information about glyph type of Tai Viet characters.
(defconst tai-viet-glyph-info
  (let ((table (make-char-table nil))
	(specials '((right-overhang . "ꪊꪋꪌꪍꪏꪓꪖꪜꪞꪡꪤꪨ")
		    (left-overhang . "ꫂ")
		    (combining-vowel . "ꪴꪰꪲꪳꪷꪸꪾ")
		    (combining-tone . "꪿꫁")
		    (misc . "-"))))
    ;; Set all TaiViet characters to `t'.
    (set-char-table-range table (cons #xaa80 #xaac2) t)
    (set-char-table-range table (cons #xaadb #xaadf) t)
    ;; Overwrite it for special characters.
    (dolist (elt specials)
      (let ((category (car elt))
	    (chars (cdr elt)))
	(dotimes (i (length chars))
	  (aset table (aref chars i) category))))
    table))

(defun tai-viet-compose-string (from to string)
  "Compose Tai Viet characters in STRING between indices FROM and TO."
  (let* ((ch (aref string from))
	 (info (aref tai-viet-glyph-info ch))
	 prev-info)
    (if (eq info 'non-spacing)
	(compose-string string from (1+ from) (string ch ?\t)))
    (setq from (1+ from) prev-info info)
    (while (and (< from to)
		(>= #xaa80 (setq ch (aref string from)))
		(<= #xaaDF ch))
      (setq info (aref tai-viet-glyph-info ch))
      (if (and (eq info 'non-spacing)
	       (eq prev-info 'non-spacing))
	  (compose-string from (1+ from) (string ?\t ch)))
      (setq from (1+ from) prev-info info))
    (if (eq info 'right-overhang)
	(compose-string string (1- from) from (string ch ?\t)))
    from))

(defun tai-viet-compose-region (from to)
  "Compose Tai Viet characters in the region between FROM and TO."
  (decompose-region from to)
  (let ((normal-rule '(Br . Bl))
	(tone-rule '(tr . bl))
	(prev-viet nil)
	ch info pos components overhang)
    (while (< from to) 
      (or ch
	  (setq ch (char-after from)
		info (aref tai-viet-glyph-info ch)))
      (setq from (1+ from))
      (if (not info)
	  (setq prev-viet nil
		ch nil)
	(if (memq info '(combining-vowel combining-tone))
	    (progn
	      ;; Display this as a spacing glyph.
	      (compose-region (1- from) from (string ?\t ch))
	      (setq prev-viet t
		    ch nil))
	  (setq pos (1- from)
		components ch
		overhang (if (eq info 'right-overhang)
			     'right-overhang
			   (if (and (not prev-viet) (eq info 'left-overhang))
			       'left-overhang))
		prev-viet t
		ch nil)
	  (if (and (< from to)
		   (setq ch (char-after from)
			 info (aref tai-viet-glyph-info ch)))
	      (if (memq info '(combining-vowel combining-tone))
		  (progn
		    (setq components
			  (list components normal-rule ch)
			  from (1+ from)
			  ch nil)
		    (if (and (< from to)
			     (setq ch (char-after from)
				   info (aref tai-viet-glyph-info ch))
			     (eq info 'combining-tone))
			(setq components (nconc components
						(list tone-rule ch))
			      from (1+ from)))
		    (if (eq overhang 'left-overhang)
			(setq components (cons ?\t
					       (cons normal-rule components)))
		      (if (and (eq overhang 'right-overhang)
			       (>= from to))
			  (setq components (nconc components
						  (list normal-rule ?\t)))))
		    (compose-region pos from components))
		(if (eq overhang 'left-overhang)
		    (compose-region pos from (string ?\t components))))
	    (if (eq overhang 'left-overhang)
		(compose-region pos from (string ?\t components))
	      (if (and (eq overhang 'right-overhang) (>= from to))
		  (compose-region pos from (string components ?\t))))))))
    from))


;;;###autoload
(defun tai-viet-composition-function (from to font-object string)
  (if string
      (if (string-match tai-viet-re string from)
	  (tai-viet-compose-string from (match-end 0) string))
    (goto-char from)
    (if (looking-at tai-viet-re)
	(tai-viet-compose-region from (match-end 0)))))

;;
(provide 'tai-viet-util)

;; arch-tag: a45ac3fc-07d0-44d5-8841-2ebea7e11f5b