view etc/ETAGS.EBNF @ 44067:e8a136850817

(QCfeature, QCdatagram): Removed variables. (QCtype, Qdatagram): New variables. (network_process_featurep): Removed function. (Fmake_network_process): Removed :feature check. Use :type 'datagram instead of :datagram t to create a datagram socket. This allows us to add other connection types (e.g. raw sockets) later in a consistent manner. (init_process) [subprocess]: Provide list of supported subfeatures for feature make-network-process. (syms_of_process) [subprocess]: Remove QCfeature and QCdatagram. Intern and staticpro QCtype and Qdatagram. (syms_of_process) [!subprocess]: Intern and staticpro QCtype.

EBNF (Extended Backus Normal Form) description of the format of the tags
file created by etags.c and interpreted by etags.el
Francesco Potorti` <[e-mail]> 2002
================================================================

FF ::= #x0c				   /* form feed */

LF ::= #x0a				   /* line feed */

DEL ::= #x7f				   /* pattern terminator */

SOH ::= #x01				   /* name terminator */

regchar ::= [^#x0a#x0c#x7f]		   /* regular character */

regstring ::= { regchar }		   /* regular string */

unsint ::= [0-9] { [0-9] }		   /* non-negative integer */



tagfile ::= { tagsection }		   /* a tags file */

tagsection ::= FF LF ( includesec | regularsec ) LF

includesec ::= filename ",include" [ LF fileprop ]

regularsec ::= filename "," [ unsint ] [ LF fileprop ] { LF tag }

filename ::= regchar regstring		   /* a file name */

fileprop ::= DEL "(" regstring ")"

tag ::= directtag | patterntag

directtag ::= DEL realposition

patterntag ::= pattern DEL [ tagname SOH ] position

pattern ::= regstring			   /* a tag pattern */

tagname ::= regchar regstring		   /* a tag name */

position ::= realposition | ","

realposition ::= "," unsint | unsint "," | unsint "," unsint