view lisp/net/hmac-def.el @ 109372:dd04c65fb401

Convert function definitions to standard C. * src/xterm.c (x_frame_of_widget, x_alloc_nearest_color_for_widget) (x_alloc_lighter_color_for_widget, cvt_string_to_pixel) (cvt_pixel_dtor, x_window_to_menu_bar, xt_action_hook) (xaw_jump_callback, xaw_scroll_callback) (x_create_toolkit_scroll_bar, x_set_toolkit_scroll_bar_thumb) (x_wm_set_size_hint, x_activate_timeout_atimer): Convert definitions to standard C. * src/xmenu.c (menubar_id_to_frame, popup_get_selection) (popup_activate_callback, popup_deactivate_callback) (menu_highlight_callback, menubar_selection_callback) (apply_systemfont_to_dialog, apply_systemfont_to_menu) (free_frame_menubar, popup_selection_callback, as) (create_and_show_popup_menu, dialog_selection_callback) (create_and_show_dialog): * src/xfns.c (hack_wm_protocols, x_window): * src/xfaces.c (x_update_menu_appearance): * src/widget.c (get_default_char_pixel_size, pixel_to_char_size) (char_to_pixel_size, round_size_to_char, get_wm_shell) (set_frame_size, update_wm_hints, setup_frame_gcs) (update_various_frame_slots, update_from_various_frame_slots) (EmacsFrameInitialize, EmacsFrameRealize, EmacsFrameResize) (EmacsFrameSetValues, EmacsFrameQueryGeometry) (EmacsFrameSetCharSize, widget_store_internal_border): Likewise.

;;; hmac-def.el --- A macro for defining HMAC functions.

;; Copyright (C) 1999, 2001, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.

;; Author: Shuhei KOBAYASHI <[e-mail]>
;; Keywords: HMAC, RFC2104

;; This file is part of GNU Emacs.

;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:

;; This program is implemented from RFC2104,
;; "HMAC: Keyed-Hashing for Message Authentication".

;;; Code:

(defmacro define-hmac-function (name H B L &optional bit)
  "Define a function NAME(TEXT KEY) which computes HMAC with function H.

HMAC function is H(KEY XOR opad, H(KEY XOR ipad, TEXT)):

H is a cryptographic hash function, such as SHA1 and MD5, which takes
a string and return a digest of it (in binary form).
B is a byte-length of a block size of H. (B=64 for both SHA1 and MD5.)
L is a byte-length of hash outputs. (L=16 for MD5, L=20 for SHA1.)
If BIT is non-nil, truncate output to specified bits."
  `(defun ,name (text key)
     ,(concat "Compute "
	      (upcase (symbol-name name))
	      " over TEXT with KEY.")
     (let ((key-xor-ipad (make-string ,B ?\x36))
	   (key-xor-opad (make-string ,B ?\x5C))
	   (len (length key))
	   (pos 0))
       (unwind-protect
	   (progn
	     ;; if `key' is longer than the block size, apply hash function
	     ;; to `key' and use the result as a real `key'.
	     (if (> len ,B)
		 (setq key (,H key)
		       len ,L))
	     (while (< pos len)
	       (aset key-xor-ipad pos (logxor (aref key pos) ?\x36))
	       (aset key-xor-opad pos (logxor (aref key pos) ?\x5C))
	       (setq pos (1+ pos)))
	     (setq key-xor-ipad (unwind-protect
				    (concat key-xor-ipad text)
				  (fillarray key-xor-ipad 0))
		   key-xor-ipad (unwind-protect
				    (,H key-xor-ipad)
				  (fillarray key-xor-ipad 0))
		   key-xor-opad (unwind-protect
				    (concat key-xor-opad key-xor-ipad)
				  (fillarray key-xor-opad 0))
		   key-xor-opad (unwind-protect
				    (,H key-xor-opad)
				  (fillarray key-xor-opad 0)))
	     ;; now `key-xor-opad' contains
	     ;; H(KEY XOR opad, H(KEY XOR ipad, TEXT)).
	     ,(if (and bit (< (/ bit 8) L))
		  `(substring key-xor-opad 0 ,(/ bit 8))
		;; return a copy of `key-xor-opad'.
		`(concat key-xor-opad)))
	 ;; cleanup.
	 (fillarray key-xor-ipad 0)
	 (fillarray key-xor-opad 0)))))

(provide 'hmac-def)

;; arch-tag: 645adcef-b835-4900-a10a-11f636c982b9
;;; hmac-def.el ends here