view m4/getopt.m4 @ 86470:c91f81134a74

(calc-set-language, calc-edit-finish) (calc-edit-cancel, calc-do-quick-calc, calc-do-calc-eval) (calc-do-keypad, calcFunc-unixtime, math-parse-date) (math-lessp, calc-embedded-finish-command) (calc-embedded-select-buffer, calc-embedded-mode-line-change) (calc-push-list-in-macro, calc-replace-selections) (calc-record-list, calc-normalize-fancy, calc-do-handle-whys) (calc-top-selected, calc-sel-error, calc-pop-stack-in-macro) (calc-embedded-stack-change, calc-refresh-evaltos) (calc-do-refresh, calc-binary-op-fancy, calc-unary-op-fancy) (calc-delete-selection, calc-alg-digit-entry, calc-alg-entry) (calc-dots, calc-temp-minibuffer-message, math-read-radix-digit) (calc-digit-dots, math-normalize-fancy, math-normalize-nonstandard) (math-recompile-eval-rules, math-apply-rewrites, calc-record-why) (math-dimension-error, calc-incomplete-error, math-float-fancy) (math-neg-fancy, math-zerop, calc-add-fractions) (math-add-objects-fancy, math-add-symb-fancy, math-mul-zero) (calc-mul-fractions, math-mul-objects-fancy, math-mul-symb-fancy) (math-reject-arg, math-div-by-zero, math-div-zero, math-make-frac) (calc-div-fractions, math-div-objects-fancy, math-div-symb-fancy) (math-compose-expr, math-comp-width, math-composition-to-string) (math-stack-value-offset-fancy, math-format-flat-expr-fancy) (math-adjust-fraction, math-format-binary, math-format-radix) (math-group-float, math-mod, math-format-number-fancy) (math-format-bignum-fancy, math-read-number-fancy) (calc-do-grab-region, calc-do-grab-rectangle, calc-do-embedded) (calc-do-embedded-activate, math-do-defmath) (calc-load-everything): Declare as functions.

# getopt.m4 serial 10
dnl Copyright (C) 2002,2003,2004,2005,2006,2007 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.

# The getopt module assume you want GNU getopt, with getopt_long etc,
# rather than vanilla POSIX getopt.  This means your your code should
# always include <getopt.h> for the getopt prototypes.

AC_DEFUN([gl_GETOPT_SUBSTITUTE],
[
  AC_LIBOBJ([getopt])
  AC_LIBOBJ([getopt1])
  gl_GETOPT_SUBSTITUTE_HEADER
  gl_PREREQ_GETOPT
])

AC_DEFUN([gl_GETOPT_SUBSTITUTE_HEADER],
[
  GETOPT_H=getopt.h
  AC_DEFINE([__GETOPT_PREFIX], [[rpl_]],
    [Define to rpl_ if the getopt replacement functions and variables
     should be used.])
  AC_SUBST([GETOPT_H])
])

AC_DEFUN([gl_GETOPT_CHECK_HEADERS],
[
  GETOPT_H=
  AC_CHECK_HEADERS([getopt.h], [], [GETOPT_H=getopt.h])
  if test -z "$GETOPT_H"; then
    AC_CHECK_FUNCS([getopt_long_only], [], [GETOPT_H=getopt.h])
  fi

  dnl BSD getopt_long uses an incompatible method to reset option processing,
  dnl and (as of 2004-10-15) mishandles optional option-arguments.
  if test -z "$GETOPT_H"; then
    AC_CHECK_DECL([optreset], [GETOPT_H=getopt.h], [], [#include <getopt.h>])
  fi

  dnl Solaris 10 getopt doesn't handle `+' as a leading character in an
  dnl option string (as of 2005-05-05).
  if test -z "$GETOPT_H"; then
    AC_CACHE_CHECK([for working GNU getopt function], [gl_cv_func_gnu_getopt],
      [AC_RUN_IFELSE(
	[AC_LANG_PROGRAM([#include <getopt.h>],
	   [[
	     char *myargv[3];
	     myargv[0] = "conftest";
	     myargv[1] = "-+";
	     myargv[2] = 0;
	     return getopt (2, myargv, "+a") != '?';
	   ]])],
	[gl_cv_func_gnu_getopt=yes],
	[gl_cv_func_gnu_getopt=no],
	[dnl cross compiling - pessimistically guess based on decls
	 dnl Solaris 10 getopt doesn't handle `+' as a leading character in an
	 dnl option string (as of 2005-05-05).
	 AC_CHECK_DECL([getopt_clip],
	   [gl_cv_func_gnu_getopt=no], [gl_cv_func_gnu_getopt=yes],
	   [#include <getopt.h>])])])
    if test "$gl_cv_func_gnu_getopt" = "no"; then
      GETOPT_H=getopt.h
    fi
  fi
])

AC_DEFUN([gl_GETOPT_IFELSE],
[
  AC_REQUIRE([gl_GETOPT_CHECK_HEADERS])
  AS_IF([test -n "$GETOPT_H"], [$1], [$2])
])

AC_DEFUN([gl_GETOPT], [gl_GETOPT_IFELSE([gl_GETOPT_SUBSTITUTE])])

# Prerequisites of lib/getopt*.
AC_DEFUN([gl_PREREQ_GETOPT], [:])

ifelse(dnl	Do not change this comment
   arch-tag: 6c64a021-551c-4a7f-9c63-cd7e1ce54707
)dnl