view msdos/sed1.inp @ 17545:c67787f92aea

(sgml-value): Use 'identity as default value. (sgml-mode): Doc fix. (sgml-name-8bit-mode): Tell the user if set or reset. (sgml-tag): Doc fix. (sgml-tag): Protect "&lt;" from skeleton-transformation. (sgml-attributes): Doc fix. (sgml-attributes): Square brackets removed from prompt. (sgml-attributes): Arg ALIST renamed to TAG. (sgml-attributes): Apply skeleton-transformation when necessary. (sgml-value): Doc added. (sgml-value): Square brackets removed from prompt. (html-tag-alist): New variable 1-7, variable `list' changed. (html-tag-alist)<dir>, <menu>: Use new value of `list'. (html-tag-alist)<font>: Fixed (doc of sgml-tag-alist needs fixing). (html-tag-alist)<ol>, <ul>: Fixed. (html-tag-alist)<fn>: Commented out.

# -sed1.inp-------------------------------------------------------------
# Configuration script for src/makefile
# ----------------------------------------------------------------------
#
# In case src/Makefile needs to rebuild `make-doc.exe' (might happen under
# Windows 95), make sure it gets built with commands that DOS
# understands (one command per line).
s/^#.*//
s/^[ \f\t][ \f\t]*$//
s/^ /	/
s/\.h\.in/.h-in/
s!^	\./temacs!	go32 temacs!
s!/bin/sh!command.com!
/^MAKE *=/s/^/# /
/^SHELL *=/s/^/# /
/^srcdir *=/s/@[^@\n]*@/./
/^VPATH *=/s/@[^@\n]*@/./
/^CC *=/s/@[^@\n]*@/gcc/
/^CPP *=/s/@[^@\n]*@/gcc -e/
/^CFLAGS *=/s/@[^@\n]*@/-O2 -g/
/^LN_S *=/s/@[^@\n]*@/ln -s/
/^M_FILE *=/s!@[^@\n]*@!m/intel386.h!
/^S_FILE *=/s!@[^@\n]*@!s/msdos.h!
/^@SET_MAKE@$/s/@SET_MAKE@//
/^.\${libsrc}make-docfile.*>/s!make-docfile!make-doc.exe -o ../etc/DOC!
/^.\${libsrc}make-doc/s!>.*$!!
/^\${libsrc}make-docfile:/c\
${libsrc}make-doc.exe:\
	cd ..\
	cd lib-src\
	$(MAKE) ${MFLAGS} make-docfile -W make-docfile.c\
	cd ..\
	cd src
/^	cd \${libsrc}; \${MAKE} \${MFLAGS} make-docfile/d
/\${libsrc}make-docfile/s/-docfile[ 	]/-doc.exe /
/^[ 	]*$/d
/^temacs:/s/prefix-args//
/^	#/d