view admin/unidata/biditype.awk @ 109480:d12162869c07

Convert some more functions to standard C. * lib-src/emacsclient.c (get_current_dir_name, w32_get_resource) (w32_getenv, w32_set_user_model_id, w32_window_app, w32_execvp) (close_winsock, initialize_sockets, w32_find_emacs_process) (w32_give_focus): * lib-src/ntlib.c (getlogin, getuid, getgid, getegid): * nt/addpm.c (add_registry, main): * nt/cmdproxy.c (get_env_size): * nt/ddeclient.c (main): * nt/runemacs.c (set_user_model_id): * src/alloc.c (emacs_blocked_free, emacs_blocked_malloc) (emacs_blocked_realloc, uninterrupt_malloc): * src/fringe.c (w32_reset_fringes): * src/image.c (convert_mono_to_color_image, lookup_rgb_color) (init_color_table, XPutPixel, jpeg_resync_to_restart_wrapper): * src/sound.c (be2hs, do_play_sound): * src/vm-limit.c (get_lim_data, ret_lim_data): * src/w32term.c (x_free_frame_resources): * src/xfaces.c (x_create_gc, x_free_gc): Convert definitions to standard C.

# Generate data for filling bidi_type_table, see src/bidi.c:bidi_initialize.

# Copyright (C) 2010, Free Software Foundation, Inc.

# This file is part of GNU Emacs.

# GNU Emacs is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.

# GNU Emacs is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.

# You should have received a copy of the GNU General Public License
# along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.

# Written by Eli Zaretskii <[e-mail]>

function trtype(type)
{
    # Types are listed in the order of decresing use in UnicodeData.txt:
    if (type == "ON")
	return "NEUTRAL_ON";
    else if (type == "NSM")
	return "WEAK_NSM";
    else if (type == "AL")
	return "STRONG_AL";
    else if (type == "R")
	return "STRONG_R";
    else if (type == "BN")
	return "WEAK_BN";
    else if (type == "EN")
	return "WEAK_EN";
    else if (type == "ET")
	return "WEAK_ET";
    else if (type == "AN")
	return "WEAK_AN";
    else if (type == "WS")
	return "NEUTRAL_WS";
    else if (type == "CS")
	return "WEAK_CS";
    else if (type == "ES")
	return "WEAK_ES";
    else if (type == "B")
	return "NEUTRAL_B";
    else if (type == "S")
	return "NEUTRAL_S";
    else if (type == "LRE" || type == "RLE" || type == "LRO" || type == "RLO" || type == "PDF")
	return type;
    else if (type == "L")
	return "STRONG_L";
    else
    {
	printf "Unknown type: %s\n", type > "/dev/stderr";
	exit 1;
    }
}

BEGIN {
     otype = "";
     startcode = "";
     endcode = "";
     printf "  struct {\n    int from, to;\n    bidi_type_t type;\n  } bidi_type[] = {\n";
     first = 1;
 }

 {   code = $1;
     ntype = $5;
     if (ntype != otype)
     {
	 # Don't output data for L, as that's the default value, see bidi.c.
	 if (otype != "L" && startcode != "")
	 {
	     if (!first)
		 printf ",\n";
	     else
		 first = 0;
	     printf "\t{ 0x%s, 0x%s, %s }", startcode, endcode, trtype(otype);
	 }
	 otype = ntype;
	 startcode = code;
	 endcode = code;
     }
     else
	 endcode = code;
 }

END {
     printf " };\n";
 }