view lib-src/=aixcc.lex @ 20892:18f3cb26243f before-miles-orphaned-changes gcc-2_8_1-980401 gcc-2_8_1-980407 gcc-2_8_1-980412 gcc-2_8_1-980413 gcc-2_8_1-RELEASE gcc_2_8_1-980315 libc-980214 libc-980215 libc-980216 libc-980217 libc-980218 libc-980219 libc-980220 libc-980221 libc-980222 libc-980223 libc-980224 libc-980225 libc-980226 libc-980227 libc-980228 libc-980301 libc-980302 libc-980303 libc-980304 libc-980306 libc-980307 libc-980308 libc-980309 libc-980310 libc-980311 libc-980312 libc-980313 libc-980314 libc-980315 libc-980316 libc-980317 libc-980318 libc-980319 libc-980320 libc-980321 libc-980322 libc-980323 libc-980324 libc-980325 libc-980326 libc-980327 libc-980328 libc-980329 libc-980330 libc-980331 libc-980401 libc-980402 libc-980403 libc-980404 libc-980405 libc-980406 libc-980407 libc-980408 libc-980409 libc-980410 libc-980411 libc-980412 libc-980413 libc-980414 libc-980428 libc-980429 libc-980430 libc-980501 libc-980502 libc-980503 libc-980504 libc-980505 libc-980506 libc-980507 libc-980508 libc-980509 libc-980510 libc-980512 libc-980513 libc-980514 libc-980515 libc-980516 libc-980517 libc-980518 libc-980519 libc-980520 libc-980521 libc-980522 libc-980523 libc-980524 libc-980525 libc-980526 libc-980527 libc-980528 libc-980529 libc-980530 libc-980531 libc-980601 libc-980602 libc-980603 libc-980604 libc-980605 libc-980606 libc-980607 libc-980608 libc-980609 libc-980610 libc-980611 libc-980612 libc-980613

Add PentiumII (i786). Add '7' to all i[3456] entries. Add AMD and Cyrix names for P5 and P6.

%Start ErrorText ErrorMessage OtherText

EC	[0-9][0-9][0-9][0-9]-[0-9][0-9][0-9]
D	[0-9]
D3	[0-9 ][0-9 ][0-9]
D4	[0-9 ][0-9 ][0-9 ][0-9]
D5	[0-9 ][0-9 ][0-9 ][0-9 ][0-9]
DS	[0-9 ]

%{
/* [e-mail]

 * Hack to work around the AIX C compiler's brain-damaged error messages
 * so that emacs can parse them.  It runs /bin/cc as a subprocess, and
 * tries to rearrange the error messages so that (a) each message contains
 * both the filename and line number where the error occurred, and (b)
 * the error message(s) for a particular line get displayed *before* the
 * line itself.
 *
 * to compile: 
 * lex aixcc.lex
 * cc -o aixcc lex.yy.c
 *
 *
 * Copyright December 1991 by Keith Moore
 *
 * This program is free software; you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation; either version 2 of the License, or
 * (at your option) any later version.
 * 
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 * 
 * You should have received a copy of the GNU General Public License
 * along with this program; if not, write to the Free Software
 * Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
 *
 *
 * TODO: figure out how the compiler counts file numbers for included
 * files, keep track of which file corresponds to which number, and
 * always output the right file name.
 */

#include <stdio.h>
#include <string.h>

char *current_file;
int line;
int debug = 0;
char bigbuf[10240];
char *bufptr = bigbuf;
int last_line_was_error = 0;

spaces (s)
char *s;
{
    while (*s++)
	*bufptr++ = ' ';
}

char *
strsave (s)
char *s;
{
    char *ptr = malloc (strlen (s) + 1);
    strcpy (ptr, s);
    return ptr;
}

yywrap ()
{
    *bufptr = '\0';
    bufptr = bigbuf;
    while (*bufptr)
	putc (*bufptr++, yyout);
    return 1;
}

%}
%%
^File\ Line\ Column\ Message\ text[^\n]*	{
   /*
    * ignore this.  don't treat it as error text
    */
}

^{DS}{DS}{DS}\ {D5}\ \|	{
    /*
     * (optional) nesting level, followed by line number, followed
     * by the source code fragment that caused the error
     */

    /*
     * save the line number for later
     */
    line = atoi (yytext+4);

    if (debug) {
	fprintf (yyout, "line <= %d\n", line);
	fprintf (yyout, "%s\n", yytext);
    }

    /*
     * if the last line was an error message, to flush out all of
     * the old source text before starting to save the new source text.
     */
    if (last_line_was_error) {
	*bufptr = '\0';
	bufptr = bigbuf;
	while (*bufptr)
	    putc (*bufptr++, yyout);
	bufptr = bigbuf;
        last_line_was_error = 0;
    }
    /*
     * stuff enough spaces in the text buffer so that the
     * saved text will line up properly when displayed.
     */
    spaces (yytext);

    BEGIN ErrorText;	/* continue below */
}

<ErrorText>[^\n]*$	{
    char *ptr;

    /* 
     * Save the text until we see the error message(s), then print it.
     * This because emacs puts the error message at the top of the
     * window, and it's nice to be able to see the text below it.
     */

    ptr = yytext;
    while (*ptr)
	*bufptr++ = *ptr++;
    *bufptr++ = '\n';

    BEGIN 0;
}

^Processing\ include\ file\ .*$	{
    /*
     * name of a new include file being processed.  Increment file number
     * and remember the file name corresponding to this file number.
     */

    current_file = strsave (yytext+24);
    
    if (debug) {
	fprintf (yyout, "current_file <= %s\n", current_file);
	fprintf (yyout, "%s\n", yytext);
    }
}

^([a-z]\ -)?\ *{EC}:	{
    /* 
     * error message (which we print immediately) preceded by an
     * error code (which we ignore)
     */

    fprintf (yyout, "\"%s\", line %d: %c -", current_file, line, *yytext);
    last_line_was_error = 1;
    BEGIN ErrorMessage;
}

^{D3}\ {D5}\ {D4}\ {EC}:	{
    /*
     * (optional) nesting level, followed by line number, followed
     * by column number, followed by error message text.
     */

    /*
     * save the line number for later
     */
    line = atoi (yytext+4);

    if (debug) {
	fprintf (yyout, "line <= %d\n", line);
	fprintf (yyout, "%s\n", yytext);
    }

    /*
     * if the last line was an error message, flush out all of
     * the old source text before printing this error message.
     */
    if (last_line_was_error) {
	*bufptr = '\0';
	bufptr = bigbuf;
	while (*bufptr)
	    putc (*bufptr++, yyout);
	bufptr = bigbuf;
        last_line_was_error = 0;
    }
    fprintf (yyout, "\"%s\", line %d:", current_file, line);
    last_line_was_error = 1;
    BEGIN ErrorMessage;
}

<ErrorMessage>[^\n]*$	{
    fprintf (yyout, "%s\n", yytext);
    BEGIN 0;
}


^[^ :]+".c:"\ *$	{
    /* name of new source file being processed */

    char *ptr;

    if (current_file)
	free (current_file);
    ptr = strchr (yytext, ':');
    *ptr = '\0';
    current_file = strsave (yytext);
}

^[^\n]	{
    /*
     * other text starting with a newline.  We have to break it up this
     * way to keep this rule from matching any of the above patterns
     */

    if (last_line_was_error) {
	*bufptr = '\0';
	bufptr = bigbuf;
	while (*bufptr)
	    putc (*bufptr++, yyout);
	bufptr = bigbuf;
        last_line_was_error = 0;
    }

    *bufptr++ = *yytext;
    BEGIN OtherText;
}

<OtherText>[^\n]*$	{
    char *ptr;

    ptr = yytext;
    while (*ptr)
	*bufptr++ = *ptr++;
    *bufptr++ = '\n';

    BEGIN 0;
}

\n	;

%%

main (argc, argv)
char **argv;
{
    int pfd[2];
    int child_pid;
    int i;

    current_file = strsave ("/dev/null");

    line = 0;

    for (i = 1; i < argc; ++i) {
	char *ptr = strrchr (argv[i], '.');
	if (ptr && ptr[1] == 'c' && ptr[2] == '\0') {
	    current_file = strsave (argv[i]);
	    break;
	}
    }

    if (pipe (pfd) < 0) {
	perror ("pipe");
	exit (1);
    }
    if ((child_pid = fork()) > 0) {
	int status;

	close (pfd[1]);
	yyin = fdopen (pfd[0], "r");
	yyout = stderr;
	yylex();

	wait (&status);
	exit ((status >> 8) & 0xff);
    }
    else if (child_pid == 0) {
	dup2 (pfd[1], 2);
	close (pfd[0]);
	close (pfd[1]);
	argv[0] = "cc";
	execv ("/bin/cc", argv);
	perror ("/bin/cc");
	exit (1);
    }
    else {
	perror ("fork");
	exit (1);
    }
}