view msdos/sedleim.inp @ 109264:f1266b2f017e

Untabify doc/misc/*.texi. * autotype.texi, cl.texi, dired-x.texi, ebrowse.texi, ede.texi: * eieio.texi, faq.texi, flymake.texi, forms.texi, gnus-faq.texi: * idlwave.texi, mh-e.texi, org.texi, pcl-cvs.texi, pgg.texi: * reftex.texi, sasl.texi, sc.texi, sem-user.texi, semantic.texi: * sieve.texi, smtpmail.texi, speedbar.texi, vip.texi, viper.texi: * widget.texi: Untabify (except for examples).

# -sedleim.inp-----------------------------------------------------------
# Configuration script for leim/Makefile under DJGPP v2.x
# ----------------------------------------------------------------------
#
# Copyright (C) 1999, 2000, 2001, 2002, 2003, 2004,
#   2005, 2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
#
# This file is part of GNU Emacs.
#
# This file is free software; as a special exception, the author gives
# unlimited permission to copy and/or distribute it, with or without
# modifications, as long as this notice is preserved.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
#
# ----------------------------------------------------------------------
/^SHELL *=/c\
SHELL=/xyzzy/command\
MAKESHELL=/xyzzy/command

/^version=/d
/^prefix=/d
/^datadir=/s|@datadir@|../..|
/^srcdir=/s|srcdir=@srcdir@|srcdir := $(subst \\,/,$(shell cd))|

/^INSTALLDIR=/c\
INSTALLDIR=.

/touch stamp-subdir/s|touch|djecho "stamp-subdir" >|
s|\([ 	]\)echo|\1djecho|g
/^	@true *$/d

/RUN-EMACS *=/,/^$/c\
export EMACSLOADPATH=${buildlisppath}\
RUN-EMACS = ${BUILT-EMACS} -batch --no-init-file --no-site-file --multibyte

/^	cd ../c\
	${MAKE} -C ../src ${MFLAGS} emacs

/else make quail/c\
	if not exist quail\\nul make quail

/if \[ -f $@ \]\; then true/d
/fi$/s/; fi$//

/^leim-list.el:/,/^$/ {
	/^	if/d
	/^	else/,/^	fi/d
	s|	 *|	|
	/^	--eval/,/; \\$/s|\; \\||
}

/^install:/,/^$/c\
install: all\

/^	if test -f/d
/^distclean:/,/^$/ {
	s|\(rm -f Makefile\)|\1 stamp-subdir|
}

# arch-tag: 33c5eed1-78bc-4a6e-9d11-cbc7c541b763