view m4/getopt.m4 @ 105975:be1ec2846896

2009-11-13 Carsten Dominik <[e-mail]> * org.texi: Removed @Ie, @ie, @Eg, @eg macros. 2009-11-13 James TD Smith <[e-mail]> * org.texi (Column attributes): Add the new age summary operators. Also, mention the fact you can only use one summary operator per property. 2009-11-13 John Wiegley <[e-mail]> * org.texi (Tracking your habits): Added a new section in the manual about how to track habits. (Resolving idle time): Added a section on how idle and dangling clocks are resolved. 2009-11-13 Carsten Dominik <[e-mail]> * org.texi (Agenda commands): Document the new `i' command. (Inserting deadline/schedule): Document logging changes of scheduling and deadline times stamps. (In-buffer settings): Document the in-buffer keywords for logging changes of scheduling and deadline times stamps. (Structure editing, Plain lists): Document indentation cycling in empty entries with TAB. (Archiving): Document the default archiving command. (Moving subtrees): Document the new keys for archiving. (Internal archiving): Fix incorrect key. (Agenda commands): Document the TODO set switching commands. (Agenda commands): Document the new archiving keys. (Clocking work time): Better description on how to save and restore a clock. (Resolving idle time): Mention the x11idle program to get true idleness also under X11. (Resolving idle time): Use @kbd instead of @key for normal letters, because this is how he rest of the manual does this. (Pushing to MobileOrg): Mention that `org-directory' should be set. (Agenda commands): Document that SPC is a filter for any tag. (Search view): Renamed from "Keyword search". (Capure): New chapter. (Markup): New chapter. (Links in HTML export, Images in HTML export): Extend the section titles. (Images in HTML export): Document the align option. (Text areas in HTML export): Extend the section title. (Images in LaTeX export): Explain image placement in LaTeX.

# getopt.m4 serial 10
dnl Copyright (C) 2002,2003,2004,2005,2006,2007 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.

# The getopt module assume you want GNU getopt, with getopt_long etc,
# rather than vanilla POSIX getopt.  This means your your code should
# always include <getopt.h> for the getopt prototypes.

AC_DEFUN([gl_GETOPT_SUBSTITUTE],
[
  AC_LIBOBJ([getopt])
  AC_LIBOBJ([getopt1])
  gl_GETOPT_SUBSTITUTE_HEADER
  gl_PREREQ_GETOPT
])

AC_DEFUN([gl_GETOPT_SUBSTITUTE_HEADER],
[
  GETOPT_H=getopt.h
  AC_DEFINE([__GETOPT_PREFIX], [[rpl_]],
    [Define to rpl_ if the getopt replacement functions and variables
     should be used.])
  AC_SUBST([GETOPT_H])
])

AC_DEFUN([gl_GETOPT_CHECK_HEADERS],
[
  GETOPT_H=
  AC_CHECK_HEADERS([getopt.h], [], [GETOPT_H=getopt.h])
  if test -z "$GETOPT_H"; then
    AC_CHECK_FUNCS([getopt_long_only], [], [GETOPT_H=getopt.h])
  fi

  dnl BSD getopt_long uses an incompatible method to reset option processing,
  dnl and (as of 2004-10-15) mishandles optional option-arguments.
  if test -z "$GETOPT_H"; then
    AC_CHECK_DECL([optreset], [GETOPT_H=getopt.h], [], [#include <getopt.h>])
  fi

  dnl Solaris 10 getopt doesn't handle `+' as a leading character in an
  dnl option string (as of 2005-05-05).
  if test -z "$GETOPT_H"; then
    AC_CACHE_CHECK([for working GNU getopt function], [gl_cv_func_gnu_getopt],
      [AC_RUN_IFELSE(
	[AC_LANG_PROGRAM([#include <getopt.h>],
	   [[
	     char *myargv[3];
	     myargv[0] = "conftest";
	     myargv[1] = "-+";
	     myargv[2] = 0;
	     return getopt (2, myargv, "+a") != '?';
	   ]])],
	[gl_cv_func_gnu_getopt=yes],
	[gl_cv_func_gnu_getopt=no],
	[dnl cross compiling - pessimistically guess based on decls
	 dnl Solaris 10 getopt doesn't handle `+' as a leading character in an
	 dnl option string (as of 2005-05-05).
	 AC_CHECK_DECL([getopt_clip],
	   [gl_cv_func_gnu_getopt=no], [gl_cv_func_gnu_getopt=yes],
	   [#include <getopt.h>])])])
    if test "$gl_cv_func_gnu_getopt" = "no"; then
      GETOPT_H=getopt.h
    fi
  fi
])

AC_DEFUN([gl_GETOPT_IFELSE],
[
  AC_REQUIRE([gl_GETOPT_CHECK_HEADERS])
  AS_IF([test -n "$GETOPT_H"], [$1], [$2])
])

AC_DEFUN([gl_GETOPT], [gl_GETOPT_IFELSE([gl_GETOPT_SUBSTITUTE])])

# Prerequisites of lib/getopt*.
AC_DEFUN([gl_PREREQ_GETOPT], [:])

ifelse(dnl	Do not change this comment
   arch-tag: 6c64a021-551c-4a7f-9c63-cd7e1ce54707
)dnl