view lisp/misc.el @ 93620:dfdeba5ae4fd

(highlight-changes-mode): Rename from highlight-changes; no longer uses sub-modes active and passive; implemented by define-minor-mode. (highlight-changes-toggle-visibility): New function, to replace the old passive/active submodes of global-highlight-changes-mode; implemented by define-minor-mode. (global-highlight-changes-mode'): Rename from global-highlight-changes; rewrite using define-globalized-minor-mode. (hilit-chg-major-mode-hook, hilit-chg-check-global) (hilit-chg-post-command-hook, hilit-chg-check-global) (hilit-chg-update-all-buffers, hilit-chg-turn-off-maybe): Remove due to use of define-globalized-minor-mode. (highlight-changes-global-initial-state): Change to be boolean. (highlight-changes-visible-string, highlight-changes-invisible-string): Rename from highlight-changes-active-string and highlight-changes-passive-string. (hilit-chg-update, hilit-chg-set): Use them. (global-highlight-changes-mode): Rename from global-highlight-changes. (hilit-chg-map-changes, hilit-chg-display-changes): Add arguments to docstring. (hilit-chg-hide-changes): Rewrite to use dolist. (hilit-chg-set-face-on-change, hilit-chg-update) (highlight-changes-rotate-faces): Use highlight-changes-visible-mode variable instead of testing highlight-changes-mode. (highlight-markup-buffers): Add reuire ediff-util; argument on calls to highlight-changes-mode changed. (highlight-compare-with-file): Fix problems with interactive call giving invalid default file.

;;; misc.el --- some nonstandard basic editing commands for Emacs

;; Copyright (C) 1989, 2001, 2002, 2003, 2004, 2005,
;;   2006, 2007, 2008 Free Software Foundation, Inc.

;; Maintainer: FSF
;; Keywords: convenience

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 3, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
;; Boston, MA 02110-1301, USA.

;;; Commentary:

;;; Code:

(defun copy-from-above-command (&optional arg)
  "Copy characters from previous nonblank line, starting just above point.
Copy ARG characters, but not past the end of that line.
If no argument given, copy the entire rest of the line.
The characters copied are inserted in the buffer before point."
  (interactive "P")
  (let ((cc (current-column))
	n
	(string ""))
    (save-excursion
      (beginning-of-line)
      (backward-char 1)
      (skip-chars-backward "\ \t\n")
      (move-to-column cc)
      ;; Default is enough to copy the whole rest of the line.
      (setq n (if arg (prefix-numeric-value arg) (point-max)))
      ;; If current column winds up in middle of a tab,
      ;; copy appropriate number of "virtual" space chars.
      (if (< cc (current-column))
	  (if (= (preceding-char) ?\t)
	      (progn
		(setq string (make-string (min n (- (current-column) cc)) ?\s))
		(setq n (- n (min n (- (current-column) cc)))))
	    ;; In middle of ctl char => copy that whole char.
	    (backward-char 1)))
      (setq string (concat string
			   (buffer-substring
			    (point)
			    (min (save-excursion (end-of-line) (point))
				 (+ n (point)))))))
    (insert string)))

;; Variation of `zap-to-char'.

(defun zap-up-to-char (arg char)
  "Kill up to, but not including ARGth occurrence of CHAR.
Case is ignored if `case-fold-search' is non-nil in the current buffer.
Goes backward if ARG is negative; error if CHAR not found.
Ignores CHAR at point."
  (interactive "p\ncZap up to char: ")
  (let ((direction (if (>= arg 0) 1 -1)))
    (kill-region (point)
		 (progn
		   (forward-char direction)
		   (unwind-protect
		       (search-forward (char-to-string char) nil nil arg)
		     (backward-char direction))
		   (point)))))

;; These were added with an eye to making possible a more CCA-compatible
;; command set; but that turned out not to be interesting.

(defun mark-beginning-of-buffer ()
  "Set mark at the beginning of the buffer."
  (interactive)
  (push-mark (point-min)))

(defun mark-end-of-buffer ()
  "Set mark at the end of the buffer."
  (interactive)
  (push-mark (point-max)))

(defun upcase-char (arg)
  "Uppercasify ARG chars starting from point.  Point doesn't move."
  (interactive "p")
  (save-excursion
    (upcase-region (point) (progn (forward-char arg) (point)))))

(defun forward-to-word (arg)
  "Move forward until encountering the beginning of a word.
With argument, do this that many times."
  (interactive "p")
  (or (re-search-forward (if (> arg 0) "\\W\\b" "\\b\\W") nil t arg)
      (goto-char (if (> arg 0) (point-max) (point-min)))))

(defun backward-to-word (arg)
  "Move backward until encountering the end of a word.
With argument, do this that many times."
  (interactive "p")
  (forward-to-word (- arg)))

(provide 'misc)

;;; arch-tag: 908f7884-c19e-4388-920c-9cfa425e449b
;;; misc.el ends here