view lisp/erc/erc-replace.el @ 111067:e36c65ac23bf

Merge changes made in Gnus trunk. nnimap.el (nnimap-insert-partial-structure): Fix boundary detection. spam.el (spam-list-of-processors): Mark as obsolete. gnus-art.el (gnus-blocked-images): New function. Allow the `gnus-blocked-images' to be a function. gnus-art.el (gnus-article-wash-function): Remove it, and use `mm-text-html-renderer' instead. mm-decode.el (mm-inline-text-html-renderer): Removed. mm-decode.el (mm-inline-media-tests): Removed use. mm-view.el (mm-inline-text-html): Removed use. mm-view.el (mm-text-html-renderer-alist): Add the `shr' and `gnus-w3m' symbols. gnus.texi (Article Washing): shr and gnus-w3m, not the direct function names. gnus-art.el (article-wash-html): Simplify and remove the charset stuff. Use the normal html rendering code instead of the special html washing code. mm-view.el (mm-text-html-washer-alist): Removed. gnus-news.texi: Mention that mm-text-html-renderer is the only HTML variable now. shr.el (shr-tag-table): Remove useless nconc.

;; erc-replace.el -- wash and massage messages inserted into the buffer

;; Copyright (C) 2001, 2002, 2004, 2006, 2007,
;;   2008, 2009, 2010 Free Software Foundation, Inc.

;; Author: Andreas Fuchs <[e-mail]>
;; Maintainer: Mario Lang ([e-mail])
;; Keywords: IRC, client, Internet

;; This file is part of GNU Emacs.

;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:

;; This module allows you to systematically replace text in incoming
;; messages.  Load erc-replace, and customize `erc-replace-alist'.
;; Then add to your ~/.emacs:

;; (require 'erc-replace)
;; (erc-replace-mode 1)

;;; Code:

(require 'erc)

(defgroup erc-replace nil
  "Replace text from incoming messages"
  :group 'erc)

(defcustom erc-replace-alist nil
  "Alist describing text to be replaced in incoming messages.
This is useful for filters.

The alist has elements of the form (FROM . TO).  FROM can be a regular
expression or a variable, or any sexp, TO can be a string or a
function to call, or any sexp.  If a function, it will be called with
one argument, the string to be replaced, and it should return a
replacement string."
  :group 'erc-replace
  :type '(repeat (cons :tag "Search & Replace"
		       (choice :tag "From"
			       regexp
			       variable
			       sexp)
		       (choice :tag "To"
			       string
			       function
			       sexp))))

(defun erc-replace-insert ()
  "Function to run from `erc-insert-modify-hook'.
It replaces text according to `erc-replace-alist'."
  (mapcar (lambda (elt)
	    (goto-char (point-min))
	    (let ((from (car elt))
		  (to (cdr elt)))
	      (unless (stringp from)
		(setq from (eval from)))
	      (while (re-search-forward from nil t)
		(cond ((stringp to)
		       (replace-match to))
		      ((and (symbolp to) (fboundp to))
		       (replace-match (funcall to (match-string 0))))
		      (t
		       (eval to))))))
	  erc-replace-alist))

;;;###autoload (autoload 'erc-replace-mode "erc-replace")
(define-erc-module replace nil
  "This mode replaces incoming text according to `erc-replace-alist'."
  ((add-hook 'erc-insert-modify-hook
	     'erc-replace-insert))
  ((remove-hook 'erc-insert-modify-hook
		'erc-replace-insert)))

(provide 'erc-replace)

;;; erc-replace.el ends here
;;
;; Local Variables:
;; indent-tabs-mode: t
;; tab-width: 8
;; End:

;; arch-tag: dd904a59-d8a6-47f8-ac3a-76b698289a18