view msdos/sed1.inp @ 17044:f07c36097f33

Include charset.h and category.h. (Vsyntax_code_object): New variable. (Fmodify_syntax_entry): Handle multibyte characters. A multibyte character in matching parenthesis is also handled correctly. Use shared object in the vector Vsyntax_code_object for an ASCII character. (describe_syntax): Handle a multibyte character in matching parenthesis. (describe_syntax_1): Describe also parent syntax tables. (scan_words, Fforward_comment): Handle multibyte characters. (scan_lists, char_quoted, Fbackward_prefix_chars): Likewise. (scan_sexps_forward): Likewise. (init_syntax_once): Initialize Vsyntax_code_object. Initialize Vstandard_syntax_table by share objects in Vsyntax_code_object. (syms_of_syntax): Staticpro Vsyntax_code_object.

# -sed1.inp-------------------------------------------------------------
# Configuration script for src/makefile
# ----------------------------------------------------------------------
#
# In case src/Makefile needs to rebuild `make-doc.exe' (might happen under
# Windows 95), make sure it gets built with commands that DOS
# understands (one command per line).
s/^#.*//
s/^[ \f\t][ \f\t]*$//
s/^ /	/
s/\.h\.in/.h-in/
s!^	\./temacs!	go32 temacs!
s!/bin/sh!command.com!
/^MAKE *=/s/^/# /
/^SHELL *=/s/^/# /
/^srcdir *=/s/@[^@\n]*@/./
/^VPATH *=/s/@[^@\n]*@/./
/^CC *=/s/@[^@\n]*@/gcc/
/^CPP *=/s/@[^@\n]*@/gcc -e/
/^CFLAGS *=/s/@[^@\n]*@/-O2 -g/
/^LN_S *=/s/@[^@\n]*@/ln -s/
/^M_FILE *=/s!@[^@\n]*@!m/intel386.h!
/^S_FILE *=/s!@[^@\n]*@!s/msdos.h!
/^@SET_MAKE@$/s/@SET_MAKE@//
/^.\${libsrc}make-docfile.*>/s!make-docfile!make-doc.exe -o ../etc/DOC!
/^.\${libsrc}make-doc/s!>.*$!!
/^\${libsrc}make-docfile:/c\
${libsrc}make-doc.exe:\
	cd ..\
	cd lib-src\
	$(MAKE) ${MFLAGS} make-docfile -W make-docfile.c\
	cd ..\
	cd src
/^	cd \${libsrc}; \${MAKE} \${MFLAGS} make-docfile/d
/\${libsrc}make-docfile/s/-docfile[ 	]/-doc.exe /
/^[ 	]*$/d
/^temacs:/s/prefix-args//
/^	#/d