Numbers
*******

GNU Emacs supports two numeric data types: integers and floating point numbers.  Integers are whole numbers such as -3, 0, 7, 13, and 511.  Their values are exact.  Floating point numbers are numbers with fractional parts, such as -4.5, 0.0, or 2.71828.  They can also be expressed in exponential notation: 1.5e2 equals 150; in this example, e2 stands for ten to the second power, and that is multiplied by 1.5.  Floating point values are not exact; they have a fixed, limited amount of precision.

Integer Basics
==============

The range of values for an integer depends on the machine.  The minimum range is -268435456 to 268435455 (29 bits; i.e., -2**28 to 2**28 - 1), but some machines may provide a wider range.  Many examples in this chapter assume an integer has 29 bits.

The Lisp reader reads an integer as a sequence of digits with optional initial sign and optional final period.

      1               ; The integer 1.
      1.              ; The integer 1.
     +1               ; Also the integer 1.
     -1               ; The integer -1.
      536870913       ; Also the integer 1, due to overflow.
      0               ; The integer 0.
     -0               ; The integer 0.

In addition, the Lisp reader recognizes a syntax for integers in bases other than 10: #BINTEGER reads INTEGER in binary (radix 2), #OINTEGER reads INTEGER in octal (radix 8), #XINTEGER reads INTEGER in hexadecimal (radix 16), and #RADIXrINTEGER reads INTEGER in radix RADIX (where RADIX is between 2 and 36, inclusively).  Case is not significant for the letter after # (B, O, etc.) that denotes the radix.

To understand how various functions work on integers, especially the bitwise operators (see Bitwise Operations), it is often helpful to view the numbers in their binary form.

In 29-bit binary, the decimal integer 5 looks like this:

     0 0000  0000 0000  0000 0000  0000 0101

(We have inserted spaces between groups of 4 bits, and two spaces between groups of 8 bits, to make the binary integer easier to read.)

The integer -1 looks like this:

     1 1111  1111 1111  1111 1111  1111 1111

-1 is represented as 29 ones.  (This is called two's complement notation.)

The negative integer, -5, is creating by subtracting 4 from -1.  In binary, the decimal integer 4 is 100.  Consequently, -5 looks like this:

     1 1111  1111 1111  1111 1111  1111 1011

In this implementation, the largest 29-bit binary integer value is 268,435,455 in decimal.  In binary, it looks like this:

     0 1111  1111 1111  1111 1111  1111 1111

Since the arithmetic functions do not check whether integers go outside their range, when you add 1 to 268,435,455, the value is the negative integer -268,435,456:

     (+ 1 268435455)
          => -268435456
          => 1 0000  0000 0000  0000 0000  0000 0000

Many of the functions described in this chapter accept markers for arguments in place of numbers.  (see Markers.)  Since the actual arguments to such functions may be either numbers or markers, we often give these arguments the name NUMBER-OR-MARKER.  When the argument value is a marker, its position value is used and its buffer is ignored.

 -- Variable: most-positive-fixnum
     The value of this variable is the largest integer that Emacs Lisp can handle.

 -- Variable: most-negative-fixnum
     The value of this variable is the smallest integer that Emacs Lisp can handle.  It is negative.

Floating Point Basics
=====================

Floating point numbers are useful for representing numbers that are not integral.  The precise range of floating point numbers is machine-specific; it is the same as the range of the C data type double on the machine you are using.

The read-syntax for floating point numbers requires either a decimal point (with at least one digit following), an exponent, or both.  For example, 1500.0, 15e2, 15.0e2, 1.5e3, and .15e4 are five ways of writing a floating point number whose value is 1500.  They are all equivalent.  You can also use a minus sign to write negative floating point numbers, as in -1.0.

Most modern computers support the IEEE floating point standard, which provides for positive infinity and negative infinity as floating point values.  It also provides for a class of values called NaN or ``not-a-number''; numerical functions return such values in cases where there is no correct answer.  For example, (sqrt -1.0) returns a NaN.  For practical purposes, there's no significant difference between different NaN values in Emacs Lisp, and there's no rule for precisely which NaN value should be used in a particular case, so Emacs Lisp doesn't try to distinguish them.  Here are the read syntaxes for these special floating point values:

positive infinity
     1.0e+INF

negative infinity
     -1.0e+INF

Not-a-number
     0.0e+NaN.

In addition, the value -0.0 is distinguishable from ordinary zero in IEEE floating point (although equal and = consider them equal values).

You can use logb to extract the binary exponent of a floating point number (or estimate the logarithm of an integer):

 -- Function: logb number
     This function returns the binary exponent of NUMBER.  More precisely, the value is the logarithm of NUMBER base 2, rounded down to an integer.

          (logb 10)
               => 3
          (logb 10.0e20)
               => 69

Type Predicates for Numbers
===========================

The functions in this section test whether the argument is a number or whether it is a certain sort of number.  The functions integerp and floatp can take any type of Lisp object as argument (the predicates would not be of much use otherwise); but the zerop predicate requires a number as its argument.  See also integer-or-marker-p and number-or-marker-p, in Predicates on Markers.

 -- Function: floatp object
     This predicate tests whether its argument is a floating point number and returns t if so, nil otherwise.

     floatp does not exist in Emacs versions 18 and earlier.

 -- Function: integerp object
     This predicate tests whether its argument is an integer, and returns t if so, nil otherwise.

 -- Function: numberp object
     This predicate tests whether its argument is a number (either integer or floating point), and returns t if so, nil otherwise.

 -- Function: wholenump object
     The wholenump predicate (whose name comes from the phrase ``whole-number-p'') tests to see whether its argument is a nonnegative integer, and returns t if so, nil otherwise.  0 is considered non-negative.

     natnump is an obsolete synonym for wholenump.

 -- Function: zerop number
     This predicate tests whether its argument is zero, and returns t if so, nil otherwise.  The argument must be a number.

     These two forms are equivalent: (zerop x) == (= x 0).

Comparison of Numbers
=====================

To test numbers for numerical equality, you should normally use =, not eq.  There can be many distinct floating point number objects with the same numeric value.  If you use eq to compare them, then you test whether two values are the same object.  By contrast, = compares only the numeric values of the objects.

At present, each integer value has a unique Lisp object in Emacs Lisp. Therefore, eq is equivalent to = where integers are concerned.  It is sometimes convenient to use eq for comparing an unknown value with an integer, because eq does not report an error if the unknown value is not a number---it accepts arguments of any type.  By contrast, = signals an error if the arguments are not numbers or markers.  However, it is a good idea to use = if you can, even for comparing integers, just in case we change the representation of integers in a future Emacs version.

Sometimes it is useful to compare numbers with equal; it treats two numbers as equal if they have the same data type (both integers, or both floating point) and the same value.  By contrast, = can treat an integer and a floating point number as equal.

There is another wrinkle: because floating point arithmetic is not exact, it is often a bad idea to check for equality of two floating point values.  Usually it is better to test for approximate equality. Here's a function to do this:

     (defvar fuzz-factor 1.0e-6)
     (defun approx-equal (x y)
       (or (and (= x 0) (= y 0))
           (< (/ (abs (- x y))
                 (max (abs x) (abs y)))
              fuzz-factor)))

     Common Lisp note: Comparing numbers in Common Lisp always requires = because Common Lisp implements multi-word integers, and two distinct integer objects can have the same numeric value.  Emacs Lisp can have just one integer object for any given value because it has a limited range of integer values.

 -- Function: = number-or-marker1 number-or-marker2
     This function tests whether its arguments are numerically equal, and returns t if so, nil otherwise.

 -- Function: /= number-or-marker1 number-or-marker2
     This function tests whether its arguments are numerically equal, and returns t if they are not, and nil if they are.

 -- Function: < number-or-marker1 number-or-marker2
     This function tests whether its first argument is strictly less than its second argument.  It returns t if so, nil otherwise.

 -- Function: <= number-or-marker1 number-or-marker2
     This function tests whether its first argument is less than or equal to its second argument.  It returns t if so, nil otherwise.

 -- Function: > number-or-marker1 number-or-marker2
     This function tests whether its first argument is strictly greater than its second argument.  It returns t if so, nil otherwise.

 -- Function: >= number-or-marker1 number-or-marker2
     This function tests whether its first argument is greater than or equal to its second argument.  It returns t if so, nil otherwise.

 -- Function: max number-or-marker &rest numbers-or-markers
     This function returns the largest of its arguments. If any of the argument is floating-point, the value is returned as floating point, even if it was given as an integer.

          (max 20)
               => 20
          (max 1 2.5)
               => 2.5
          (max 1 3 2.5)
               => 3.0

 -- Function: min number-or-marker &rest numbers-or-markers
     This function returns the smallest of its arguments. If any of the argument is floating-point, the value is returned as floating point, even if it was given as an integer.

          (min -4 1)
               => -4

 -- Function: abs number
     This function returns the absolute value of NUMBER.

Numeric Conversions
===================

To convert an integer to floating point, use the function float.

 -- Function: float number
     This returns NUMBER converted to floating point. If NUMBER is already a floating point number, float returns it unchanged.

There are four functions to convert floating point numbers to integers; they differ in how they round.  These functions accept integer arguments also, and return such arguments unchanged.

 -- Function: truncate number
     This returns NUMBER, converted to an integer by rounding towards zero.

          (truncate 1.2)
               => 1
          (truncate 1.7)
               => 1
          (truncate -1.2)
               => -1
          (truncate -1.7)
               => -1

 -- Function: floor number &optional divisor
     This returns NUMBER, converted to an integer by rounding downward (towards negative infinity).

     If DIVISOR is specified, floor divides NUMBER by DIVISOR and then converts to an integer; this uses the kind of division operation that corresponds to mod, rounding downward. An arith-error results if DIVISOR is 0.

          (floor 1.2)
               => 1
          (floor 1.7)
               => 1
          (floor -1.2)
               => -2
          (floor -1.7)
               => -2
          (floor 5.99 3)
               => 1

 -- Function: ceiling number
     This returns NUMBER, converted to an integer by rounding upward (towards positive infinity).

          (ceiling 1.2)
               => 2
          (ceiling 1.7)
               => 2
          (ceiling -1.2)
               => -1
          (ceiling -1.7)
               => -1

 -- Function: round number
     This returns NUMBER, converted to an integer by rounding towards the nearest integer.  Rounding a value equidistant between two integers may choose the integer closer to zero, or it may prefer an even integer, depending on your machine.

          (round 1.2)
               => 1
          (round 1.7)
               => 2
          (round -1.2)
               => -1
          (round -1.7)
               => -2

Arithmetic Operations
=====================

Emacs Lisp provides the traditional four arithmetic operations: addition, subtraction, multiplication, and division.  Remainder and modulus functions supplement the division functions.  The functions to add or subtract 1 are provided because they are traditional in Lisp and commonly used.

All of these functions except % return a floating point value if any argument is floating.

It is important to note that in Emacs Lisp, arithmetic functions do not check for overflow.  Thus (1+ 268435455) may evaluate to -268435456, depending on your hardware.

 -- Function: 1+ number-or-marker
     This function returns NUMBER-OR-MARKER plus 1. For example,

          (setq foo 4)
               => 4
          (1+ foo)
               => 5

     This function is not analogous to the C operator ++---it does not increment a variable.  It just computes a sum.  Thus, if we continue,

          foo
               => 4

     If you want to increment the variable, you must use setq, like this:

          (setq foo (1+ foo))
               => 5

 -- Function: 1- number-or-marker
     This function returns NUMBER-OR-MARKER minus 1.

 -- Function: + &rest numbers-or-markers
     This function adds its arguments together.  When given no arguments, + returns 0.

          (+)
               => 0
          (+ 1)
               => 1
          (+ 1 2 3 4)
               => 10

 -- Function: - &optional number-or-marker &rest more-numbers-or-markers
     The - function serves two purposes: negation and subtraction. When - has a single argument, the value is the negative of the argument.  When there are multiple arguments, - subtracts each of the MORE-NUMBERS-OR-MARKERS from NUMBER-OR-MARKER, cumulatively.  If there are no arguments, the result is 0.

          (- 10 1 2 3 4)
               => 0
          (- 10)
               => -10
          (-)
               => 0

 -- Function: * &rest numbers-or-markers
     This function multiplies its arguments together, and returns the product.  When given no arguments, * returns 1.

          (*)
               => 1
          (* 1)
               => 1
          (* 1 2 3 4)
               => 24

 -- Function: / dividend divisor &rest divisors
     This function divides DIVIDEND by DIVISOR and returns the quotient.  If there are additional arguments DIVISORS, then it divides DIVIDEND by each divisor in turn.  Each argument may be a number or a marker.

     If all the arguments are integers, then the result is an integer too. This means the result has to be rounded.  On most machines, the result is rounded towards zero after each division, but some machines may round differently with negative arguments.  This is because the Lisp function / is implemented using the C division operator, which also permits machine-dependent rounding.  As a practical matter, all known machines round in the standard fashion.

     If you divide an integer by 0, an arith-error error is signaled. (see Errors.)  Floating point division by zero returns either infinity or a NaN if your machine supports IEEE floating point; otherwise, it signals an arith-error error.

          (/ 6 2)
               => 3

          (/ 5 2)
               => 2
          (/ 5.0 2)
               => 2.5
          (/ 5 2.0)
               => 2.5
          (/ 5.0 2.0)
               => 2.5
          (/ 25 3 2)
               => 4
          (/ -17 6)
               => -2

     The result of (/ -17 6) could in principle be -3 on some machines.

 -- Function: % dividend divisor
     This function returns the integer remainder after division of DIVIDEND by DIVISOR.  The arguments must be integers or markers.

     For negative arguments, the remainder is in principle machine-dependent since the quotient is; but in practice, all known machines behave alike.

     An arith-error results if DIVISOR is 0.

          (% 9 4)
               => 1
          (% -9 4)
               => -1
          (% 9 -4)
               => 1
          (% -9 -4)
               => -1

     For any two integers DIVIDEND and DIVISOR,

          (+ (% DIVIDEND DIVISOR)
             (* (/ DIVIDEND DIVISOR) DIVISOR))

     always equals DIVIDEND.

 -- Function: mod dividend divisor
     This function returns the value of DIVIDEND modulo DIVISOR; in other words, the remainder after division of DIVIDEND by DIVISOR, but with the same sign as DIVISOR. The arguments must be numbers or markers.

     Unlike %, mod returns a well-defined result for negative arguments.  It also permits floating point arguments; it rounds the quotient downward (towards minus infinity) to an integer, and uses that quotient to compute the remainder.

     An arith-error results if DIVISOR is 0.

          (mod 9 4)
               => 1

          (mod -9 4)
               => 3

          (mod 9 -4)
               => -3

          (mod -9 -4)
               => -1

          (mod 5.5 2.5)
               => .5

     For any two numbers DIVIDEND and DIVISOR,

          (+ (mod DIVIDEND DIVISOR)
             (* (floor DIVIDEND DIVISOR) DIVISOR))

     always equals DIVIDEND, subject to rounding error if either argument is floating point.  For floor, see Numeric Conversions.

Rounding Operations
===================

The functions ffloor, fceiling, fround, and ftruncate take a floating point argument and return a floating point result whose value is a nearby integer.  ffloor returns the nearest integer below; fceiling, the nearest integer above; ftruncate, the nearest integer in the direction towards zero; fround, the nearest integer.

 -- Function: ffloor float
     This function rounds FLOAT to the next lower integral value, and returns that value as a floating point number.

 -- Function: fceiling float
     This function rounds FLOAT to the next higher integral value, and returns that value as a floating point number.

 -- Function: ftruncate float
     This function rounds FLOAT towards zero to an integral value, and returns that value as a floating point number.

 -- Function: fround float
     This function rounds FLOAT to the nearest integral value, and returns that value as a floating point number.

Bitwise Operations on Integers
==============================

In a computer, an integer is represented as a binary number, a sequence of bits (digits which are either zero or one).  A bitwise operation acts on the individual bits of such a sequence.  For example, shifting moves the whole sequence left or right one or more places, reproducing the same pattern ``moved over''.

The bitwise operations in Emacs Lisp apply only to integers.

 -- Function: lsh integer1 count
     lsh, which is an abbreviation for logical shift, shifts the bits in INTEGER1 to the left COUNT places, or to the right if COUNT is negative, bringing zeros into the vacated bits.  If COUNT is negative, lsh shifts zeros into the leftmost (most-significant) bit, producing a positive result even if INTEGER1 is negative.  Contrast this with ash, below.

     Here are two examples of lsh, shifting a pattern of bits one place to the left.  We show only the low-order eight bits of the binary pattern; the rest are all zero.

          (lsh 5 1)
               => 10
          ;; Decimal 5 becomes decimal 10.
          00000101 => 00001010

          (lsh 7 1)
               => 14
          ;; Decimal 7 becomes decimal 14.
          00000111 => 00001110

     As the examples illustrate, shifting the pattern of bits one place to the left produces a number that is twice the value of the previous number.

     Shifting a pattern of bits two places to the left produces results like this (with 8-bit binary numbers):

          (lsh 3 2)
               => 12
          ;; Decimal 3 becomes decimal 12.
          00000011 => 00001100

     On the other hand, shifting one place to the right looks like this:

          (lsh 6 -1)
               => 3
          ;; Decimal 6 becomes decimal 3.
          00000110 => 00000011

          (lsh 5 -1)
               => 2
          ;; Decimal 5 becomes decimal 2.
          00000101 => 00000010

     As the example illustrates, shifting one place to the right divides the value of a positive integer by two, rounding downward.

     The function lsh, like all Emacs Lisp arithmetic functions, does not check for overflow, so shifting left can discard significant bits and change the sign of the number.  For example, left shifting 268,435,455 produces -2 on a 29-bit machine:

          (lsh 268435455 1)          ; left shift
               => -2

     In binary, in the 29-bit implementation, the argument looks like this:

          ;; Decimal 268,435,455
          0 1111  1111 1111  1111 1111  1111 1111

     which becomes the following when left shifted:

          ;; Decimal -2
          1 1111  1111 1111  1111 1111  1111 1110

 -- Function: ash integer1 count
     ash (arithmetic shift) shifts the bits in INTEGER1 to the left COUNT places, or to the right if COUNT is negative.

     ash gives the same results as lsh except when INTEGER1 and COUNT are both negative.  In that case, ash puts ones in the empty bit positions on the left, while lsh puts zeros in those bit positions.

     Thus, with ash, shifting the pattern of bits one place to the right looks like this:

          (ash -6 -1) => -3
          ;; Decimal -6 becomes decimal -3.
          1 1111  1111 1111  1111 1111  1111 1010
               =>
          1 1111  1111 1111  1111 1111  1111 1101

     In contrast, shifting the pattern of bits one place to the right with lsh looks like this:

          (lsh -6 -1) => 268435453
          ;; Decimal -6 becomes decimal 268,435,453.
          1 1111  1111 1111  1111 1111  1111 1010
               =>
          0 1111  1111 1111  1111 1111  1111 1101

     Here are other examples:

                             ;               29-bit binary values

          (lsh 5 2)          ;   5  =  0 0000  0000 0000  0000 0000  0000 0101
               => 20         ;      =  0 0000  0000 0000  0000 0000  0001 0100

          (ash 5 2)
               => 20
          (lsh -5 2)         ;  -5  =  1 1111  1111 1111  1111 1111  1111 1011
               => -20        ;      =  1 1111  1111 1111  1111 1111  1110 1100
          (ash -5 2)
               => -20

          (lsh 5 -2)         ;   5  =  0 0000  0000 0000  0000 0000  0000 0101
               => 1          ;      =  0 0000  0000 0000  0000 0000  0000 0001

          (ash 5 -2)
               => 1

          (lsh -5 -2)        ;  -5  =  1 1111  1111 1111  1111 1111  1111 1011
               => 134217726  ;      =  0 0111  1111 1111  1111 1111  1111 1110

          (ash -5 -2)        ;  -5  =  1 1111  1111 1111  1111 1111  1111 1011
               => -2         ;      =  1 1111  1111 1111  1111 1111  1111 1110

 -- Function: logand &rest ints-or-markers
     This function returns the ``logical and'' of the arguments: the Nth bit is set in the result if, and only if, the Nth bit is set in all the arguments.  (``Set'' means that the value of the bit is 1 rather than 0.)

     For example, using 4-bit binary numbers, the ``logical and'' of 13 and 12 is 12: 1101 combined with 1100 produces 1100. In both the binary numbers, the leftmost two bits are set (i.e., they are 1's), so the leftmost two bits of the returned value are set. However, for the rightmost two bits, each is zero in at least one of the arguments, so the rightmost two bits of the returned value are 0's.

     Therefore,

          (logand 13 12)
               => 12

     If logand is not passed any argument, it returns a value of -1.  This number is an identity element for logand because its binary representation consists entirely of ones.  If logand is passed just one argument, it returns that argument.

                             ;                29-bit binary values

          (logand 14 13)     ; 14  =  0 0000  0000 0000  0000 0000  0000 1110
                             ; 13  =  0 0000  0000 0000  0000 0000  0000 1101
               => 12         ; 12  =  0 0000  0000 0000  0000 0000  0000 1100

          (logand 14 13 4)   ; 14  =  0 0000  0000 0000  0000 0000  0000 1110
                             ; 13  =  0 0000  0000 0000  0000 0000  0000 1101
                             ;  4  =  0 0000  0000 0000  0000 0000  0000 0100
               => 4          ;  4  =  0 0000  0000 0000  0000 0000  0000 0100

          (logand)
               => -1         ; -1  =  1 1111  1111 1111  1111 1111  1111 1111

 -- Function: logior &rest ints-or-markers
     This function returns the ``inclusive or'' of its arguments: the Nth bit is set in the result if, and only if, the Nth bit is set in at least one of the arguments.  If there are no arguments, the result is zero, which is an identity element for this operation.  If logior is passed just one argument, it returns that argument.

                             ;               29-bit binary values

          (logior 12 5)      ; 12  =  0 0000  0000 0000  0000 0000  0000 1100
                             ;  5  =  0 0000  0000 0000  0000 0000  0000 0101
               => 13         ; 13  =  0 0000  0000 0000  0000 0000  0000 1101

          (logior 12 5 7)    ; 12  =  0 0000  0000 0000  0000 0000  0000 1100
                             ;  5  =  0 0000  0000 0000  0000 0000  0000 0101
                             ;  7  =  0 0000  0000 0000  0000 0000  0000 0111
               => 15         ; 15  =  0 0000  0000 0000  0000 0000  0000 1111

 -- Function: logxor &rest ints-or-markers
     This function returns the ``exclusive or'' of its arguments: the Nth bit is set in the result if, and only if, the Nth bit is set in an odd number of the arguments.  If there are no arguments, the result is 0, which is an identity element for this operation.  If logxor is passed just one argument, it returns that argument.

                             ;               29-bit binary values

          (logxor 12 5)      ; 12  =  0 0000  0000 0000  0000 0000  0000 1100
                             ;  5  =  0 0000  0000 0000  0000 0000  0000 0101
               => 9          ;  9  =  0 0000  0000 0000  0000 0000  0000 1001

          (logxor 12 5 7)    ; 12  =  0 0000  0000 0000  0000 0000  0000 1100
                             ;  5  =  0 0000  0000 0000  0000 0000  0000 0101
                             ;  7  =  0 0000  0000 0000  0000 0000  0000 0111
               => 14         ; 14  =  0 0000  0000 0000  0000 0000  0000 1110

 -- Function: lognot integer
     This function returns the logical complement of its argument: the Nth bit is one in the result if, and only if, the Nth bit is zero in INTEGER, and vice-versa.

          (lognot 5)
               => -6
          ;;  5  =  0 0000  0000 0000  0000 0000  0000 0101
          ;; becomes
          ;; -6  =  1 1111  1111 1111  1111 1111  1111 1010

Standard Mathematical Functions
===============================

These mathematical functions allow integers as well as floating point numbers as arguments.

 -- Function: sin arg
 -- Function: cos arg
 -- Function: tan arg
     These are the ordinary trigonometric functions, with argument measured in radians.

 -- Function: asin arg
     The value of (asin ARG) is a number between -pi/2 and pi/2 (inclusive) whose sine is ARG; if, however, ARG is out of range (outside [-1, 1]), then the result is a NaN.

 -- Function: acos arg
     The value of (acos ARG) is a number between 0 and pi (inclusive) whose cosine is ARG; if, however, ARG is out of range (outside [-1, 1]), then the result is a NaN.

 -- Function: atan y &optional x
     The value of (atan Y) is a number between -pi/2 and pi/2 (exclusive) whose tangent is Y.  If the optional second argument X is given, the value of (atan y x) is the angle in radians between the vector [X, Y] and the X axis.

 -- Function: exp arg
     This is the exponential function; it returns e to the power ARG. e is a fundamental mathematical constant also called the base of natural logarithms.

 -- Function: log arg &optional base
     This function returns the logarithm of ARG, with base BASE. If you don't specify BASE, the base e is used.  If ARG is negative, the result is a NaN.

 -- Function: log10 arg
     This function returns the logarithm of ARG, with base 10.  If ARG is negative, the result is a NaN.  (log10 X) == (log X 10), at least approximately.

 -- Function: expt x y
     This function returns X raised to power Y.  If both arguments are integers and Y is positive, the result is an integer; in this case, it is truncated to fit the range of possible integer values.

 -- Function: sqrt arg
     This returns the square root of ARG.  If ARG is negative, the value is a NaN.

Random Numbers
==============

A deterministic computer program cannot generate true random numbers. For most purposes, pseudo-random numbers suffice.  A series of pseudo-random numbers is generated in a deterministic fashion.  The numbers are not truly random, but they have certain properties that mimic a random series.  For example, all possible values occur equally often in a pseudo-random series.

In Emacs, pseudo-random numbers are generated from a ``seed'' number. Starting from any given seed, the random function always generates the same sequence of numbers.  Emacs always starts with the same seed value, so the sequence of values of random is actually the same in each Emacs run!  For example, in one operating system, the first call to (random) after you start Emacs always returns -1457731, and the second one always returns -7692030.  This repeatability is helpful for debugging.

If you want random numbers that don't always come out the same, execute (random t).  This chooses a new seed based on the current time of day and on Emacs's process ID number.

 -- Function: random &optional limit
     This function returns a pseudo-random integer.  Repeated calls return a series of pseudo-random integers.

     If LIMIT is a positive integer, the value is chosen to be nonnegative and less than LIMIT.

     If LIMIT is t, it means to choose a new seed based on the current time of day and on Emacs's process ID number.

     On some machines, any integer representable in Lisp may be the result of random.  On other machines, the result can never be larger than a certain maximum or less than a certain (negative) minimum.