view lisp/play/studly.el @ 57191:bd5d1158ebcf

(ido-choice-list): New dynamic var for `list' context. (ido-context-switch-command): New dynamic var. (ido-define-mode-map): Generalize switch between file/buffer contexts. (ido-read-internal): Handle new `list' context. Handle insert-buffer and insert-file ido-exit values. (ido-buffer-internal): New arg switch-cmd. Use it to setup ido-context-switch-command. Handle insert-file ido-exit value. (ido-read-buffer): Set ido-context-switch-command to 'ignore unless it is already bound by caller. (ido-file-internal): New arg switch-cmd. Use it to setup ido-context-switch-command. Handle insert-buffer ido-exit value. (ido-enter-insert-buffer, ido-enter-insert-file): New commands used for context switching. (ido-all-completions): Handle new `list' context. (ido-make-choice-list): Return choices for `list' context. (ido-find-file-in-dir, ido-display-file, ido-write-file) (ido-display-buffer, ido-kill-buffer): Disable context switching. (ido-insert-buffer, ido-insert-file): Setup context switching. (ido-exhibit): Handle `list' context. (ido-read-file-name): Disable context switching. Handle fallback. (ido-read-directory-name): Disable context switching. (ido-completing-read): New defun like completing-read. Setup and use new `list' context.

;;; studly.el --- StudlyCaps (tm)(r)(c)(xxx)

;;; This is in the public domain, since it was distributed
;;; by its author without a copyright notice in 1986.

;; This file is part of GNU Emacs.

;; Maintainer: FSF
;; Keywords: games

;;; Commentary:

;; Functions to studlycapsify a region, word, or buffer.  Possibly the
;; esoteric significance of studlycapsification escapes you; that is,
;; you suffer from autostudlycapsifibogotification.  Too bad.

;;; Code:

;;;###autoload
(defun studlify-region (begin end)
  "Studlify-case the region."
  (interactive "*r")
  (save-excursion
    (goto-char begin)
    (setq begin (point))
    (while (and (<= (point) end)
		(not (looking-at "\\W*\\'")))
      (forward-word 1)
      (backward-word 1)
      (setq begin (max (point) begin))
      (forward-word 1)
      (let ((offset 0)
	    (word-end (min (point) end))
	    c)
	(goto-char begin)
	(while (< (point) word-end)
	  (setq offset (+ offset (following-char)))
	  (forward-char 1))
	(setq offset (+ offset (following-char)))
	(goto-char begin)
	(while (< (point) word-end)
	  (setq c (following-char))
	  (if (and (= (% (+ c offset) 4) 2)
		   (let ((ch (following-char)))
		     (or (and (>= ch ?a) (<= ch ?z))
			 (and (>= ch ?A) (<= ch ?Z)))))
	      (progn
		(delete-char 1)
		(insert (logxor c ? ))))
	  (forward-char 1))
	(setq begin (point))))))

;;;###autoload
(defun studlify-word (count)
  "Studlify-case the current word, or COUNT words if given an argument."
  (interactive "*p")
  (let ((begin (point)) end rb re)
    (forward-word count)
    (setq end (point))
    (setq rb (min begin end) re (max begin end))
    (studlify-region rb re)))

;;;###autoload
(defun studlify-buffer ()
  "Studlify-case the current buffer."
  (interactive "*")
  (studlify-region (point-min) (point-max)))

(provide 'studly)

;;; arch-tag: 0dbf5a60-d2e6-48c2-86ae-77fc8575ac67
;;; studly.el ends here