view admin/nt/makedist.bat @ 86277:a8503aaf3a82

* frame.el (msdos-mouse-p): * files.el (msdos-long-file-names, w32-long-file-name) (msdos-long-file-names): * term/mac-win.el (mac-code-convert-string, mac-coerce-ae-data) (mac-resume-apple-event, mac-font-panel-mode) (mac-atsu-font-face-attributes, mac-ae-set-reply-parameter) (mac-clear-font-name-table): * term/pc-win.el (msdos-remember-default-colors) (w16-set-clipboard-data, w16-get-clipboard-data): * term/w32-win.el (w32-send-sys-command, w32-select-font) (set-message-beep): * net/browse-url.el (w32-shell-execute): * dos-fns.el (int86, msdos-long-file-names): * dos-w32.el (default-printer-name): Undo previous change.

@echo off

rem Copyright (C) 2001, 2002, 2003, 2004, 2005, 2006, 2007
rem   Free Software Foundation, Inc.
rem
rem Cannot use brackets in andrewi's email below because
rem older Windows shells will treat that as redirection.
rem
rem Author: Andrew Innes [e-mail]
rem
rem This file is part of GNU Emacs.
rem
rem GNU Emacs is free software; you can redistribute it and/or modify
rem it under the terms of the GNU General Public License as published by
rem the Free Software Foundation; either version 3, or (at your option)
rem any later version.
rem
rem GNU Emacs is distributed in the hope that it will be useful,
rem but WITHOUT ANY WARRANTY; without even the implied warranty of
rem MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
rem GNU General Public License for more details.
rem
rem You should have received a copy of the GNU General Public License
rem along with GNU Emacs; see the file COPYING.  If not, write to the
rem Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
rem Boston, MA 02110-1301, USA.

if (%3) == () goto usage
if not (%4) == () goto %4

:bin

echo Create full bin distribution
copy %3\README.W32 emacs-%1\README.W32
rem Info-ZIP zip seems to be broken on Windows.
rem It always writes to zip.zip and treats the zipfile argument as one
rem of the files to go in it.
rem zip -9 -r %2-bin-i386 emacs-%1/BUGS emacs-%1/COPYING emacs-%1/README emacs-%1/README.W32 emacs-%1/INSTALL emacs-%1/bin emacs-%1/etc emacs-%1/info emacs-%1/lisp emacs-%1/leim -x emacs.mdp *.pdb *.opt *~ CVS
7z a -tZIP -mx=9 -xr!emacs.mdp -xr!*.pdb -xr!*.opt -xr!*~ -xr!CVS -xr!.arch-inventory %2-bin-i386.zip emacs-%1/BUGS emacs-%1/COPYING emacs-%1/README emacs-%1/README.W32 emacs-%1/INSTALL emacs-%1/bin emacs-%1/etc emacs-%1/info emacs-%1/lisp emacs-%1/leim emacs-%1/site-lisp
del emacs-%1\README.W32
if not (%4) == () goto end

:barebin
echo Create archive with just the basic binaries and generated files
echo (the user needs to unpack the full source distribution for
echo  everything else)
copy %3\README.W32 emacs-%1\README.W32
copy %3\dump.bat emacs-%1\bin\dump.bat
rem Info-ZIP zip seems to be broken on Windows.
rem It always writes to zip.zip and treats the zipfile argument as one
rem of the files to go in it.
rem zip -9 -r %2-barebin-i386.zip emacs-%1/README.W32 emacs-%1/bin emacs-%1/etc/DOC-X emacs-%1/COPYING
7z a -tZIP -mx=9 %2-barebin-i386.zip emacs-%1/README.W32 emacs-%1/bin emacs-%1/etc/DOC-X emacs-%1/COPYING
del emacs-%1\README.W32
if not (%4) == () goto end

goto end

:usage
echo Generate source and binary distributions of emacs.
echo Usage: %0 emacs-version dist-basename distfiles [bin,barebin]
echo   (e.g., %0 19.34 emacs-19.34.5 d:\andrewi\distfiles)
:end

goto skipArchTag
   arch-tag: 6e2ddd92-c1c9-4992-b6b5-207aaab72f68
:skipArchTag