view msdos/sed1v2.inp @ 32983:a7eb5c4fe0ba

(find-file-not-found-set-buffer-file-coding-system): Don't call find-buffer-file-type-coding-system. Instead, just set eol-type to -unix if inhibit-eol-conversion is in effect, or if the file is on an untranslated filesystem. (add-untranslated-filesystem): Use "D" instead of "f" inside interactive.

# -sed1v2.inp-----------------------------------------------------------
# Configuration script for src/Makefile under DJGPP v2.x
# ----------------------------------------------------------------------
s/^#.*//
s/^[ \f\t][ \f\t]*$//
s/^ /	/
s/\.h\.in/.h-in/
/^	LC_ALL=C \.\/temacs/i\
	stubedit temacs.exe minstack=100k
/^	LC_ALL=C \.\/temacs/s/LC_ALL=C/set &;/
/^MAKE *=/s/^/# /
/^SHELL *=/s/^/# /
/^srcdir *=/s/@[^@\n]*@/./
/^VPATH *=/s/@[^@\n]*@/./
/^CC *=/s/@[^@\n]*@/gcc/
/^CPP *=/s/@[^@\n]*@/gcc -e/
/^CFLAGS *=/s/@[^@\n]*@/-O2 -gcoff/
/^CPPFLAGS *=/s/@[^@\n]*@//
/^LDFLAGS *=/s/@[^@\n]*@//
/^LIBS *=/s/@[^@\n]*@//
/^LIBOBJS *=/s/@[^@\n]*@/getloadavg.o/
/^GETLOADAVG_LIBS *=/s/@[^@\n]*@//
/^LIBSOUND *=/s/@LIBSOUND@//
/^LN_S *=/s/@[^@\n]*@/ln -s/
/^M_FILE *=/s!@[^@\n]*@!m/intel386.h!
/^S_FILE *=/s!@[^@\n]*@!s/msdos.h!
/^@SET_MAKE@$/s/@SET_MAKE@//
/^.\${libsrc}make-docfile.*>/s!make-docfile!make-docfile -o ../etc/DOC!
/^.\${libsrc}make-doc/s!>.*$!!
/^[ 	]*$/d
/^temacs:/s/prefix-args//
/^temacs:/s/stamp-oldxmenu//
/^	#/d