view etc/ETAGS.EBNF @ 43882:e601e469e7a4

(fortran-mode): Set comment-padding to "$$$". Add fortran-comment-line-start-skip to comment-start-skip. (fortran-comment-indent): Keep whole-line comments in column 0. (fortran-find-comment-start-skip): New arg `all'. If ALL is nil, make sure we only match comment-start-skip if we can't match fortran-comment-line-start-skip. Fix bug that made it return t but without moving point when matching '!'! (a false-comment followed by a real comment). (fortran-indent-comment): Use new `all' argument above. Be careful not to add an incorrect comment-starter like "C" in comment-column. (fortran-split-line): When splitting a comment, reuse the comment starter from the current line rather than fortran-comment-line-start. (fortran-indent-line, fortran-auto-fill): Simplify thanks to the cleaner behavior of fortran-find-comment-start-skip. (fortran-fill): Don't be confused by ! inside a comment. (fortran-break-line): Minor cleanup and simplification.

EBNF (Extended Backus Normal Form) description of the format of the tags
file created by etags.c and interpreted by etags.el
Francesco Potorti` <[e-mail]> 2002
================================================================

FF ::= #x0c				   /* form feed */

LF ::= #x0a				   /* line feed */

DEL ::= #x7f				   /* pattern terminator */

SOH ::= #x01				   /* name terminator */

regchar ::= [^#x0a#x0c#x7f]		   /* regular character */

regstring ::= { regchar }		   /* regular string */

unsint ::= [0-9] { [0-9] }		   /* non-negative integer */



tagfile ::= { tagsection }		   /* a tags file */

tagsection ::= FF LF ( includesec | regularsec ) LF

includesec ::= filename ",include" [ LF fileprop ]

regularsec ::= filename "," [ unsint ] [ LF fileprop ] { LF tag }

filename ::= regchar regstring		   /* a file name */

fileprop ::= DEL "(" regstring ")"

tag ::= directtag | patterntag

directtag ::= DEL realposition

patterntag ::= pattern DEL [ tagname SOH ] position

pattern ::= regstring			   /* a tag pattern */

tagname ::= regchar regstring		   /* a tag name */

position ::= realposition | ","

realposition ::= "," unsint | unsint "," | unsint "," unsint