view msdos/sed1.inp @ 96833:c06568fd3844

* s/usg5-4.h (LIBS_SYSTEM): Remove, system for which this was added not supported anymore. * s/usg5-4-2.h (LIBS_SYSTEM): * s/sol2.h (LIBS_SYSTEM): Do not undefine. * s/netbsd.h (GETPGRP_NO_ARG, N_TRELOFF): * s/lynxos.h (GETPGRP_NO_ARG): * s/hpux10-20.h (NO_SIOCTL_H): * s/gnu.h (GETPGRP_NO_ARG): * s/gnu-linux.h (NO_SIOCTL_H): * s/freebsd.h (GETPGRP_NO_ARG, N_TRELOFF): * s/cygwin.h (GETPGRP_NO_ARG): * s/irix6-5.h (LIBS_SYSTEM, GETPGRP_NO_ARG): Remove, unused. (C_DEBUG_SWITCH): Remove duplicate definition. * m/ibms390.h: Remove boilerplate comments. * sysdep.c (closedir): Use SOLARIS2 instead of sun && USG5_4. * process.c (HAVE_SERIAL): Consolidate ifdefs. (wait_reading_process_output): Remove code for SunOS, platform not supported anymore. Use SOLARIS2 instead of sun.

# -sed1.inp-------------------------------------------------------------
# Configuration script for src/makefile
# ----------------------------------------------------------------------
#
# Copyright (C) 1993, 1994, 1995, 1996, 1997, 2000, 2001, 2002, 2003,
#   2004, 2005, 2006, 2007, 2008  Free Software Foundation, Inc.
#
# This file is part of GNU Emacs.
#
# This file is free software; as a special exception, the author gives
# unlimited permission to copy and/or distribute it, with or without
# modifications, as long as this notice is preserved.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
#
# ----------------------------------------------------------------------
# In case src/Makefile needs to rebuild `make-doc.exe' (might happen under
# Windows 95), make sure it gets built with commands that DOS
# understands (one command per line).
s/^#.*//
s/^[ \f\t][ \f\t]*$//
s/^ /	/
s/\.h\.in/.h-in/
s!^	\./temacs!	go32 temacs!
s!/bin/sh!command.com!
/^MAKE *=/s/^/# /
/^SHELL *=/s/^/# /
/^srcdir *=/s/@[^@\n]*@/./
/^VPATH *=/s/@[^@\n]*@/./
/^CC *=/s/@[^@\n]*@/gcc/
/^CPP *=/s/@[^@\n]*@/gcc -e/
/^CFLAGS *=/s/@[^@\n]*@/-O2 -g/
/^LIBS *=/s/@[^@\n]*@//
/^LIBOBJS *=/s/@[^@\n]*@//
/^LN_S *=/s/@[^@\n]*@/ln -s/
/^M_FILE *=/s!@[^@\n]*@!m/intel386.h!
/^S_FILE *=/s!@[^@\n]*@!s/msdos.h!
/^@SET_MAKE@$/s/@SET_MAKE@//
/^.\${libsrc}make-docfile.*>/s!make-docfile!make-doc.exe -o ../etc/DOC!
/^.\${libsrc}make-doc/s!>.*$!!
/^\${libsrc}make-docfile:/c\
${libsrc}make-doc.exe:\
	cd ..\
	cd lib-src\
	$(MAKE) ${MFLAGS} make-docfile -W make-docfile.c\
	cd ..\
	cd src
/^	cd \${libsrc}; \${MAKE} \${MFLAGS} make-docfile/d
/\${libsrc}make-docfile/s/-docfile[ 	]/-doc.exe /
/^[ 	]*$/d
/^temacs:/s/prefix-args//
/^temacs:/s/stamp-oldxmenu//
/^	#/d

# arch-tag: 246725c1-79de-4d03-a080-8f19329fa35e