Mercurial > emacs

view lisp/url/url-about.el @ 105864:c6d77597d0f2

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
* verilog-mode.el (verilog-getopt-file, verilog-set-define): Remove extra save-excursions and make-variable-buffer-local's. Suggested by Stefan Monnier. (verilog-getopt-file, verilog-module-inside-filename-p) (verilog-set-define): Merge GNU 1.35 and repair changes from switching to using with-current-buffer. (verilog-read-always-signals-recurse): Fix "a == 2'b00 ? b : c" being treated as a number and confusing AUTORESET. Reported by Dan Dever. (verilog-auto-ignore-concat, verilog-read-sub-decls-expr): Add verilog-auto-ignore-concat to fix backward compatibility with older verilog-modes. Reported by Dan Katz. (verilog-read-auto-template): Fix AUTO_TEMPLATEs with regexps containing closing anchors "...$". (verilog-read-decls): Fix AUTOREG not detecting "assign {a,b}". Reported by Wade Smith. (verilog-batch-execute-func) Comment on function usage. (verilog-label-re): Fix regular expression for labels. (verilog-label-re, verilog-calc-1): Support proper indent of named asserts. (verilog-backward-token, verilog-basic-complete-re) (verilog-beg-of-statement, verilog-indent-re): Support proper indent of the assert statement at the beginning of a block of text. (verilog-beg-block-re, verilog-ovm-begin-re): Support the `ovm_object_param_utils_begin and `ovm_component_param_utils_begin tokens as begins.
author Stefan Monnier <monnier@iro.umontreal.ca>
date Thu, 05 Nov 2009 20:54:34 +0000
parents a9dc0e7c3f2b
children 1d1d5d9bd884
line wrap: on
line source

;;; url-about.el --- Show internal URLs

;; Copyright (C) 2001, 2004, 2005, 2006, 2007, 2008, 2009
;;   Free Software Foundation, Inc.

;; Keywords: comm, data, processes, hypermedia

;; This file is part of GNU Emacs.
;;
;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:

;;; Code:

(require 'url-util)
(require 'url-parse)

(defun url-probe-protocols ()
  "Return a list of all potential URL schemes."
  (or (get 'url-extension-protocols 'probed)
      (mapc (lambda (s) (url-scheme-get-property s 'name))
	    (or (get 'url-extension-protocols 'schemes)
		(let ((schemes '("info" "man" "rlogin" "telnet"
				 "tn3270" "data" "snews")))
		  (mapc (lambda (d)
			  (mapc (lambda (f)
				  (if (string-match "url-\\(.*\\).el$" f)
				      (push (match-string 1 f) schemes)))
				(directory-files d nil "^url-.*\\.el$")))
			load-path)
		  (put 'url-extension-protocols 'schemes schemes)
		  schemes)))))

(defvar url-scheme-registry)

(defun url-about-protocols (url)
  (url-probe-protocols)
  (insert "<html>\n"
	  " <head>\n"
	  "  <title>Supported Protocols</title>\n"
	  " </head>\n"
	  " <body>\n"
	  "  <h1>Supported Protocols - URL v" url-version "</h1>\n"
	  "  <table width='100%' border='1'>\n"
	  "   <tr>\n"
	  "    <td>Protocol\n"
	  "    <td>Properties\n"
	  "    <td>Description\n"
	  "   </tr>\n")
  (mapc (lambda (k)
	  (if (string= k "proxy")
	      ;; Ignore the proxy setting... its magic!
	      nil
	    (insert "   <tr>\n")
	    ;; The name of the protocol
	    (insert "    <td valign=top>" (or (url-scheme-get-property k 'name) k) "\n")

	    ;; Now the properties.  Currently just asynchronous
	    ;; status, default port number, and proxy status.
	    (insert "    <td valign=top>"
		    (if (url-scheme-get-property k 'asynchronous-p) "As" "S")
		    "ynchronous<br>\n"
		    (if (url-scheme-get-property k 'default-port)
			(format "Default Port: %d<br>\n"
				(url-scheme-get-property k 'default-port)) "")
		    (if (assoc k url-proxy-services)
			(format "Proxy: %s<br>\n" (assoc k url-proxy-services)) ""))
	    ;; Now the description...
	    (insert "    <td valign=top>"
		    (or (url-scheme-get-property k 'description) "N/A"))))
	(sort (let (x) (maphash (lambda (k v) (push k x)) url-scheme-registry) x) 'string-lessp))
  (insert "  </table>\n"
	  " </body>\n"
	  "</html>\n"))

(defun url-about (url)
  "Show internal URLs."
  (let* ((item (downcase (url-filename url)))
	 (func (intern (format "url-about-%s" item))))
    (if (fboundp func)
	(progn
	  (set-buffer (generate-new-buffer " *about-data*"))
	  (insert "Content-type: text/plain\n\n")
	  (funcall func url)
	  (current-buffer))
      (error "URL does not know about `%s'" item))))

(provide 'url-about)

;; arch-tag: 65dd7fca-db3f-4cb1-8026-7dd37d4a460e
;;; url-about.el ends here