view lisp/gnus-mh.el @ 23894:f96c37cbdeef

New file. Mule related code extracted from ps-print.el. Require ps-print, provide ps-mule. (ps-multibyte-buffer): Add autoload cookie. (ps-mule-prepare-ascii-font): New fun. (ps-mule-set-ascii-font): New fun. (ps-mule-skip-same-charset): Fun deleted. (ps-mule-plot-string): Set ps-mule-current-charset. (ps-mule-initialize): Add autload cookie. Don't set ps-mule-font-info-database here. (ps-mule-begin-job): Renamed from ps-mule-begin. Update ps-mule-font-info-database and ps-control-or-escape-regexp. (ps-mule-begin-page): New fun. Doc fix. Require ps-print only when compiled. (ps-mule-prologue-generated): New fun. (ps-mule-plot-string): Add autoload cookie. (ps-mule-begin-job): Call ps-mule-prologue-generated. Programming uniformization and little code improvement. (ps-mule-prepare-font): Programming uniformization. (ps-mule-find-wrappoint, ps-mule-plot-rule-cmpchar) (ps-mule-string-encoding, ps-mule-begin-job): Little code improvement. Always require ps-print. Move some function definitions for Emacs 20.2 and the earlier to ps-print.el. (ps-mule-find-wrappoint): Make it work also with Emacs 20.2. (ps-mule-begin-job): Delete nil and unknown from a list of character sets found by find-charset-region.

;;; gnus-mh.el --- mh-e interface for Gnus
;; Copyright (C) 1994,95,96 Free Software Foundation, Inc.

;; Author: Masanobu UMEDA <[e-mail]>
;;	Lars Magne Ingebrigtsen <[e-mail]>
;; Keywords: news

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
;; Boston, MA 02111-1307, USA.

;;; Commentary:

;;; Send mail using mh-e.

;; The following mh-e interface is all cooperative works of
;; [e-mail] (TANAKA Hiroshi), [e-mail]
;; (Yoshikatsu Kawabe), and [e-mail] (Toshiaki
;; SHINGU).

;;; Code:

(require 'mh-e)
(require 'mh-comp)
(require 'gnus)
(require 'gnus-msg)
(eval-when-compile (require 'cl))

(defun gnus-summary-save-article-folder (&optional arg)
  "Append the current article to an mh folder.
If N is a positive number, save the N next articles.
If N is a negative number, save the N previous articles.
If N is nil and any articles have been marked with the process mark,
save those articles instead."
  (interactive "P")
  (let ((gnus-default-article-saver 'gnus-summary-save-in-folder))
    (gnus-summary-save-article arg)))

(defun gnus-summary-save-in-folder (&optional folder)
  "Save this article to MH folder (using `rcvstore' in MH library).
Optional argument FOLDER specifies folder name."
  ;; Thanks to [e-mail] and [e-mail].
  (mh-find-path)
  (let ((folder
	 (cond ((and (eq folder 'default)
		     gnus-newsgroup-last-folder)
		gnus-newsgroup-last-folder)
	       (folder folder)
	       (t (mh-prompt-for-folder 
		   "Save article in"
		   (funcall gnus-folder-save-name gnus-newsgroup-name
			    gnus-current-headers gnus-newsgroup-last-folder)
		   t))))
	(errbuf (get-buffer-create " *Gnus rcvstore*"))
	;; Find the rcvstore program.
	(exec-path (if mh-lib (cons mh-lib exec-path) exec-path)))
    (gnus-eval-in-buffer-window gnus-original-article-buffer
      (save-restriction
	(widen)
	(unwind-protect
	    (call-process-region 
	     (point-min) (point-max) "rcvstore" nil errbuf nil folder)
	  (set-buffer errbuf)
	  (if (zerop (buffer-size))
	      (message "Article saved in folder: %s" folder)
	    (message "%s" (buffer-string)))
	  (kill-buffer errbuf))))
    (setq gnus-newsgroup-last-folder folder)))

(defun gnus-Folder-save-name (newsgroup headers &optional last-folder)
  "Generate folder name from NEWSGROUP, HEADERS, and optional LAST-FOLDER.
If variable `gnus-use-long-file-name' is nil, it is +News.group.
Otherwise, it is like +news/group."
  (or last-folder
      (concat "+"
	      (if gnus-use-long-file-name
		  (gnus-capitalize-newsgroup newsgroup)
		(gnus-newsgroup-directory-form newsgroup)))))

(defun gnus-folder-save-name (newsgroup headers &optional last-folder)
  "Generate folder name from NEWSGROUP, HEADERS, and optional LAST-FOLDER.
If variable `gnus-use-long-file-name' is nil, it is +news.group.
Otherwise, it is like +news/group."
  (or last-folder
      (concat "+"
	      (if gnus-use-long-file-name
		  newsgroup
		(gnus-newsgroup-directory-form newsgroup)))))

(provide 'gnus-mh)

;;; gnus-mh.el ends here