Mercurial > emacs

view msdos/sedleim.inp @ 24684:cca41b0e7ae7

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
(diary-remind): Rewritten to behave sensibly for diary-block diary entries for which the reminders and the diary entries can overlap.
author Karl Heuer <kwzh@gnu.org>
date Mon, 03 May 1999 20:03:07 +0000
parents cd4343d3cd01
children 00af2bda43f0
line wrap: on
line source

# -sedleim.inp-----------------------------------------------------------
# Configuration script for leim/Makefile under DJGPP v2.x
# ----------------------------------------------------------------------
/^SHELL *=/c\
SHELL=/dos/command\
MAKESHELL=/dos/command

/^version=/d
/^prefix=/d
/^datadir=/s|@datadir@|../..|
/^srcdir=/s|@srcdir@|.|

/^INSTALLDIR=/c\
INSTALLDIR=.

/^	cd ../c\
	${MAKE} -C ../src ${MFLAGS} emacs

/else make quail/c\
	if not exist quail\\nul make quail

/^leim-list.el:/,/^$/ {
	/^	if/d
	/^	else/,/^	fi/d
	s|	 *|	|
	/^	--eval/,/; \\$/s|\; \\||
}

/^install:/,/^$/c\
install: all\

/^	ELC=/,/^	rm -f/c\
	rm -f ${TIT} $(shell echo ${TIT} | sed 's/\.el/.elc/g') leim-list.elc

/^	if test -f/d