view lisp/master.el @ 109141:fa173b9bd9ce

Fix some bad prototypes and formatting after conversion from K&R declaration. * lwlib/lwlib-Xaw.c: Include <ctype.h> for isdigit. (fill_xft_data, set_text): Remove unused variable screen. (draw_text): Cast bp to FcChar8*. (find_xft_data): Return 0 if inst or xft_data is not set. (wm_delete_window): Correct prototype. Initialize widget to 0 and return if widget is still 0 after loop. * lwlib/xlwmenu.c (XlwMenuSetValues, XlwMenuInitialize): Correct prototype. (display_menu_item): Remove unused variable gi. (make_windows_if_needed): Remove unused variable screen. (XlwMenuRedisplay): Remove unused variable i. * src/gtkutil.c (xg_get_pixbuf_from_pix_and_mask) (xg_get_image_for_pixmap, create_dialog) (xg_get_file_with_selection, xg_get_file_name, update_cl_data) (menuitem_highlight_callback, make_menu_item) (xg_create_one_menuitem, create_menus, xg_update_menu_item) (xg_create_scroll_bar, xg_update_scrollbar_pos) (xg_set_toolkit_scroll_bar_thumb, xg_tool_bar_button_cb) (xg_tool_bar_proxy_help_callback, xg_tool_bar_detach_callback) (xg_tool_bar_attach_callback, xg_tool_bar_help_callback) (xg_tool_bar_item_expose_callback): Reformat prototype. (xg_update_menubar): GList *group => GSList *group. (xg_modify_menubar_widgets): Initialize witem to 0, check witem != 0 before use. (update_frame_tool_bar): 4:th param to xg_get_image_for_pixmap changed to GTK_IMAGE (wimage). * src/xsettings.c (something_changedCB, parse_settings) (apply_xft_settings): Reformat prototype. (something_changedCB, init_gconf): Remove unused variable i. (read_settings): Remove unused variable long_len. * src/xsmfns.c (SSDATA): New macro. (smc_save_yourself_CB, x_session_initialize): Use SSDATA for strings passed to strlen/strcpy/strcat. (create_client_leader_window): Surround with #ifndef USE_GTK. Cast 7:th arg to XChangeProperty to (unsigned char *)

;;; master.el --- make a buffer the master over another buffer

;; Copyright (C) 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010
;;   Free Software Foundation, Inc.

;; Author: Alex Schroeder <[e-mail]>
;; Maintainer: Alex Schroeder <[e-mail]>
;; Version: 1.0.2
;; Keywords: comm

;; This file is part of GNU Emacs.

;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:

;; master-mode is a minor mode which enables you to scroll another
;; buffer (the slave) without leaving your current buffer (the master).

;; It can be used by sql.el, for example: The SQL buffer is the master
;; and its SQLi buffer is the slave.  This allows you to scroll the SQLi
;; buffer containing the output from the SQL buffer containing the
;; commands.
;;
;; This is how to use sql.el and master.el together: The variable
;; sql-buffer contains the slave buffer.  It is a local variable in the
;; SQL buffer.
;;
;; (add-hook 'sql-mode-hook
;;	   (function (lambda ()
;;		       (master-mode t)
;;		       (master-set-slave sql-buffer))))
;; (add-hook 'sql-set-sqli-hook
;;	   (function (lambda ()
;;		       (master-set-slave sql-buffer))))

;;; Thanks to all the people who helped me out:
;;
;; Rob Riepel <networking.stanford.edu>

;;; History:
;;

;;; Code:

(defgroup master nil
  "Support for master/slave relationships between buffers."
  :version "22.1"
  :group 'convenience)

;; Variables that don't need initialization.

(defvar master-of nil
  "Slave buffer of the current buffer.  See `master-mode'.
You can set this variable using `master-set-slave'.")

(defvar master-set-slave-hook nil
  "Hook run after the slave is changed using \\[master-set-slave].")

;;; Define master mode.

;;;###autoload
(define-minor-mode master-mode
  "Toggle Master mode.
With no argument, this command toggles the mode.
Non-null prefix argument turns on the mode.
Null prefix argument turns off the mode.

When Master mode is enabled, you can scroll the slave buffer using the
following commands:

\\{master-mode-map}

The slave buffer is stored in the buffer-local variable `master-of'.
You can set this variable using `master-set-slave'.  You can show
yourself the value of `master-of' by calling `master-show-slave'."
  :group 'master
  :keymap
  '(("\C-c\C-n" . master-says-scroll-up)
    ("\C-c\C-p" . master-says-scroll-down)
    ("\C-c<" . master-says-beginning-of-buffer)
    ("\C-c>" . master-says-end-of-buffer)
    ("\C-c\C-l" . master-says-recenter)))

;; Initialize Master mode by setting a slave buffer.

(defun master-set-slave (buffer)
  "Makes BUFFER the slave of the current buffer.
Use \\[master-mode] to toggle control of the slave buffer."
  (interactive "bSlave: ")
  (make-local-variable 'master-of)
  (setq master-of buffer)
  (run-hooks 'master-set-slave-hook))

(defun master-show-slave ()
  "Displays a message with the name of the slave buffer."
  (interactive)
  (message "This buffer is the master of %s.  Master-mode is %S."
	   (or master-of "none")
	   master-mode))



;;; Functions that the master buffer can call for the slave buffer.

(defun master-says-scroll-up (&optional arg)
  "Display and scroll the slave buffer up.
See `scroll-up'."
  (interactive)
  (master-says 'scroll-up arg))

(defun master-says-scroll-down (&optional arg)
  "Display and scroll the slave buffer down.
See `scroll-down'."
  (interactive)
  (master-says 'scroll-down arg))

(defun master-says-beginning-of-buffer (&optional arg)
  "Display and move to the beginning of the slave buffer.
See `beginning-of-buffer'."
  (interactive)
  (master-says 'beginning-of-buffer arg))

(defun master-says-end-of-buffer (&optional arg)
  "Display and move to the end of the slave buffer.
See `end-of-buffer'."
  (interactive)
  (master-says 'end-of-buffer arg))

(defun master-says-recenter (&optional arg)
  "Recenter the slave buffer.
See `recenter'."
  (interactive)
  (master-says 'recenter arg))

;; The master function doing the stuff.

(defun master-says (&optional command arg)
  "Display slave buffer and execute COMMAND with ARG in its window."
  (interactive)
  (if (null (buffer-live-p (get-buffer master-of)))
      (error "Slave buffer has disappeared")
    (let ((window  (selected-window)))
      (if (not (eq (window-buffer window) (get-buffer master-of)))
	  (switch-to-buffer-other-window master-of))
      (if command (condition-case nil (apply command arg) (error nil)))
      (select-window window))))

(provide 'master)

;; arch-tag: dca08daa-8127-45ae-b77e-b135160dce98
;;; master.el ends here