view msdos/sed1.inp @ 29422:be5a54fc840d

(sh-symbol-list, sh-number-or-symbol-list) (sh-re-done): Use defconst. (sh-indent-supported-here, sh-electric-rparen-needed-here): Add defvar. (sh-help-string-for-variable, sh-guess-basic-offset): Don't quote lambdas. (sh-electric-rparen, sh-electric-hash, sh-search-word): Docstring typo. (sh-regexp-for-done, sh-kw-alist, sh-kw): Moved to before their use.

# -sed1.inp-------------------------------------------------------------
# Configuration script for src/makefile
# ----------------------------------------------------------------------
#
# In case src/Makefile needs to rebuild `make-doc.exe' (might happen under
# Windows 95), make sure it gets built with commands that DOS
# understands (one command per line).
s/^#.*//
s/^[ \f\t][ \f\t]*$//
s/^ /	/
s/\.h\.in/.h-in/
s!^	\./temacs!	go32 temacs!
s!/bin/sh!command.com!
/^MAKE *=/s/^/# /
/^SHELL *=/s/^/# /
/^srcdir *=/s/@[^@\n]*@/./
/^VPATH *=/s/@[^@\n]*@/./
/^CC *=/s/@[^@\n]*@/gcc/
/^CPP *=/s/@[^@\n]*@/gcc -e/
/^CFLAGS *=/s/@[^@\n]*@/-O2 -g/
/^LIBS *=/s/@[^@\n]*@//
/^LIBOBJS *=/s/@[^@\n]*@//
/^LN_S *=/s/@[^@\n]*@/ln -s/
/^M_FILE *=/s!@[^@\n]*@!m/intel386.h!
/^S_FILE *=/s!@[^@\n]*@!s/msdos.h!
/^@SET_MAKE@$/s/@SET_MAKE@//
/^.\${libsrc}make-docfile.*>/s!make-docfile!make-doc.exe -o ../etc/DOC!
/^.\${libsrc}make-doc/s!>.*$!!
/^\${libsrc}make-docfile:/c\
${libsrc}make-doc.exe:\
	cd ..\
	cd lib-src\
	$(MAKE) ${MFLAGS} make-docfile -W make-docfile.c\
	cd ..\
	cd src
/^	cd \${libsrc}; \${MAKE} \${MFLAGS} make-docfile/d
/\${libsrc}make-docfile/s/-docfile[ 	]/-doc.exe /
/^[ 	]*$/d
/^temacs:/s/prefix-args//
/^temacs:/s/stamp-oldxmenu//
/^	#/d