view etc/ETAGS.EBNF @ 67483:b6000aca7291

Set VER to `22.1'. (Basic editing): Explain how to use localized versions of the Tutorial. Mention that `C-h r' displays the manual. Delete obsolete WWW link to an Emacs 18 tutorial. (Getting a printed manual): Point to the new locations of the manuals on the GNU Web site. (Emacs Lisp documentation): Explain that the Emacs Lisp manual is available via Info (it was previously distributed separately). (Installing Texinfo documentation): The latest version of Texinfo is 4.8, not 4.0. (Informational files for Emacs): COPYING is the GNU General Public License, not the Emacs General Public License. (Informational files for Emacs): Delete obsolete link to the GNUinfo pages as they have been removed from the GNU Web site. (New in Emacs 22): New node. (Setting up a customization file): Say that most packages support Customize nowadays. (Colors on a TTY): Delete reference to instructions on how to enable syntax highlighting, it is now enabled by default. (Turning on abbrevs by default): Emacs now reads the abbrevs file at startup automatically. (Controlling case sensitivity): Mention `M-c' in isearch. (Using an already running Emacs process): Emacs now creates the socket in `/tmp/emacsUID'. Fix typos. Change default location of gnuserv. As emacsclient can now run Lisp code as well, delete a sentence praising gnuserv for that. Simplify description of how the client/server operation works. (Compiler error messages): Delete obsolete text (compile.el has been rewritten). (Indenting switch statements): Fix typo. (Matching parentheses): Simplify setup instructions, mention the menu bar item in the Options menu. (Repeating a command as many times as possible): Mention `C-x e'. (Going to a line by number): Mention new keymap and bindings `M-g M-g', `M-g M-p' and `M-g M-n'. (Turning on syntax highlighting): Now on by default. Simplify. (Replacing highlighted text): Use `1', not `t'. (Problems with very large files): The maximum size is now 256MB on 32-bit machines. (^M in the shell buffer): Mention `comint-process-echoes'. (Emacs for Apple computers): Emacs 22 has native support for Mac OS X. (Translating names to IP addresses): Delete node. (Binding keys to commands): Fix typo. (SPC no longer completes file names): New node. (MIME with Emacs mail packages): Delete section about the Emacs MIME FAQ (it's not reachable anymore).

-*- indented-text -*-

This file contains two sections:

1) An EBNF (Extended Backus-Naur Form) description of the format of
    the tags file created by etags.c and interpreted by etags.el;
2) A discussion of tag names and implicit tag names.

====================== 1) EBNF tag file description =====================

Productions created from current behaviour to aid extensions
Francesco Potorti` <[e-mail]> 2002
----------------

FF ::= #x0c				   /* tag section starter */

LF ::= #x0a				   /* line terminator */

DEL ::= #x7f				   /* pattern terminator */

SOH ::= #x01				   /* name terminator */

regchar ::= [^#x0a#x0c#x7f]		   /* regular character */

regstring ::= { regchar }		   /* regular string */

unsint ::= [0-9] { [0-9] }		   /* non-negative integer */



tagfile ::= { tagsection }		   /* a tags file */

tagsection ::= FF LF ( includesec | regularsec ) LF

includesec ::= filename ",include" [ LF fileprop ]

regularsec ::= filename "," [ unsint ] [ LF fileprop ] { LF tag }

filename ::= regchar regstring		   /* a file name */

fileprop ::= "(" regstring ")"		   /* an elisp alist */

tag ::= directtag | patterntag

directtag ::= DEL realposition		   /* no pattern */

patterntag ::= pattern DEL [ tagname SOH ] position

pattern ::= regstring			   /* a tag pattern */

tagname ::= regchar regstring		   /* a tag name */

position ::= realposition | "," 	   /* charpos,linepos */

realposition ::= "," unsint | unsint "," | unsint "," unsint

==================== end of EBNF tag file description ====================



======================= 2) discussion of tag names =======================

- WHAT ARE TAG NAMES
Tag lines in a tags file are usually made from the above defined pattern
and by an optional tag name.  The pattern is a string that is searched
in the source file to find the tagged line.

- WHY TAG NAMES ARE GOOD
When a user looks for a tag, Emacs first compares the tag with the tag
names contained in the tags file.  If no match is found, Emacs compares
the tag with the patterns.  The tag name is then the preferred way to
look for tags in the tags file, because when the tag name is present
Emacs can find a tag faster and more accurately.  These tag names are
part of tag lines in the tags file, so we call them "explicit".

- WHY IMPLICIT TAG NAMES ARE EVEN BETTER
When a tag line has no name, but a name can be deduced from the pattern,
we say that the tag line has an implicit tag name.  Often tag names are
redundant; this happens when the name of a tag is an easily guessable
substring of the tag pattern.  We define a set of rules to decide
whether it is possible to deduce the tag name from the pattern, and make
an unnamed tag in those cases.  The name deduced from the pattern of an
unnamed tag is the implicit name of that tag.
  When the user looks for a tag, and Emacs finds no explicit tag names
that match it, Emacs then looks for an tag whose implicit tag name
matches the request.  etags.c uses implicit tag names when possible, in
order to reduce the size of the tags file.
  An implicit tag name is deduced from the pattern by discarding the
last character if it is one of ` \f\t\n\r()=,;', then taking all the
rightmost consecutive characters in the pattern which are not one of
those.

===================== end of discussion of tag names =====================