view msdos/sed1v2.inp @ 92551:a9c1d203dd4a

(calendar-version): Use emacs-version and make it obsolete. Move to end. (calendar-offset, view-diary-entries-initially) (mark-diary-entries-in-calendar) (calendar-remove-frame-by-deleting) (view-calendar-holidays-initially, all-hebrew-calendar-holidays) (all-christian-calendar-holidays, all-islamic-calendar-holidays) (all-bahai-calendar-holidays, calendar-load-hook) (initial-calendar-window-hook, today-visible-calendar-hook) (today-invisible-calendar-hook, calendar-move-hook) (diary-nonmarking-symbol, hebrew-diary-entry-symbol) (islamic-diary-entry-symbol, bahai-diary-entry-symbol) (diary-include-string, sexp-diary-entry-symbol) (abbreviated-calendar-year, american-date-diary-pattern) (european-date-diary-pattern, european-calendar-display-form) (american-calendar-display-form, print-diary-entries-hook) (list-diary-entries-hook, diary-hook, diary-display-hook) (nongregorian-diary-listing-hook, mark-diary-entries-hook) (nongregorian-diary-marking-hook, diary-list-include-blanks) (holidays-in-diary-buffer, general-holidays, oriental-holidays) (local-holidays, other-holidays, hebrew-holidays-1) (hebrew-holidays-2, hebrew-holidays-3, hebrew-holidays-4) (hebrew-holidays, christian-holidays, islamic-holidays) (bahai-holidays, solar-holidays, calendar-setup) (calendar-week-start-day): Remove autoload cookies. (diary-glob-file-regexp-prefix): Doc fix. (calendar-goto-info-node): Use `info' rather than `Info-find-node'. (Info-find-emacs-command-nodes, Info-find-node): Remove declarations. (calendar-week-start-day, calendar-debug-sexp): Move to start.

# -sed1v2.inp-----------------------------------------------------------
# Configuration script for src/Makefile under DJGPP v2.x
# ----------------------------------------------------------------------
#
# Copyright (C) 1996, 1997, 1999, 2000, 2001, 2002, 2003, 2004,
#   2005, 2006, 2007, 2008  Free Software Foundation, Inc.
#
# This file is part of GNU Emacs.
#
# This file is free software; as a special exception, the author gives
# unlimited permission to copy and/or distribute it, with or without
# modifications, as long as this notice is preserved.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
#
# ----------------------------------------------------------------------
s/^#.*//
s/^[ \f\t][ \f\t]*$//
s/^ /	/
s/\.h\.in/.h-in/
/^	LC_ALL=C \$(RUN_TEMACS)/i\
	stubedit temacs.exe minstack=100k
/^	LC_ALL=C.*\$(RUN_TEMACS)/s/LC_ALL=C/set &;/
/^MAKE *=/s/^/# /
/^SHELL *=/s/^/# /
/^srcdir *=/s/@[^@\n]*@/./
/^VPATH *=/s/@[^@\n]*@/./
/^CC *=/s/@[^@\n]*@/gcc/
/^CPP *=/s/@[^@\n]*@/gcc -e/
/^CFLAGS *=/s/@[^@\n]*@/-O2 -gcoff/
/^CPPFLAGS *=/s/@[^@\n]*@//
/^LDFLAGS *=/s/@[^@\n]*@//
/^LIBS *=/s/@[^@\n]*@//
/^LIBOBJS *=/s/@[^@\n]*@/getloadavg.o/
/^GETLOADAVG_LIBS *=/s/@[^@\n]*@//
/^LIBSOUND *=/s/@LIBSOUND@//
/^CFLAGS_SOUND *=/s/@CFLAGS_SOUND@//
/^RSVG_LIBS *=/s/@RSVG_LIBS@//
/^RSVG_CFLAGS *=/s/@RSVG_CFLAGS@//
/^EXEEXT *=/s/@EXEEXT@//
/^LN_S *=/s/@[^@\n]*@/ln -s/
/^M_FILE *=/s!@[^@\n]*@!m/intel386.h!
/^S_FILE *=/s!@[^@\n]*@!s/msdos.h!
/^@SET_MAKE@$/s/@SET_MAKE@//
/^.\${libsrc}make-docfile.*>/s!make-docfile!make-docfile -o ../etc/DOC!
/^.\${libsrc}make-doc/s!>.*$!!
/^[ 	]*$/d
/^temacs:/s/prefix-args//
/^temacs:/s/stamp-oldxmenu//
/^	mv \.\/\.gdbinit/d
/^	if test -f/c\
	command.com /c if exist .gdbinit rm -f _gdbinit
/^	else mv \.\/\.gdbinit/d
/^	#/d
/^	cd.*make-docfile/s!$!; cd ${dot}${dot}/src!
s/bootstrap-emacs/b-emacs/
s/bootstrap-temacs/b-temacs/
s/bootstrap-doc/b-doc/
/rm -f bootstrap-emacs/s/b-emacs/b-emacs b-emacs.exe/
/^	els=/c\
	${libsrc}make-docfile -o ${etc}DOC -d ${srcdir} ${SOME_MACHINE_LISP:.elc=.el} ${shortlisp:.elc=.el} ${SOME_MACHINE_OBJECTS} ${obj}
s/echo.*buildobj.lst/dj&/
/^	mv -f emacs/a\
	stubify b-emacs\
	stubedit b-emacs.exe minstack=1024k\
	rm -f emacs.exe temacs.exe emacs
/^	rm -f/s/\\#/#/

# arch-tag: c7e3aacb-4162-460e-99f9-4252bca68d2c