view lisp/forms-d2.el @ 28223:b888c69e8bf0

All codes rewritten or adjusted for the change of fontset implementation. Now fontset is represented by char table. (Vglobal_fontset_alist, font_idx_temp, my_strcasetbl): Variables removed. (my_strcasecmp): Function removed. (Vfontset_table, next_fontset_id, Vdefault_fontset): New variables. (AREF, ASIZE): New macros. (FONTSET_FROM_ID, FONTSET_ID, FONTSET_NAME, FONTSET_FRAME, FONTSET_ASCII, FONTSET_BASE, BASE_FONTSET_P, FONTSET_REF, FONTSET_REF_VIA_BASE, FONTSET_SET): New macros. (fontset_ref, fontset_ref_via_base, fontset_set, make_fontset, fontset_id_valid_p, font_family_registry, fontset_name, fontset_ascii, free_face_fontset, face_suitable_for_char_p, face_for_char, make_fontset_for_ascii_face, fontset_font_pattern): New functions. (fs_load_font): New arg FACE. Caller changed. (fs_query_fontset): Argument changed. Caller changed. (Fquery_fontset): call fs_query_fontset. (fs_register_fontset, alloc_fontset_data, free_fontset_data): Functions removed. (clear_fontset_elements, check_registry_encoding, check_fontset_name): New functions. (syms_of_fontset): Set char-table-extra-slots property of fontset to 3. Staticpro and initialize Vfontset_table and Vdefault_fontset. Defsubr fontset_font and fontset_list.

;;; forms-d2.el --- demo forms-mode

;; Author: Johan Vromans <[e-mail]>
;; Created: 1989

;; This sample forms exploit most of the features of forms mode.

;; Set the name of the data file.
(setq forms-file "forms-d2.dat")

;; Use 'forms-enumerate' to set field names and number thereof.
(setq forms-number-of-fields
      (forms-enumerate
       '(arch-newsgroup			; 1
	 arch-volume			; 2
	 arch-issue			; and ...
	 arch-article			; ... so
	 arch-shortname			; ... ... on
	 arch-parts
	 arch-from
	 arch-longname
	 arch-keywords
	 arch-date
	 arch-remarks)))

;; The following functions are used by this form for layout purposes.
;;
(defun arch-tocol (target &optional fill)
  "Produces a string to skip to column TARGET. Prepends newline if needed.
The optional FILL should be a character, used to fill to the column."
  (if (null fill)
      (setq fill ? ))
  (if (< target (current-column))
      (concat "\n" (make-string target fill))
    (make-string (- target (current-column)) fill)))
;;
(defun arch-rj (target field &optional fill) 
  "Produces a string to skip to column TARGET minus the width of field FIELD.
Prepends newline if needed. The optional FILL should be a character,
used to fill to the column."
  (arch-tocol (- target (length (nth field forms-fields))) fill))

;; Record filters.
;;
(defun arch-new-record-filter (the-record)
  "Form a new record with some defaults."
  (aset the-record arch-from (user-full-name))
  (aset the-record arch-date (current-time-string))
  the-record				; return it
)
(setq forms-new-record-filter 'arch-new-record-filter)

;; The format list.
(setq forms-format-list
     (list
       "====== Public Domain Software Archive ======\n\n"
       arch-shortname
       " - "			arch-longname
       "\n\n"
       "Article: "		arch-newsgroup
       "/"			arch-article
       " "
       '(arch-tocol 40)
       "Issue: "		arch-issue
       " "
       '(arch-rj 73 10)
       "Date: "			arch-date
       "\n\n"
       "Submitted by: "		arch-from
       "\n"
       '(arch-tocol 79 ?-)
       "\n"
       "Keywords: "		arch-keywords
       "\n\n"
       "Parts: "		arch-parts
       "\n\n====== Remarks ======\n\n"
       arch-remarks
     ))

;; That's all, folks!