view test/newsticker-testsuite.el @ 99602:c94ec53df9d8

* net/ange-ftp.el (ange-ftp-multi-msgs, ange-ftp-good-msgs) (ange-ftp-try-passive-mode, ange-ftp-data-buffer-name) (ange-ftp-account-hashtable, ange-ftp-ls-cache-lsargs) (ange-ftp-ls-cache-file, ange-ftp-ls-cache-res, ange-ftp-get-user) (ange-ftp-ftp-name-component, ange-ftp-kill-ftp-process) (ange-ftp-quote-string, ange-ftp-process-handle-line) (ange-ftp-start-process, ange-ftp-send-cmd, ange-ftp-add-dumb-unix-host) (ange-ftp-before-parse-ls-hook, ange-ftp-after-parse-ls-hook) (ange-ftp-ls, ange-ftp-add-dl-dir, ange-ftp-get-file-entry) (ange-ftp-set-binary-mode, ange-ftp-set-ascii-mode, ange-ftp-get-pwd) (ange-ftp-file-name-as-directory-alist, ange-ftp-reread-dir) (ange-ftp-vms-filename-regexp, ange-ftp-bs2000-fix-name-regexp-reverse) (ange-ftp-bs2000-fix-name-regexp): Fix typos in docstrings. (ange-ftp-name-format, ange-ftp-gateway-fatal-msgs) (ange-ftp-xfer-size-msgs, ange-ftp-tmp-name-template) (ange-ftp-netrc-filename, ange-ftp-disable-netrc-security-check) (ange-ftp-default-user, ange-ftp-default-password) (ange-ftp-default-account, ange-ftp-netrc-default-password) (ange-ftp-netrc-default-account, ange-ftp-dumb-unix-host-regexp) (ange-ftp-binary-file-name-regexp, ange-ftp-gateway-host) (ange-ftp-gateway-prompt-pattern, ange-ftp-smart-gateway-port) (ange-ftp-send-hash, ange-ftp-binary-hash-mark-size) (ange-ftp-ascii-hash-mark-size, ange-ftp-process-verbose) (ange-ftp-ftp-program-name, ange-ftp-gateway-ftp-program-name) (ange-ftp-ftp-program-args, ange-ftp-nslookup-program) (ange-ftp-make-backup-files, ange-ftp-retry-time) (ange-ftp-bs2000-special-prefix): Remove * from defcustom docstrings. (ange-ftp-skip-msgs, ange-ftp-potential-error-msgs) (ange-ftp-gateway-tmp-name-template) (ange-ftp-generate-anonymous-password, ange-ftp-local-host-regexp) (ange-ftp-gateway-program-interactive, ange-ftp-smart-gateway) (ange-ftp-raw-login): Remove * from defcustom docstrings; fix typos. (ange-ftp-fatal-msgs): Remove * from defcustom docstring; doc fix. (ange-ftp-gateway-program): Remove * from docstring and reflow. (ange-ftp-hash-entry-exists-p, ange-ftp-hash-table-keys) (ange-ftp-raw-send-cmd, ange-ftp-get-files, ange-ftp-canonize-filename) (ange-ftp-file-name-as-directory, ange-ftp-directory-file-name): (ange-ftp-copy-files-async, ange-ftp-rename-remote-to-remote): (ange-ftp-rename-local-to-remote): Doc fixes. (ange-ftp-set-xfer-size, ange-ftp-call-cont, ange-ftp-process-filter): Use `when', `unless'. (ange-ftp-set-passwd): Rename arg PASSWD to PASSWORD. (ange-ftp-process-handle-hash): Rename arg STR to STRING. (ange-ftp-nslookup-host): Rename arg HOST to HOSTNAME. (ange-ftp-smart-login): Rename arg PASS to PASSWORD. (ange-ftp-normal-login): Rename arg PASS to PASSWORD. Fix typo. (ange-ftp-process-sentinel): Use `when'. Fix typo. (ange-ftp-gwp-start): Use `let', not `let*'; use `when'. Fix typo. (ange-ftp-fix-name-func-alist, ange-ftp-fix-dir-name-func-alist) (ange-ftp-parse-list-func-alist, ange-ftp-add-file-entry-alist) (ange-ftp-delete-file-entry-alist): Fix typos and reflow docstring. (ange-ftp-dumb-unix-host, ange-ftp-binary-file) (ange-ftp-directory-files, ange-ftp-file-modtime, ange-ftp-vms-host) (ange-ftp-mts-host, ange-ftp-cms-host, ange-ftp-bs2000-host) (ange-ftp-bs2000-posix-host): Use `string-match-p' instead of `(save-match-data (string-match ...))'. (ange-ftp-use-gateway-p, ange-ftp-use-smart-gateway-p) (ange-ftp-file-name-directory, ange-ftp-file-name-nondirectory): Use `string-match-p' instead of `(save-match-data (string-match ...))'. Doc fixes.

;;; newsticker-testsuite.el --- Test suite for newsticker.

;; Copyright (C) 2003, 2004, 2005, 2006, 2007, 2008
;;   Free Software Foundation, Inc.

;; Author:      Ulf Jasper <[e-mail]>
;; Filename:    newsticker-testsuite.el
;; URL:         http://www.nongnu.org/newsticker
;; Keywords:    News, RSS, Atom
;; Time-stamp:  "14. Juni 2008, 12:09:39 (ulf)"

;; ======================================================================

;; This file is part of GNU Emacs.

;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.

;; ======================================================================

;;; Commentary:

;;; Code:

(require 'cl)                           ; assert

;; ======================================================================
;; Entry point
;; ======================================================================
(defun newsticker--testsuite ()
  "Unit test for newsticker.
Subtests signal errors if something goes wrong."
  (interactive)
  (newsticker--test--guid)
  (newsticker--test--cache-contains)
  (newsticker--test--decode-iso8601-date)
  (newsticker--test--decode-rfc822-date)
  (newsticker--test--group-manage-orphan-feeds)
  (message "All tests passed successfully."))

;; ======================================================================
;; Tests for newsticker-backend
;; ======================================================================
(defun newsticker--test--guid ()
  "Test `newsticker-guid-*'.
Signals an error if something goes wrong."
  (assert (string= "blah" (newsticker--guid-to-string "blah")))
  (assert (string= "myguid" (newsticker--guid '("title1" "description1" "link1"
                                                nil 'new 42 nil nil
                                                ((guid () "myguid")))))))

(defun newsticker--test--cache-contains ()
  "Test `newsticker--test--cache-contains'.
Signals an error if something goes wrong."
  (let ((newsticker--cache '((feed1
                              ("title1" "description1" "link1" nil 'new 42
                               nil nil ((guid () "myguid")))))))
    (newsticker--guid-to-string
     (assoc 'guid (newsticker--extra '("title1" "description1"
                                       "link1" nil 'new 42 nil nil
                                       ((guid "myguid"))))))
    (assert (newsticker--cache-contains newsticker--cache 'feed1 "WRONGTITLE"
                                        "description1" "link1" 'new "myguid"))
    (assert (not (newsticker--cache-contains newsticker--cache 'feed1 "title1"
                                             "description1" "link1" 'new
                                             "WRONG GUID")))
    (assert (newsticker--cache-contains newsticker--cache 'feed1 "title1"
                                        "description1" "link1" 'new "myguid")))
  (let ((newsticker--cache '((feed1
                              ("title1" "description1" "link1" nil 'new 42
                               nil nil ((guid () "myguid1")))
                              ("title1" "description1" "link1" nil 'new 42
                               nil nil ((guid () "myguid2")))))))
    (assert (not (newsticker--cache-contains newsticker--cache 'feed1 "title1"
                                             "description1" "link1" 'new
                                             "myguid")))
    (assert (string= "myguid1"
                     (newsticker--guid (newsticker--cache-contains
                                        newsticker--cache 'feed1 "title1"
                                        "description1" "link1" 'new
                                        "myguid1"))))
    (assert (string= "myguid2"
                     (newsticker--guid (newsticker--cache-contains
                                        newsticker--cache 'feed1 "title1"
                                        "description1" "link1" 'new
                                        "myguid2"))))))

(defun newsticker--do-test--decode-iso8601-date (input expected)
  "Actually test `newsticker--decode-iso8601-date'.
Signals an error if iso8601-encoded INPUT does not match EXPECTED."
  (let ((result (format-time-string "%Y-%m-%dT%H:%M:%S"
                                    (newsticker--decode-iso8601-date input)
                                    t)))
    (assert (string= result expected)
            nil "Error decoding '%s': found '%s' but expected '%s'."
            input result expected)))

(defun newsticker--test--decode-iso8601-date ()
  "Test `newsticker--decode-iso8601-date'."
  (newsticker--decode-iso8601-date "2004-09-17T05:09:49+00:00")
  (newsticker--decode-iso8601-date "2004-09-17T05:09+00:00")
  (newsticker--decode-iso8601-date "2004-09-17T05:09:49")
  (newsticker--decode-iso8601-date "2004-09-17T05:09")
  (newsticker--decode-iso8601-date "2004-09-17")
  (newsticker--decode-iso8601-date "2004-09")
  (newsticker--do-test--decode-iso8601-date "2004"
                                            "2004-01-01T00:00:00")
  (newsticker--do-test--decode-iso8601-date "2004-09"
                                            "2004-09-01T00:00:00")
  (newsticker--do-test--decode-iso8601-date "2004-09-17"
                                            "2004-09-17T00:00:00")
  (newsticker--do-test--decode-iso8601-date "2004-09-17T05:09"
                                            "2004-09-17T05:09:00")
  (newsticker--do-test--decode-iso8601-date "2004-09-17T05:09:49"
                                            "2004-09-17T05:09:49")
  (newsticker--do-test--decode-iso8601-date "2004-09-17T05:09:49.123"
                                            "2004-09-17T05:09:49")
  (newsticker--do-test--decode-iso8601-date "2004-09-17T05:09+01:00"
                                            "2004-09-17T04:09:00")
  (newsticker--do-test--decode-iso8601-date "2004-09-17T05:09-02:00"
                                            "2004-09-17T07:09:00"))

(defun newsticker--do-test--decode-rfc822-date (input expected)
  "Actually test `newsticker--decode-rfc822-date'.
Signals an error if rfc822-encoded INPUT does not match EXPECTED."
  (let ((result (format-time-string "%Y-%m-%dT%H:%M:%S"
                                    (newsticker--decode-rfc822-date input)
                                    t)))
    (assert (string= result expected)
            nil "Error decoding '%s': found '%s' but expected '%s'."
            input result expected)))

(defun newsticker--test--decode-rfc822-date ()
  "Test `newsticker--decode-rfc822-date'."
  (newsticker--do-test--decode-rfc822-date "Mon, 10 Mar 2008 19:27:52 +0100"
                                           "2008-03-10T18:27:52")
  ;;(format-time-string "%d.%m.%y, %H:%M %T%z"
  ;;(newsticker--decode-rfc822-date "Mon, 10 Mar 2008 19:27:52 +0200"))

  (newsticker--do-test--decode-rfc822-date "Mon, 10 Mar 2008 19:27:52"
                                           "2008-03-10T19:27:52")
  (newsticker--do-test--decode-rfc822-date "Mon, 10 Mar 2008 19:27"
                                           "2008-03-10T19:27:00")
  (newsticker--do-test--decode-rfc822-date "10 Mar 2008 19:27"
                                           "2008-03-10T19:27:00")
  (newsticker--do-test--decode-rfc822-date "Mon, 10 Mar 2008"
                                           "2008-03-10T00:00:00")
  (newsticker--do-test--decode-rfc822-date "10 Mar 2008"
                                           "2008-03-10T00:00:00")
  (newsticker--do-test--decode-rfc822-date "Sat, 01 Dec 2007 00:05:00 +0100"
                                           "2007-11-30T23:05:00")
  (newsticker--do-test--decode-rfc822-date "Sun, 30 Dec 2007 18:58:13 +0100"
                                           "2007-12-30T17:58:13"))

;; ======================================================================
;; Tests for newsticker-treeview
;; ======================================================================
(defun newsticker--test--group-manage-orphan-feeds ()
  "Test `newsticker--group-manage-orphan-feeds'.
Signals an error if something goes wrong."
  (let ((newsticker-groups '("Feeds"))
        (newsticker-url-list-defaults nil)
        (newsticker-url-list '(("feed1") ("feed2") ("feed3"))))
    (newsticker--group-manage-orphan-feeds)
    (assert (equal '("Feeds" "feed3" "feed2" "feed1")
                   newsticker-groups))))

(provide 'newsticker-testsuite)

;; arch-tag: e6c09af2-cc7a-4373-8f5f-9c36699ec34c
;;; newsticker-testsuite.el ends here