view lib-src/b2m.pl @ 86470:c91f81134a74

(calc-set-language, calc-edit-finish) (calc-edit-cancel, calc-do-quick-calc, calc-do-calc-eval) (calc-do-keypad, calcFunc-unixtime, math-parse-date) (math-lessp, calc-embedded-finish-command) (calc-embedded-select-buffer, calc-embedded-mode-line-change) (calc-push-list-in-macro, calc-replace-selections) (calc-record-list, calc-normalize-fancy, calc-do-handle-whys) (calc-top-selected, calc-sel-error, calc-pop-stack-in-macro) (calc-embedded-stack-change, calc-refresh-evaltos) (calc-do-refresh, calc-binary-op-fancy, calc-unary-op-fancy) (calc-delete-selection, calc-alg-digit-entry, calc-alg-entry) (calc-dots, calc-temp-minibuffer-message, math-read-radix-digit) (calc-digit-dots, math-normalize-fancy, math-normalize-nonstandard) (math-recompile-eval-rules, math-apply-rewrites, calc-record-why) (math-dimension-error, calc-incomplete-error, math-float-fancy) (math-neg-fancy, math-zerop, calc-add-fractions) (math-add-objects-fancy, math-add-symb-fancy, math-mul-zero) (calc-mul-fractions, math-mul-objects-fancy, math-mul-symb-fancy) (math-reject-arg, math-div-by-zero, math-div-zero, math-make-frac) (calc-div-fractions, math-div-objects-fancy, math-div-symb-fancy) (math-compose-expr, math-comp-width, math-composition-to-string) (math-stack-value-offset-fancy, math-format-flat-expr-fancy) (math-adjust-fraction, math-format-binary, math-format-radix) (math-group-float, math-mod, math-format-number-fancy) (math-format-bignum-fancy, math-read-number-fancy) (calc-do-grab-region, calc-do-grab-rectangle, calc-do-embedded) (calc-do-embedded-activate, math-do-defmath) (calc-load-everything): Declare as functions.

#!/usr/bin/perl

# b2m.pl - Script to convert a Babyl file to an mbox file

# Copyright (C) 2002, 2003, 2004, 2005, 2006, 2007
#   Free Software Foundation, Inc.

# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 3, or (at your option)
# any later version.

# This program is distributed in the hope that it will be useful, but
# WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
# General Public License for more details.

# You should have received a copy of the GNU General Public License
# along with this program; see the file COPYING.  If not, write to the
# Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
# Boston, MA 02110-1301 USA.

# Maintained by Jonathan Kamens <[e-mail]>.

# Requires CPAN modules: MailTools (for Mail::Address), TimeDate (for
# Date::Parse).

use warnings;
use strict;
use File::Basename;
use Getopt::Long;
use Mail::Address;
use Date::Parse;

my($whoami) = basename $0;
my($version) = '$Revision$';
my($usage) = "Usage: $whoami [--help] [--version] [--[no]full-headers] [Babyl-file]
\tBy default, full headers are printed.\n";

my($opt_help, $opt_version);
my($opt_full_headers) = 1;

die $usage if (! GetOptions(
			    'help' => \$opt_help,
			    'version' => \$opt_version,
			    'full-headers!' => \$opt_full_headers,
			    ));

if ($opt_help) {
    print $usage;
    exit;
}
elsif ($opt_version) {
    print "$whoami version: $version\n";
    exit;
}

die $usage if (@ARGV > 1);

$/ = "\n\037";

if (<> !~ /^BABYL OPTIONS:/) {
    die "$whoami: $ARGV is not a Babyl file\n$usage";
}

while (<>) {
    my($msg_num) = $. - 1;
    my($labels, $pruned, $full_header, $header);
    my($from_line, $from_addr);
    my($time);

    # This will strip the initial form feed, any whitespace that may
    # be following it, and then a newline
    s/^\s+//;
    # This will strip the ^_ off of the end of the message
    s/\037$//;

    if (! s/(.*)\n//) {
      malformatted:
	warn "$whoami: message $msg_num in $ARGV is malformatted\n";
	next;
    }
    $labels = $1;

    # Strip the integer indicating whether the header is pruned
    $labels =~ s/^(\d+)[,\s]*//;
    $pruned = $1;

    s/(?:((?:.+\n)+)\n*)?\*\*\* EOOH \*\*\*\n+// || goto malformatted;
    $full_header = $1;

    if (s/((?:.+\n)+)\n+//) {
	$header = $1;
    }
    else {
	# Message has no body
	$header = $_;
	$_ = '';
    }

    # "$pruned eq '0'" is different from "! $pruned".  We want to make
    # sure that we found a valid label line which explicitly indicated
    # that the header was not pruned.
    if ((! $full_header) || ($pruned eq '0')) {
	$full_header = $header;
    }

    # End message with two newlines (some mbox parsers require a blank
    # line before the next "From " line).
    s/\s+$/\n\n/;

    # Quote "^From "
    s/(^|\n)From /$1>From /g;

    # Strip extra commas and whitespace from the end
    $labels =~ s/[,\s]+$//;
    # Now collapse extra commas and whitespace in the remaining label string
    $labels =~ s/[,\s]+/, /g;

    foreach my $rmail_header qw(summary-line x-coding-system) {
	$full_header =~ s/(^|\n)$rmail_header:.*\n/$1/i;
    }

    if ($full_header =~ s/(^|\n)mail-from:\s*(From .*)\n/$1/i) {
	($from_line = $2) =~ s/\s*$/\n/;
    }
    else {
	foreach my $addr_header qw(return-path from really-from sender) {
	    if ($full_header =~ /(?:^|\n)$addr_header:\s*(.*\n(?:\B.*\n)*)/i) {
		my($addr) = Mail::Address->parse($1);
		$from_addr = $addr->address($addr);
		last;
	    }
	}

	if (! $from_addr) {
	    $from_addr = "Babyl_to_mail_by_$whoami\@localhost";
	}

	if ($full_header =~ /(?:^|\n)date:\s*(\S.*\S)/i) {
	    $time = str2time($1);
	}

	if (! $time) {
	    # No Date header or we failed to parse it
	    $time = time;
	}

	$from_line = "From " . $from_addr . " " . localtime($time) . "\n";
    }

    print($from_line, ($opt_full_headers ? $full_header : $header),
	  ($labels ? "X-Babyl-Labels: $labels\n" : ""), "\n",
	  $_) || die "$whoami: error writing to stdout: $!\n";
}

close(STDOUT) || die "$whoami: Error closing stdout: $!\n";

# arch-tag: 8c7c8ab0-721c-46d7-ba3e-139801240aa8