view etc/ETAGS.EBNF @ 45621:d3c9a2133579

(redisplay_internal, redisplay_window, decode_mode_spec): Cast `current_column' return value to int. (back_to_previous_visible_line_start, reseat_at_next_visible_line_start, next_element_from_buffer): Cast `indented_beyond_p' 3rd arg to float.

EBNF (Extended Backus Normal Form) description of the format of the tags
file created by etags.c and interpreted by etags.el
Francesco Potorti` <[e-mail]> 2002
================================================================

FF ::= #x0c				   /* form feed */

LF ::= #x0a				   /* line feed */

DEL ::= #x7f				   /* pattern terminator */

SOH ::= #x01				   /* name terminator */

regchar ::= [^#x0a#x0c#x7f]		   /* regular character */

regstring ::= { regchar }		   /* regular string */

unsint ::= [0-9] { [0-9] }		   /* non-negative integer */



tagfile ::= { tagsection }		   /* a tags file */

tagsection ::= FF LF ( includesec | regularsec ) LF

includesec ::= filename ",include" [ LF fileprop ]

regularsec ::= filename "," [ unsint ] [ LF fileprop ] { LF tag }

filename ::= regchar regstring		   /* a file name */

fileprop ::= DEL "(" regstring ")"

tag ::= directtag | patterntag

directtag ::= DEL realposition

patterntag ::= pattern DEL [ tagname SOH ] position

pattern ::= regstring			   /* a tag pattern */

tagname ::= regchar regstring		   /* a tag name */

position ::= realposition | ","

realposition ::= "," unsint | unsint "," | unsint "," unsint