view lisp/mh-e/mh-inc.el @ 107793:d3738a1728c6

* verilog-mode.el (verilog-forward-sexp, verilog-calc-1): Support "disable fork" and "fork wait" multi word keywords, suggested by Steve Pearlmutter. (verilog-pretty-declarations): Support lineup of declarations in port lists. (verilog-skip-backward-comments, verilog-skip-forward-comment-p): fix bug for /* / comments (verilog-backward-syntactic-ws, verilog-forward-syntactic-ws): Speed up and simplfy as this is never called with a bound. (verilog-pretty-declarations): Enhance to line up declarations inside a parameter list, suggested by Alan Morgan. (verilog-pretty-expr): Tune assignment regular expression match string for corner cases; also use markers instead of character number as indent changes the later. (verilog-type-keywords): Fix pulldown as missing keyword. (verilog-read-sub-decls-line): Fix comments in AUTO_TEMPLATE causing truncation of AUTOWIRE signals. Reported by Bruce Tennant. (verilog-auto-inst, verilog-auto-inst-port): Add vl_mbits for AUTO_TEMPLATEs needing multiple array bits. Suggested by Bruce Tennant. (verilog-keywords): (verilog-1800-2005-keywords, verilog-1800-2009-keywords): Add IEEE 1800-2009 keywords, including "global.".

;;; mh-inc.el --- MH-E "inc" and separate mail spool handling

;; Copyright (C) 2003, 2004, 2006, 2007, 2008, 2009, 2010
;;   Free Software Foundation, Inc.

;; Author: Peter S. Galbraith <[e-mail]>
;; Maintainer: Bill Wohler <[e-mail]>
;; Keywords: mail
;; See: mh-e.el

;; This file is part of GNU Emacs.

;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:

;; Support for inc. In addition to reading from the system mailbox,
;; inc can also be used to incorporate mail from multiple spool files
;; into separate folders. See "C-h v mh-inc-spool-list".

;;; Change Log:

;;; Code:

(require 'mh-e)
(mh-require-cl)

(defvar mh-inc-spool-map-help nil
  "Help text for `mh-inc-spool-map'.")

(define-key mh-inc-spool-map "?"
  '(lambda ()
     (interactive)
     (if mh-inc-spool-map-help
         (mh-help mh-inc-spool-map-help)
       (mh-ephem-message
        "There are no keys defined yet; customize `mh-inc-spool-list'"))))

;;;###mh-autoload
(defun mh-inc-spool-make ()
  "Make all commands and defines keys for contents of `mh-inc-spool-list'."
  (setq mh-inc-spool-map-help nil)
  (when mh-inc-spool-list
    (loop for elem in mh-inc-spool-list
          do (let ((spool (nth 0 elem))
                   (folder (nth 1 elem))
                   (key (nth 2 elem)))
               (progn
                 (mh-inc-spool-generator folder spool)
                 (mh-inc-spool-def-key key folder))))))

(defalias 'mh-inc-spool-make-no-autoload 'mh-inc-spool-make)

(defun mh-inc-spool-generator (folder spool)
  "Create a command to inc into FOLDER from SPOOL file."
  (let ((folder1 (make-symbol "folder"))
        (spool1 (make-symbol "spool")))
    (set folder1 folder)
    (set spool1 spool)
    (setf (symbol-function (intern (concat "mh-inc-spool-" folder)))
          `(lambda ()
             ,(format "Inc spool file %s into folder %s." spool folder)
             (interactive)
             (mh-inc-folder ,spool1 (concat "+" ,folder1))))))

(defun mh-inc-spool-def-key (key folder)
  "Define a KEY in `mh-inc-spool-map' to inc FOLDER and collect help string."
  (when (not (= 0 key))
    (define-key mh-inc-spool-map (format "%c" key)
       (intern (concat "mh-inc-spool-" folder)))
    (add-to-list 'mh-inc-spool-map-help
                 (concat "[" (char-to-string key) "] inc " folder " folder\n")
                 t)))

(provide 'mh-inc)

;; Local Variables:
;; indent-tabs-mode: nil
;; sentence-end-double-space: nil
;; End:

;; arch-tag: 3713cf2a-6082-4cb4-8ce2-99d9acaba835
;;; mh-inc.el ends here