view lisp/hscroll.el @ 20892:18f3cb26243f before-miles-orphaned-changes gcc-2_8_1-980401 gcc-2_8_1-980407 gcc-2_8_1-980412 gcc-2_8_1-980413 gcc-2_8_1-RELEASE gcc_2_8_1-980315 libc-980214 libc-980215 libc-980216 libc-980217 libc-980218 libc-980219 libc-980220 libc-980221 libc-980222 libc-980223 libc-980224 libc-980225 libc-980226 libc-980227 libc-980228 libc-980301 libc-980302 libc-980303 libc-980304 libc-980306 libc-980307 libc-980308 libc-980309 libc-980310 libc-980311 libc-980312 libc-980313 libc-980314 libc-980315 libc-980316 libc-980317 libc-980318 libc-980319 libc-980320 libc-980321 libc-980322 libc-980323 libc-980324 libc-980325 libc-980326 libc-980327 libc-980328 libc-980329 libc-980330 libc-980331 libc-980401 libc-980402 libc-980403 libc-980404 libc-980405 libc-980406 libc-980407 libc-980408 libc-980409 libc-980410 libc-980411 libc-980412 libc-980413 libc-980414 libc-980428 libc-980429 libc-980430 libc-980501 libc-980502 libc-980503 libc-980504 libc-980505 libc-980506 libc-980507 libc-980508 libc-980509 libc-980510 libc-980512 libc-980513 libc-980514 libc-980515 libc-980516 libc-980517 libc-980518 libc-980519 libc-980520 libc-980521 libc-980522 libc-980523 libc-980524 libc-980525 libc-980526 libc-980527 libc-980528 libc-980529 libc-980530 libc-980531 libc-980601 libc-980602 libc-980603 libc-980604 libc-980605 libc-980606 libc-980607 libc-980608 libc-980609 libc-980610 libc-980611 libc-980612 libc-980613

Add PentiumII (i786). Add '7' to all i[3456] entries. Add AMD and Cyrix names for P5 and P6.

;;; hscroll.el: Minor mode to automatically scroll truncated lines horizontally
;;; Copyright (C) 1992, 1993, 1995, 1996 Free Software Foundation, Inc.

;; Author: Wayne Mesard <[e-mail]>
;; Keywords: display

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
;; Boston, MA 02111-1307, USA.

;;; Commentary:a
;;
;;    Automatically scroll horizontally when the point moves off the
;;    left or right edge of the window.  
;;
;;    - Type "M-x hscroll-mode" to enable it in the current buffer.
;;    - Type "M-x hscroll-global-mode" to enable it in every buffer.
;;    - "turn-on-hscroll" is useful in mode hooks as in:
;;          (add-hook 'text-mode-hook 'turn-on-hscroll)
;;
;;    - hscroll-margin controls how close the cursor can get to the edge 
;;      of the window.
;;    - hscroll-step-percent controls how far to jump once we decide to do so.
;;
;;    Most users won't want to mess with the other variables defined
;;    here.  But they're all documented, and they all start with
;;    "hscroll-" if you're curious.
;;
;;    Oh, you should also know that if you set the hscroll-margin and
;;    hscroll-step-percent large enough, you can get an interesting, but
;;    undesired ping-pong effect as the point bounces from one edge to
;;    the other.
;;
;;    [e-mail]

;;; Code:

;;; 
;;; PUBLIC VARIABLES
;;; 

(defvar hscroll-version "2.2")

(defgroup hscroll nil
  "Minor mode to automatically scroll truncated lines horizontally."
  :group 'editing)


(defcustom hscroll-global-mode nil
  "Toggle horizontal scrolling.
You must modify via \\[customize] for this variable to have an effect."
  :set (lambda (symbol value)
	 (hscroll-global-mode (if value 1 -1)))
  :initialize 'custom-initialize-default
  :group 'hscroll
  :type 'boolean
  :require 'hscroll)

(defcustom hscroll-margin 5 
  "*How many columns away from the edge of the window point is allowed to get
before HScroll will horizontally scroll the window."
  :group 'hscroll
  :type 'integer)

(defcustom hscroll-snap-threshold 30
  "*When point is this many columns (or less) from the left edge of the document, 
don't do any horizontal scrolling.  In other words, be biased towards the left
edge of the document.
  Set this variable to zero to disable this bias."
  :group 'hscroll
  :type 'integer)

(defcustom hscroll-step-percent 25
  "*How far away to place the point from the window's edge when scrolling.
Expressed as a percentage of the window's width."
  :group 'hscroll
  :type 'integer)

(defcustom hscroll-mode-name " Hscr"
  "*Horizontal scrolling mode line indicator.
Set this to nil to conserve valuable mode line space."
  :group 'hscroll
  :type 'string)

(or (assq 'hscroll-mode minor-mode-alist)
    (setq minor-mode-alist
	  (cons '(hscroll-mode hscroll-mode-name) minor-mode-alist)))


;;; 
;;; PRIVATE VARIABLES
;;; 

(defvar hscroll-mode nil 
  "Non-nil if HScroll mode is enabled.")
(make-variable-buffer-local 'hscroll-mode)


(defvar hscroll-old-truncate-local nil)
(defvar hscroll-old-truncate-was-global nil)
(make-variable-buffer-local 'hscroll-old-truncate)
(make-variable-buffer-local 'hscroll-old-truncate-was-global)

(defvar hscroll-old-truncate-default nil)

;;; 
;;; PUBLIC COMMANDS
;;; 

;;;###autoload
(defun turn-on-hscroll ()
  "Unconditionally turn on Hscroll mode in the current buffer."
  (hscroll-mode 1))

;;;###autoload
(defun hscroll-mode (&optional arg)
  "Toggle HScroll mode in the current buffer.
With ARG, turn HScroll mode on if ARG is positive, off otherwise.
In HScroll mode, truncated lines will automatically scroll left or
right when point gets near either edge of the window.
  See also \\[hscroll-global-mode]."
  (interactive "P")
  (make-local-hook 'post-command-hook)
  (let ((newmode (if (null arg)
		      (not hscroll-mode)
		    (> (prefix-numeric-value arg) 0))))

    (if newmode
	;; turn it on
	(if (not hscroll-mode)
	    ;; it was off
	    (let ((localp (local-variable-p 'truncate-lines)))
	      (if localp
		  (setq hscroll-old-truncate-local truncate-lines))
	      (setq hscroll-old-truncate-was-global (not localp))
	      (setq truncate-lines t)
	      (add-hook 'post-command-hook 
			(function hscroll-window-maybe) nil t)
	      ))
      ;; turn it off
      (if hscroll-mode
	  ;; it was on
	  (progn
	    (if hscroll-old-truncate-was-global
		(kill-local-variable 'truncate-lines)
	      (setq truncate-lines hscroll-old-truncate-local))
	    (if (not truncate-lines)
		(set-window-hscroll (selected-window) 0))
	    (remove-hook 'post-command-hook
			 (function hscroll-window-maybe) t)
	    ))
      )

    (setq hscroll-mode newmode)
    (force-mode-line-update nil)
    ))


;;;###autoload
(defun hscroll-global-mode  (&optional arg)
  "Toggle HScroll mode in all buffers.
With ARG, turn HScroll mode on if ARG is positive, off otherwise.
If a buffer ever has HScroll mode set locally (via \\[hscroll-mode]), 
it will forever use the local value (i.e., \\[hscroll-global-mode] 
will have no effect on it).
  See also \\[hscroll-mode]."
  (interactive "P")
  (let* ((oldmode (default-value 'hscroll-mode))
	 (newmode (if (null arg)
		      (not oldmode)
		    (> (prefix-numeric-value arg) 0))))
    (setq hscroll-global-mode newmode)
    (if newmode
	;; turn it on
	(if (not hscroll-mode)
	    ;; it was off
	    (progn
	      (setq hscroll-old-truncate-default (default-value truncate-lines))
	      (setq hscroll-old-truncate-was-global t)
	      (setq-default truncate-lines t)
	      (add-hook 'post-command-hook (function hscroll-window-maybe))
	      ))
      ;; turn it off
      (if hscroll-mode
	  ;; it was on
	  (progn
	    (setq-default truncate-lines hscroll-old-truncate-default)
	    (remove-hook 'post-command-hook (function hscroll-window-maybe))
	    ))
      )

    (setq-default hscroll-mode newmode)
    (force-mode-line-update t)
    ))

(defun hscroll-window-maybe ()
  "Scroll horizontally if point is off or nearly off the edge of the window.
This is called automatically when in HScroll mode, but it can be explicitly
invoked as well (i.e., it can be bound to a key)."
  (interactive)
  ;; Only consider scrolling if truncate-lines is true, 
  ;; the window is already scrolled or partial-widths is true and this is
  ;; a partial width window.  See display_text_line() in xdisp.c.
  (if (and hscroll-mode
	   (or truncate-lines
	       (not (zerop (window-hscroll)))
	       (and truncate-partial-width-windows
		    (< (window-width) (frame-width)))))
      (let ((linelen (save-excursion (end-of-line) (current-column)))
	    (rightmost-char (+ (window-width) (window-hscroll)))
	    )
 	(if (< (current-column) hscroll-snap-threshold)
 	    (set-window-hscroll 
 	     (selected-window) 
 	     (- (window-hscroll)))
 	  (if (>= (current-column)
		(- rightmost-char hscroll-margin
		   ;; Off-by-one if the left edge is scrolled
		   (if (not (zerop (window-hscroll))) 1 0)
		   ;; Off by one if the right edge is scrolled
		   (if (> linelen rightmost-char) 1 0)
		   ))
	    ;; Scroll to the left a proportion of the window's width.
	    (set-window-hscroll 
	     (selected-window) 
	     (- (+ (current-column) 
		   (/ (* (window-width) hscroll-step-percent) 100))
		(window-width)))
	  (if (< (current-column) (+ (window-hscroll) hscroll-margin))
	      ;; Scroll to the right a proportion of the window's width.
	      (set-window-hscroll
	       (selected-window)
	       (- (current-column) (/ (* (window-width) hscroll-step-percent) 100)))
	    )))
	)))

;;; 
;;; It's not a bug, it's a *feature*
;;; 

(if hscroll-global-mode
    (hscroll-global-mode 1))

(provide 'hscroll)

;;; hscroll.el ends here