view msdos/sedleim.inp @ 109099:e16f43875a48

Remove P_ and __P macros. * lwlib/lwlib-Xaw.h: Remove P_ and __P macros. * lwlib/lwlib-Xlw.h: * lwlib/lwlib-Xm.h: * lwlib/lwlib-int.h: * lwlib/lwlib-utils.h: * lwlib/lwlib.h: Likewise. * src/buffer.h: Remove P_ and __P macros. * src/category.h: * src/ccl.h: * src/character.h: * src/charset.h: * src/cm.h: * src/coding.h: * src/composite.h: * src/dispextern.h: * src/disptab.h: * src/font.h: * src/fontset.h: * src/frame.h: * src/gtkutil.h: * src/indent.h: * src/intervals.h: * src/keyboard.h: * src/keymap.h: * src/lisp.h: * src/macros.h: * src/md5.h: * src/menu.h: * src/msdos.h: * src/nsterm.h: * src/puresize.h: * src/region-cache.h: * src/syntax.h: * src/syssignal.h: * src/systime.h: * src/termhooks.h: * src/w32term.h: * src/widget.h: * src/window.h: * src/xgselect.h: * src/xsettings.h: * src/xterm.h: Likewise.

# -sedleim.inp-----------------------------------------------------------
# Configuration script for leim/Makefile under DJGPP v2.x
# ----------------------------------------------------------------------
#
# Copyright (C) 1999, 2000, 2001, 2002, 2003, 2004,
#   2005, 2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
#
# This file is part of GNU Emacs.
#
# This file is free software; as a special exception, the author gives
# unlimited permission to copy and/or distribute it, with or without
# modifications, as long as this notice is preserved.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
#
# ----------------------------------------------------------------------
/^SHELL *=/c\
SHELL=/xyzzy/command\
MAKESHELL=/xyzzy/command

/^version=/d
/^prefix=/d
/^datadir=/s|@datadir@|../..|
/^srcdir=/s|srcdir=@srcdir@|srcdir := $(subst \\,/,$(shell cd))|

/^INSTALLDIR=/c\
INSTALLDIR=.

/touch stamp-subdir/s|touch|djecho "stamp-subdir" >|
s|\([ 	]\)echo|\1djecho|g
/^	@true *$/d

/RUN-EMACS *=/,/^$/c\
export EMACSLOADPATH=${buildlisppath}\
RUN-EMACS = ${BUILT-EMACS} -batch --no-init-file --no-site-file --multibyte

/^	cd ../c\
	${MAKE} -C ../src ${MFLAGS} emacs

/else make quail/c\
	if not exist quail\\nul make quail

/if \[ -f $@ \]\; then true/d
/fi$/s/; fi$//

/^leim-list.el:/,/^$/ {
	/^	if/d
	/^	else/,/^	fi/d
	s|	 *|	|
	/^	--eval/,/; \\$/s|\; \\||
}

/^install:/,/^$/c\
install: all\

/^	if test -f/d
/^distclean:/,/^$/ {
	s|\(rm -f Makefile\)|\1 stamp-subdir|
}

# arch-tag: 33c5eed1-78bc-4a6e-9d11-cbc7c541b763