view lisp/uncompress.el @ 8970:c0a15f821bd8

* man.el (Man-notify-flag): replaces the old Man-notify variable, use the old one if it is bound as initial value. (Man-reuse-okay-flag): replaces Man-reuse-okay. (Man-downcase-section-letters-flag): replaces Man-downcase-section-letters. (Man-circular-pages-flag): replaces Man-circular-pages. (Man-auto-section-alist): variable deleted. (Man-section-translations-alist): removed the "3x" translation. (Man-untabify-command, Man-untabify-command-args): new vars. (Man-sed-command, Man-awk-command): new variables. (Man-sysv-sed-script, Man-berkeley-sed-script): new constants. (Man-name-regexp, Man-page-header-regexp): new variable. (Man-heading-regexp): changed default value. (Man-reference-regexp): now refers to previous regexps. (Man-arguments): new buffer-local variable. (Man-page-mode-string): changed default value. (Man-mode-map): changed the meanings of ",", ".", "q". Added new keys ">", "<", "k". (Man-page-mode-string): function deleted. (Man-init-defvars): New function used for initialising the system and environment dependent variables Man-fontify-manpage-flag, Man-uses-untabify, Man-sed-script, Man-filter-list. (Man-delete-trailing-newlines): function deleted. (Man-make-page-mode-string): new subst. (Man-build-man-command): now subst instead of function. Modified to comply with the new format of Man-filter-list. (Man-downcase): function deleted. (Man-translate-references): complete rewrite. (Man-linepos): function deleted. (Man-match-substring): new function. (Man-default-man-args): function deleted. (Man-default-man-entry): complete rewrite. (man, manual-entry): function-alias relationship reversed. (man): prompt changed, prompt using interactive, call Man-init-defvars, set Man-arguments. (Man-notify-when-ready): manage the 'pushy value. (Man-fontify-manpage): substitute Man-set-fonts. (Man-cleanup-manpage): new function. (Man-bgproc-sentinel): cleanup, call Man-fontify-manpage and Man-cleanup-page when necessary. (Man-mode): call Man-strip-page-headers and Man-unindent. (Man-build-section-alist, Man-build-references-alist, Man-build-page-list): substs instead of functions. (Man-build-references-alist): cleanup. (Man-build-page-list): new algorithm. (Man-strip-page-headers, Man-unindent): new substs. (Man-find-section): assume section names start in column 1. (Man-quit): bury the buffer instead of killing it, delete the frame when necessary. (Man-kill): new function. (Man-goto-page): do the right thing when the manpage is not found, do not assume that Man-build-references-alist is broken.

;;; uncompress.el --- auto-decompression hook for visiting .Z files

;; Copyright (C) 1992, 1994 Free Software Foundation, Inc.

;; Maintainer: FSF

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to
;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.

;;; Commentary:

;; This package can be used to arrange for automatic uncompress of
;; files packed with the UNIX compress(1) utility when they are visited.
;; All that's necessary is to load it.  This can conveniently be done from
;; your .emacs file.

;;; Code:

;; When we are about to make a backup file,
;; uncompress the file we visited
;; so that making the backup can work properly.
;; This is used as a write-file-hook.

(defvar uncompress-program "gunzip"
  "Program to use for uncompression.")

(defun uncompress-backup-file ()
  (and buffer-file-name make-backup-files (not buffer-backed-up)
       (not (file-exists-p buffer-file-name))
       (call-process uncompress-program nil nil nil buffer-file-name))
  nil)

(or (assoc "\\.Z$" auto-mode-alist)
    (setq auto-mode-alist
	  (cons '("\\.Z$" . uncompress-while-visiting) auto-mode-alist)))
(or (assoc "\\.gz$" auto-mode-alist)
    (setq auto-mode-alist
	  (cons '("\\.gz$" . uncompress-while-visiting) auto-mode-alist)))

(defun uncompress-while-visiting ()
  "Temporary \"major mode\" used for .Z and .gz files, to uncompress them.
It then selects a major mode from the uncompressed file name and contents."
  (if (and (not (null buffer-file-name))
	   (string-match "\\.Z$" buffer-file-name))
      (set-visited-file-name
       (substring buffer-file-name 0 (match-beginning 0)))
    (if (and (not (null buffer-file-name))
	     (string-match "\\.gz$" buffer-file-name))
	(set-visited-file-name
	 (substring buffer-file-name 0 (match-beginning 0)))))
  (message "Uncompressing...")
  (let ((buffer-read-only nil))
    (shell-command-on-region (point-min) (point-max) uncompress-program t))
  (message "Uncompressing...done")
  (set-buffer-modified-p nil)
  (make-local-variable 'write-file-hooks)
  (or (memq 'uncompress-backup-file write-file-hooks)
      (setq write-file-hooks (cons 'uncompress-backup-file write-file-hooks)))
  (normal-mode))

(or (memq 'find-compressed-version find-file-not-found-hooks)
    (setq find-file-not-found-hooks
	  (cons 'find-compressed-version find-file-not-found-hooks)))

(defun find-compressed-version ()
  "Hook to read and uncompress the compressed version of a file."
  ;; Just pretend we had visited the compressed file,
  ;; and uncompress-while-visiting will do the rest.
  (let (name)
    (if (file-exists-p (setq name (concat buffer-file-name ".Z")))
	(setq buffer-file-name name)
      (if (file-exists-p (setq name (concat buffer-file-name ".gz")))
	  (setq buffer-file-name name)))
    (if (eq name buffer-file-name)
	(progn
	  (insert-file-contents buffer-file-name t)
	  (goto-char (point-min))
	  (setq error nil)
	  t))))

(provide 'uncompress)

;;; uncompress.el ends here