view lisp/tabify.el @ 94515:b64e3d5c5852

(make_window): Initialize resize_proportionally. (enlarge_window): Temporarily set resize_proportionally to make sure that shrink_windows does scale the window proportionally. (shrink_windows): When window has resize_proportionally set try to shrink it proportionally by stealing from other windows. (struct saved_window, Fset_window_configuration) (compare_window_configurations): Handle resize_proportionally. (WINDOW_TOTAL_SIZE): New macro. (window_min_size, shrink_windows, size_window): Use it. (check_min_window_sizes): Removed. Invalid values of window-min-height|width are handled by window_min_size_2 now. (size_window, Fsplit_window, enlarge_window) (adjust_window_trailing_edge, grow_mini_window): Don't call check_min_window_sizes. (window_min_size_2, window_min_size_1, window_min_size): New argument safe_p for retrieving "safe" minimum sizes. (Fdisplay_buffer, Fsplit_window, enlarge_window): (adjust_window_trailing_edge, grow_mini_window): Adjust arguments of window_min_size... functions. (shrink_windows): Argument min_size removed. New argument safe_p allows shrinking windows to their safe minimum sizes. Calculate minimum size and decide whether a window shall be deleted for each window individually. (size_window): When nodelete_p equals 2, tell shrink_windows to delete windows only if their new minimum size is no more safe. (shrink_window_lowest_first): Call window_min_size_1 to make sure to preserve modeline of bottom-most window when resizing the minibuffer. (Fset_window_configuration, Fcurrent_window_configuration) (compare_window_configurations): Do not handle window-min-height|width any more. (syms_of_window): Clarify window-min-height|width doc-strings.

;;; tabify.el --- tab conversion commands for Emacs

;; Copyright (C) 1985, 1994, 2001, 2002, 2003, 2004,
;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.

;; Maintainer: FSF

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 3, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
;; Boston, MA 02110-1301, USA.

;;; Commentary:

;; Commands to optimize spaces to tabs or expand tabs to spaces in a region
;; (`tabify' and `untabify').  The variable tab-width does the obvious.

;;; Code:

;;;###autoload
(defun untabify (start end)
  "Convert all tabs in region to multiple spaces, preserving columns.
Called non-interactively, the region is specified by arguments
START and END, rather than by the position of point and mark.
The variable `tab-width' controls the spacing of tab stops."
  (interactive "r")
  (save-excursion
    (save-restriction
      (narrow-to-region (point-min) end)
      (goto-char start)
      (while (search-forward "\t" nil t)	; faster than re-search
	(forward-char -1)
	(let ((tab-beg (point))
	      (indent-tabs-mode nil)
	      column)
	  (skip-chars-forward "\t")
	  (setq column (current-column))
	  (delete-region tab-beg (point))
	  (indent-to column))))))

(defvar tabify-regexp " [ \t]+"
  "Regexp matching whitespace that tabify should consider.
Usually this will be \" [ \\t]+\" to match a space followed by whitespace.
\"^\\t* [ \\t]+\" is also useful, for tabifying only initial whitespace.")

;;;###autoload
(defun tabify (start end)
  "Convert multiple spaces in region to tabs when possible.
A group of spaces is partially replaced by tabs
when this can be done without changing the column they end at.
Called non-interactively, the region is specified by arguments
START and END, rather than by the position of point and mark.
The variable `tab-width' controls the spacing of tab stops."
  (interactive "r")
  (save-excursion
    (save-restriction
      ;; Include the beginning of the line in the narrowing
      ;; since otherwise it will throw off current-column.
      (goto-char start)
      (beginning-of-line)
      (narrow-to-region (point) end)
      (goto-char start)
      (let ((indent-tabs-mode t))
        (while (re-search-forward tabify-regexp nil t)
          ;; The region between (match-beginning 0) and (match-end 0) is just
          ;; spacing which we want to adjust to use TABs where possible.
          (let ((end-col (current-column))
                (beg-col (save-excursion (goto-char (match-beginning 0))
                                         (skip-chars-forward "\t")
                                         (current-column))))
            (if (= (/ end-col tab-width) (/ beg-col tab-width))
                ;; The spacing (after some leading TABs which we wouldn't
                ;; want to touch anyway) does not straddle a TAB boundary,
                ;; so it neither contains a TAB, nor will we be able to use
                ;; a TAB here anyway: there's nothing to do.
                nil
              (delete-region (match-beginning 0) (point))
              (indent-to end-col))))))))

(provide 'tabify)

;; arch-tag: c83893b1-e0cc-4e57-8a09-73fd03466416
;;; tabify.el ends here