Major and Minor Modes
*********************

A mode is a set of definitions that customize Emacs and can be turned on and off while you edit.  There are two varieties of modes: major modes, which are mutually exclusive and used for editing particular kinds of text, and minor modes, which provide features that users can enable individually.

This chapter describes how to write both major and minor modes, how to indicate them in the mode line, and how they run hooks supplied by the user.  For related topics such as keymaps and syntax tables, see Keymaps, and Syntax Tables.

Major Modes
===========

Major modes specialize Emacs for editing particular kinds of text. Each buffer has only one major mode at a time.

The least specialized major mode is called Fundamental mode. This mode has no mode-specific definitions or variable settings, so each Emacs command behaves in its default manner, and each option is in its default state.  All other major modes redefine various keys and options. For example, Lisp Interaction mode provides special key bindings for C-j (eval-print-last-sexp), TAB (lisp-indent-line), and other keys.

When you need to write several editing commands to help you perform a specialized editing task, creating a new major mode is usually a good idea.  In practice, writing a major mode is easy (in contrast to writing a minor mode, which is often difficult).

If the new mode is similar to an old one, it is often unwise to modify the old one to serve two purposes, since it may become harder to use and maintain.  Instead, copy and rename an existing major mode definition and alter the copy---or define a derived mode (see Derived Modes).  For example, Rmail Edit mode, which is in emacs/lisp/mail/rmailedit.el, is a major mode that is very similar to Text mode except that it provides two additional commands.  Its definition is distinct from that of Text mode, but uses that of Text mode.

Rmail Edit mode offers an example of changing the major mode temporarily for a buffer, so it can be edited in a different way (with ordinary Emacs commands rather than Rmail commands).  In such cases, the temporary major mode usually provides a command to switch back to the buffer's usual mode (Rmail mode, in this case).  You might be tempted to present the temporary redefinitions inside a recursive edit and restore the usual ones when the user exits; but this is a bad idea because it constrains the user's options when it is done in more than one buffer: recursive edits must be exited most-recently-entered first.  Using an alternative major mode avoids this limitation.  See Recursive Editing.

The standard GNU Emacs Lisp library directory tree contains the code for several major modes, in files such as text-mode.el, texinfo.el, lisp-mode.el, c-mode.el, and rmail.el.  They are found in various subdirectories of the lisp directory.  You can study these libraries to see how modes are written.  Text mode is perhaps the simplest major mode aside from Fundamental mode.  Rmail mode is a complicated and specialized mode.

Major Mode Conventions
----------------------

The code for existing major modes follows various coding conventions, including conventions for local keymap and syntax table initialization, global names, and hooks.  Please follow these conventions when you define a new major mode:

  * Define a command whose name ends in -mode, with no arguments, that switches to the new mode in the current buffer.  This command should set up the keymap, syntax table, and buffer-local variables in an existing buffer, without changing the buffer's contents.

  * Write a documentation string for this command that describes the special commands available in this mode.  C-h m (describe-mode) in your mode will display this string.

     The documentation string may include the special documentation substrings, \[COMMAND], \{KEYMAP}, and \<KEYMAP>, which enable the documentation to adapt automatically to the user's own key bindings.  See Keys in Documentation.

  * The major mode command should start by calling kill-all-local-variables.  This is what gets rid of the buffer-local variables of the major mode previously in effect.

  * The major mode command should set the variable major-mode to the major mode command symbol.  This is how describe-mode discovers which documentation to print.

  * The major mode command should set the variable mode-name to the ``pretty'' name of the mode, as a string.  This string appears in the mode line.

  * Since all global names are in the same name space, all the global variables, constants, and functions that are part of the mode should have names that start with the major mode name (or with an abbreviation of it if the name is long).  See Coding Conventions.

  * The major mode should usually have its own keymap, which is used as the local keymap in all buffers in that mode.  The major mode command should call use-local-map to install this local map.  See Active Keymaps, for more information.

     This keymap should be stored permanently in a global variable named MODENAME-mode-map.  Normally the library that defines the mode sets this variable.

     See Tips for Defining, for advice about how to write the code to set up the mode's keymap variable.

  * The key sequences bound in a major mode keymap should usually start with C-c, followed by a control character, a digit, or {, }, <, >, : or ;.  The other punctuation characters are reserved for minor modes, and ordinary letters are reserved for users.

     It is reasonable for a major mode to rebind a key sequence with a standard meaning, if it implements a command that does ``the same job'' in a way that fits the major mode better.  For example, a major mode for editing a programming language might redefine C-M-a to ``move to the beginning of a function'' in a way that works better for that language.

     Major modes such as Dired or Rmail that do not allow self-insertion of text can reasonably redefine letters and other printing characters as editing commands.  Dired and Rmail both do this.

  * The mode may have its own syntax table or may share one with other related modes.  If it has its own syntax table, it should store this in a variable named MODENAME-mode-syntax-table.  See Syntax Tables.

  * If the mode handles a language that has a syntax for comments, it should set the variables that define the comment syntax.  See Options Controlling Comments (The GNU Emacs Manual).

  * The mode may have its own abbrev table or may share one with other related modes.  If it has its own abbrev table, it should store this in a variable named MODENAME-mode-abbrev-table.  See Abbrev Tables.

  * The mode should specify how to do highlighting for Font Lock mode, by setting up a buffer-local value for the variable font-lock-defaults (see Font Lock Mode).

  * The mode should specify how Imenu should find the definitions or sections of a buffer, by setting up a buffer-local value for the variable imenu-generic-expression or imenu-create-index-function (see Imenu).

  * Use defvar or defcustom to set mode-related variables, so that they are not reinitialized if they already have a value.  (Such reinitialization could discard customizations made by the user.)

  * To make a buffer-local binding for an Emacs customization variable, use make-local-variable in the major mode command, not make-variable-buffer-local.  The latter function would make the variable local to every buffer in which it is subsequently set, which would affect buffers that do not use this mode.  It is undesirable for a mode to have such global effects.  See Buffer-Local Variables.

     With rare exceptions, the only reasonable way to use use make-variable-buffer-local in a Lisp package is for a variable which is used only within that package.  Using it on a variable used by other packages would interfere with them.

  * Each major mode should have a mode hook named MODENAME-mode-hook.  The major mode command should run that hook, with run-hooks, as the very last thing it does.  See Hooks.

  * The major mode command may also run the hooks of some more basic modes. For example, indented-text-mode runs text-mode-hook as well as indented-text-mode-hook.  It may run these other hooks immediately before the mode's own hook (that is, after everything else), or it may run them earlier.

  * If something special should be done if the user switches a buffer from this mode to any other major mode, this mode can set up a buffer-local value for change-major-mode-hook (see Creating Buffer-Local).

  * If this mode is appropriate only for specially-prepared text, then the major mode command symbol should have a property named mode-class with value special, put on as follows:

          (put 'funny-mode 'mode-class 'special)

     This tells Emacs that new buffers created while the current buffer is in Funny mode should not inherit Funny mode.  Modes such as Dired, Rmail, and Buffer List use this feature.

  * If you want to make the new mode the default for files with certain recognizable names, add an element to auto-mode-alist to select the mode for those file names.  If you define the mode command to autoload, you should add this element in the same file that calls autoload.  Otherwise, it is sufficient to add the element in the file that contains the mode definition.  See Auto Major Mode.

  * In the documentation, you should provide a sample autoload form and an example of how to add to auto-mode-alist, that users can include in their init files (see Init File).

  * The top-level forms in the file defining the mode should be written so that they may be evaluated more than once without adverse consequences. Even if you never load the file more than once, someone else will.

Major Mode Examples
-------------------

Text mode is perhaps the simplest mode besides Fundamental mode. Here are excerpts from  text-mode.el that illustrate many of the conventions listed above:

     ;; Create mode-specific tables.
     (defvar text-mode-syntax-table nil
       "Syntax table used while in text mode.")

     (if text-mode-syntax-table
         ()              ; Do not change the table if it is already set up.
       (setq text-mode-syntax-table (make-syntax-table))
       (modify-syntax-entry ?\" ".   " text-mode-syntax-table)
       (modify-syntax-entry ?\\ ".   " text-mode-syntax-table)
       (modify-syntax-entry ?' "w   " text-mode-syntax-table))

     (defvar text-mode-abbrev-table nil
       "Abbrev table used while in text mode.")
     (define-abbrev-table 'text-mode-abbrev-table ())

     (defvar text-mode-map nil    ; Create a mode-specific keymap.
       "Keymap for Text mode.
     Many other modes, such as Mail mode, Outline mode and Indented Text mode,
     inherit all the commands defined in this map.")

     (if text-mode-map
         ()              ; Do not change the keymap if it is already set up.
       (setq text-mode-map (make-sparse-keymap))
       (define-key text-mode-map "\e\t" 'ispell-complete-word)
       (define-key text-mode-map "\t" 'indent-relative)
       (define-key text-mode-map "\es" 'center-line)
       (define-key text-mode-map "\eS" 'center-paragraph))

Here is the complete major mode function definition for Text mode:

     (defun text-mode ()
       "Major mode for editing text intended for humans to read...
      Special commands: \\{text-mode-map}

     Turning on text-mode runs the hook `text-mode-hook'."
       (interactive)
       (kill-all-local-variables)
       (use-local-map text-mode-map)

       (setq local-abbrev-table text-mode-abbrev-table)
       (set-syntax-table text-mode-syntax-table)

       (make-local-variable 'paragraph-start)
       (setq paragraph-start (concat "[ \t]*$\\|" page-delimiter))
       (make-local-variable 'paragraph-separate)
       (setq paragraph-separate paragraph-start)
       (make-local-variable 'indent-line-function)
       (setq indent-line-function 'indent-relative-maybe)

       (setq mode-name "Text")
       (setq major-mode 'text-mode)
       (run-hooks 'text-mode-hook))      ; Finally, this permits the user to
                                         ;   customize the mode with a hook.

The three Lisp modes (Lisp mode, Emacs Lisp mode, and Lisp Interaction mode) have more features than Text mode and the code is correspondingly more complicated.  Here are excerpts from lisp-mode.el that illustrate how these modes are written.

     ;; Create mode-specific table variables.
     (defvar lisp-mode-syntax-table nil "")
     (defvar emacs-lisp-mode-syntax-table nil "")
     (defvar lisp-mode-abbrev-table nil "")

     (if (not emacs-lisp-mode-syntax-table) ; Do not change the table
                                            ;   if it is already set.
         (let ((i 0))
           (setq emacs-lisp-mode-syntax-table (make-syntax-table))

           ;; Set syntax of chars up to 0 to class of chars that are
           ;;   part of symbol names but not words.
           ;;   (The number 0 is 48 in the ASCII character set.)
           (while (< i ?0)
             (modify-syntax-entry i "_   " emacs-lisp-mode-syntax-table)
             (setq i (1+ i)))
           ...

           ;; Set the syntax for other characters.
           (modify-syntax-entry ?  "    " emacs-lisp-mode-syntax-table)
           (modify-syntax-entry ?\t "    " emacs-lisp-mode-syntax-table)
           ...

           (modify-syntax-entry ?\( "()  " emacs-lisp-mode-syntax-table)
           (modify-syntax-entry ?\) ")(  " emacs-lisp-mode-syntax-table)
           ...))
     ;; Create an abbrev table for lisp-mode.
     (define-abbrev-table 'lisp-mode-abbrev-table ())

Much code is shared among the three Lisp modes.  The following function sets various variables; it is called by each of the major Lisp mode functions:

     (defun lisp-mode-variables (lisp-syntax)
       (cond (lisp-syntax
     	  (set-syntax-table lisp-mode-syntax-table)))
       (setq local-abbrev-table lisp-mode-abbrev-table)
       ...

Functions such as forward-paragraph use the value of the paragraph-start variable.  Since Lisp code is different from ordinary text, the paragraph-start variable needs to be set specially to handle Lisp.  Also, comments are indented in a special fashion in Lisp and the Lisp modes need their own mode-specific comment-indent-function.  The code to set these variables is the rest of lisp-mode-variables.

       (make-local-variable 'paragraph-start)
       (setq paragraph-start (concat page-delimiter "\\|$" ))
       (make-local-variable 'paragraph-separate)
       (setq paragraph-separate paragraph-start)
       ...

       (make-local-variable 'comment-indent-function)
       (setq comment-indent-function 'lisp-comment-indent))
       ...

Each of the different Lisp modes has a slightly different keymap.  For example, Lisp mode binds C-c C-z to run-lisp, but the other Lisp modes do not.  However, all Lisp modes have some commands in common.  The following code sets up the common commands:

     (defvar shared-lisp-mode-map ()
       "Keymap for commands shared by all sorts of Lisp modes.")

     (if shared-lisp-mode-map
         ()
        (setq shared-lisp-mode-map (make-sparse-keymap))
        (define-key shared-lisp-mode-map "\e\C-q" 'indent-sexp)
        (define-key shared-lisp-mode-map "\177"
                    'backward-delete-char-untabify))

And here is the code to set up the keymap for Lisp mode:

     (defvar lisp-mode-map ()
       "Keymap for ordinary Lisp mode...")

     (if lisp-mode-map
         ()
       (setq lisp-mode-map (make-sparse-keymap))
       (set-keymap-parent lisp-mode-map shared-lisp-mode-map)
       (define-key lisp-mode-map "\e\C-x" 'lisp-eval-defun)
       (define-key lisp-mode-map "\C-c\C-z" 'run-lisp))

Finally, here is the complete major mode function definition for Lisp mode.

     (defun lisp-mode ()
       "Major mode for editing Lisp code for Lisps other than GNU Emacs Lisp.
     Commands:
     Delete converts tabs to spaces as it moves back.
     Blank lines separate paragraphs.  Semicolons start comments.
     \\{lisp-mode-map}
     Note that `run-lisp' may be used either to start an inferior Lisp job
     or to switch back to an existing one.

     Entry to this mode calls the value of `lisp-mode-hook'
     if that value is non-nil."
       (interactive)
       (kill-all-local-variables)

       (use-local-map lisp-mode-map)          ; Select the mode's keymap.
       (setq major-mode 'lisp-mode)           ; This is how describe-mode
                                              ;   finds out what to describe.
       (setq mode-name "Lisp")                ; This goes into the mode line.
       (lisp-mode-variables t)                ; This defines various variables.

       (setq imenu-case-fold-search t)
       (set-syntax-table lisp-mode-syntax-table)
       (run-hooks 'lisp-mode-hook))           ; This permits the user to use a
                                              ;   hook to customize the mode.

How Emacs Chooses a Major Mode
------------------------------

Based on information in the file name or in the file itself, Emacs automatically selects a major mode for the new buffer when a file is visited.  It also processes local variables specified in the file text.

 -- Command: fundamental-mode
     Fundamental mode is a major mode that is not specialized for anything in particular.  Other major modes are defined in effect by comparison with this one---their definitions say what to change, starting from Fundamental mode.  The fundamental-mode function does not run any hooks; you're not supposed to customize it.  (If you want Emacs to behave differently in Fundamental mode, change the global state of Emacs.)

 -- Command: normal-mode &optional find-file
     This function establishes the proper major mode and buffer-local variable bindings for the current buffer.  First it calls set-auto-mode, then it runs hack-local-variables to parse, and bind or evaluate as appropriate, the file's local variables.

     If the FIND-FILE argument to normal-mode is non-nil, normal-mode assumes that the find-file function is calling it.  In this case, it may process a local variables list at the end of the file and in the -*- line.  The variable enable-local-variables controls whether to do so.  See Local Variables in Files (The GNU Emacs Manual), for the syntax of the local variables section of a file.

     If you run normal-mode interactively, the argument FIND-FILE is normally nil.  In this case, normal-mode unconditionally processes any local variables list.

     normal-mode uses condition-case around the call to the major mode function, so errors are caught and reported as a File mode specification error,  followed by the original error message.

 -- User Option: enable-local-variables
     This variable controls processing of local variables lists in files being visited.  A value of t means process the local variables lists unconditionally; nil means ignore them; anything else means ask the user what to do for each file.  The default value is t.

 -- Variable: ignored-local-variables
     This variable holds a list of variables that should not be set by a file's local variables list.  Any value specified for one of these variables is ignored.

In addition to this list, any variable whose name has a non-nil risky-local-variable property is also ignored.

 -- User Option: enable-local-eval
     This variable controls processing of Eval: in local variables lists in files being visited.  A value of t means process them unconditionally; nil means ignore them; anything else means ask the user what to do for each file.  The default value is maybe.

 -- Function: set-auto-mode
     This function selects the major mode that is appropriate for the current buffer.  It may base its decision on the value of the -*- line, on the visited file name (using auto-mode-alist), on the #! line (using interpreter-mode-alist), or on the file's local variables list.  However, this function does not look for the mode: local variable near the end of a file; the hack-local-variables function does that.  See How Major Modes are Chosen (The GNU Emacs Manual).

 -- User Option: default-major-mode
     This variable holds the default major mode for new buffers.  The standard value is fundamental-mode.

     If the value of default-major-mode is nil, Emacs uses the (previously) current buffer's major mode for the major mode of a new buffer.  However, if that major mode symbol has a mode-class property with value special, then it is not used for new buffers; Fundamental mode is used instead.  The modes that have this property are those such as Dired and Rmail that are useful only with text that has been specially prepared.

 -- Function: set-buffer-major-mode buffer
     This function sets the major mode of BUFFER to the value of default-major-mode.  If that variable is nil, it uses the current buffer's major mode (if that is suitable).

     The low-level primitives for creating buffers do not use this function, but medium-level commands such as switch-to-buffer and find-file-noselect use it whenever they create buffers.

 -- Variable: initial-major-mode
     The value of this variable determines the major mode of the initial *scratch* buffer.  The value should be a symbol that is a major mode command.  The default value is lisp-interaction-mode.

 -- Variable: auto-mode-alist
     This variable contains an association list of file name patterns (regular expressions; see Regular Expressions) and corresponding major mode commands.  Usually, the file name patterns test for suffixes, such as .el and .c, but this need not be the case.  An ordinary element of the alist looks like (REGEXP . MODE-FUNCTION).

     For example,

          (("\\`/tmp/fol/" . text-mode)
           ("\\.texinfo\\'" . texinfo-mode)
           ("\\.texi\\'" . texinfo-mode)

           ("\\.el\\'" . emacs-lisp-mode)
           ("\\.c\\'" . c-mode)
           ("\\.h\\'" . c-mode)
           ...)

     When you visit a file whose expanded file name (see File Name Expansion) matches a REGEXP, set-auto-mode calls the corresponding MODE-FUNCTION.  This feature enables Emacs to select the proper major mode for most files.

     If an element of auto-mode-alist has the form (REGEXP FUNCTION t), then after calling FUNCTION, Emacs searches auto-mode-alist again for a match against the portion of the file name that did not match before.  This feature is useful for uncompression packages: an entry of the form ("\\.gz\\'" FUNCTION t) can uncompress the file and then put the uncompressed file in the proper mode according to the name sans .gz.

     Here is an example of how to prepend several pattern pairs to auto-mode-alist.  (You might use this sort of expression in your init file.)

          (setq auto-mode-alist
            (append
             ;; File name (within directory) starts with a dot.
             '(("/\\.[^/]*\\'" . fundamental-mode)
               ;; File name has no dot.
               ("[^\\./]*\\'" . fundamental-mode)
               ;; File name ends in .C.
               ("\\.C\\'" . c++-mode))
             auto-mode-alist))

 -- Variable: interpreter-mode-alist
     This variable specifies major modes to use for scripts that specify a command interpreter in a #! line.  Its value is a list of elements of the form (INTERPRETER . MODE); for example, ("perl" . perl-mode) is one element present by default. The element says to use mode MODE if the file specifies an interpreter which matches INTERPRETER.  The value of INTERPRETER is actually a regular expression.

     This variable is applicable only when the auto-mode-alist does not indicate which major mode to use.

 -- Function: hack-local-variables &optional force
     This function parses, and binds or evaluates as appropriate, any local variables specified by the contents of the current buffer.

     The handling of enable-local-variables documented for normal-mode actually takes place here.  The argument FORCE usually comes from the argument FIND-FILE given to normal-mode.

Getting Help about a Major Mode
-------------------------------

The describe-mode function is used to provide information about major modes.  It is normally called with C-h m.  The describe-mode function uses the value of major-mode, which is why every major mode function needs to set the major-mode variable.

 -- Command: describe-mode
     This function displays the documentation of the current major mode.

     The describe-mode function calls the documentation function using the value of major-mode as an argument.  Thus, it displays the documentation string of the major mode function. (see Accessing Documentation.)

 -- Variable: major-mode
     This variable holds the symbol for the current buffer's major mode. This symbol should have a function definition that is the command to switch to that major mode.  The describe-mode function uses the documentation string of the function as the documentation of the major mode.

Defining Derived Modes
----------------------

It's often useful to define a new major mode in terms of an existing one.  An easy way to do this is to use define-derived-mode.

 -- Macro: define-derived-mode variant parent name docstring body...
     This construct defines VARIANT as a major mode command, using NAME as the string form of the mode name.

     The new command VARIANT is defined to call the function PARENT, then override certain aspects of that parent mode:

       * The new mode has its own keymap, named VARIANT-map. define-derived-mode initializes this map to inherit from PARENT-map, if it is not already set.

       * The new mode has its own syntax table, kept in the variable VARIANT-syntax-table. define-derived-mode initializes this variable by copying PARENT-syntax-table, if it is not already set.

       * The new mode has its own abbrev table, kept in the variable VARIANT-abbrev-table. define-derived-mode initializes this variable by copying PARENT-abbrev-table, if it is not already set.

       * The new mode has its own mode hook, VARIANT-hook, which it runs in standard fashion as the very last thing that it does. (The new mode also runs the mode hook of PARENT as part of calling PARENT.)

     In addition, you can specify how to override other aspects of PARENT with BODY.  The command VARIANT evaluates the forms in BODY after setting up all its usual overrides, just before running VARIANT-hook.

     The argument DOCSTRING specifies the documentation string for the new mode.  If you omit DOCSTRING, define-derived-mode generates a documentation string.

     Here is a hypothetical example:

          (define-derived-mode hypertext-mode
            text-mode "Hypertext"
            "Major mode for hypertext.
          \\{hypertext-mode-map}"
            (setq case-fold-search nil))

          (define-key hypertext-mode-map
            [down-mouse-3] 'do-hyper-link)

Minor Modes
===========

A minor mode provides features that users may enable or disable independently of the choice of major mode.  Minor modes can be enabled individually or in combination.  Minor modes would be better named ``generally available, optional feature modes,'' except that such a name would be unwieldy.

A minor mode is not usually meant as a variation of a single major mode. Usually they are general and can apply to many major modes.  For example, Auto Fill mode works with any major mode that permits text insertion.  To be general, a minor mode must be effectively independent of the things major modes do.

A minor mode is often much more difficult to implement than a major mode.  One reason is that you should be able to activate and deactivate minor modes in any order.  A minor mode should be able to have its desired effect regardless of the major mode and regardless of the other minor modes in effect.

Often the biggest problem in implementing a minor mode is finding a way to insert the necessary hook into the rest of Emacs.  Minor mode keymaps make this easier than it used to be.

Conventions for Writing Minor Modes
-----------------------------------

There are conventions for writing minor modes just as there are for major modes.  Several of the major mode conventions apply to minor modes as well: those regarding the name of the mode initialization function, the names of global symbols, and the use of keymaps and other tables.

In addition, there are several conventions that are specific to minor modes.

  * Make a variable whose name ends in -mode to control the minor mode.  We call this the mode variable.  The minor mode command should set this variable (nil to disable; anything else to enable).

     If possible, implement the mode so that setting the variable automatically enables or disables the mode.  Then the minor mode command does not need to do anything except set the variable.

     This variable is used in conjunction with the minor-mode-alist to display the minor mode name in the mode line.  It can also enable or disable a minor mode keymap.  Individual commands or hooks can also check the variable's value.

     If you want the minor mode to be enabled separately in each buffer, make the variable buffer-local.

  * Define a command whose name is the same as the mode variable. Its job is to enable and disable the mode by setting the variable.

     The command should accept one optional argument.  If the argument is nil, it should toggle the mode (turn it on if it is off, and off if it is on).  Otherwise, it should turn the mode on if the argument is a positive integer, a symbol other than nil or -, or a list whose CAR is such an integer or symbol; it should turn the mode off otherwise.

     Here is an example taken from the definition of transient-mark-mode. It shows the use of transient-mark-mode as a variable that enables or disables the mode's behavior, and also shows the proper way to toggle, enable or disable the minor mode based on the raw prefix argument value.

          (setq transient-mark-mode
                (if (null arg) (not transient-mark-mode)
                  (> (prefix-numeric-value arg) 0)))

  * Add an element to minor-mode-alist for each minor mode (see Mode Line Variables), if you want to indicate the minor mode in the mode line.  This element should be a list of the following form:

          (MODE-VARIABLE STRING)

     Here MODE-VARIABLE is the variable that controls enabling of the minor mode, and STRING is a short string, starting with a space, to represent the mode in the mode line.  These strings must be short so that there is room for several of them at once.

     When you add an element to minor-mode-alist, use assq to check for an existing element, to avoid duplication.  For example:

          (unless (assq 'leif-mode minor-mode-alist)
            (setq minor-mode-alist
                  (cons '(leif-mode " Leif") minor-mode-alist)))

     or like this, using add-to-list (see Setting Variables):

          (add-to-list 'minor-mode-alist '(leif-mode " Leif"))

Global minor modes distributed with Emacs should if possible support enabling and disabling via Custom (see Customization).  To do this, the first step is to define the mode variable with defcustom, and specify :type boolean.

If just setting the variable is not sufficient to enable the mode, you should also specify a :set method which enables the mode by invoke the mode command.  Note in the variable's documentation string that setting the variable other than via Custom may not take effect.

Also mark the definition with an autoload cookie (see Autoload), and specify a :require so that customizing the variable will load the library that defines the mode.  This will copy suitable definitions into loaddefs.el so that users can use customize-option to enable the mode.  For example:

     ;;;###autoload
     (defcustom msb-mode nil
       "Toggle msb-mode.
     Setting this variable directly does not take effect;
     use either \\[customize] or the function `msb-mode'."
       :set (lambda (symbol value)
     	 (msb-mode (or value 0)))
       :initialize 'custom-initialize-default
       :version "20.4"
       :type    'boolean
       :group   'msb
       :require 'msb)

Keymaps and Minor Modes
-----------------------

Each minor mode can have its own keymap, which is active when the mode is enabled.  To set up a keymap for a minor mode, add an element to the alist minor-mode-map-alist.  See Active Keymaps.

One use of minor mode keymaps is to modify the behavior of certain self-inserting characters so that they do something else as well as self-insert.  In general, this is the only way to do that, since the facilities for customizing self-insert-command are limited to special cases (designed for abbrevs and Auto Fill mode).  (Do not try substituting your own definition of self-insert-command for the standard one.  The editor command loop handles this function specially.)

The key sequences bound in a minor mode should consist of C-c followed by a punctuation character other than {, }, <, >, :, and ;.  (Those few punctuation characters are reserved for major modes.)

Defining Minor Modes
--------------------

The macro define-minor-mode offers a convenient way of implementing a mode in one self-contained definition.  It supports only buffer-local minor modes, not global ones.

 -- Macro: define-minor-mode mode doc &optional init-value mode-indicator keymap body...
     This macro defines a new minor mode whose name is MODE (a symbol). It defines a command named MODE to toggle the minor mode, with DOC as its documentation string.  It also defines a variable named MODE, which is set to t or nil by enabling or disabling the mode.  The variable is initialized to INIT-VALUE.

     The command named MODE finishes by executing the BODY forms, if any, after it has performed the standard actions such as setting the variable named MODE.

     The string MODE-INDICATOR says what to display in the mode line when the mode is enabled; if it is nil, the mode is not displayed in the mode line.

     The optional argument KEYMAP specifies the keymap for the minor mode. It can be a variable name, whose value is the keymap, or it can be an alist specifying bindings in this form:

          (KEY-SEQUENCE . DEFINITION)

Here is an example of using define-minor-mode:

     (define-minor-mode hungry-mode
       "Toggle Hungry mode.
     With no argument, this command toggles the mode.
     Non-null prefix argument turns on the mode.
     Null prefix argument turns off the mode.

     When Hungry mode is enabled, the control delete key
     gobbles all preceding whitespace except the last.
     See the command \\[hungry-electric-delete]."
      ;; The initial value.
      nil
      ;; The indicator for the mode line.
      " Hungry"
      ;; The minor mode bindings.
      '(("\C-\^?" . hungry-electric-delete)
        ("\C-\M-\^?"
         . (lambda ()
             (interactive)
             (hungry-electric-delete t)))))

This defines a minor mode named ``Hungry mode'', a command named hungry-mode to toggle it, a variable named hungry-mode which indicates whether the mode is enabled, and a variable named hungry-mode-map which holds the keymap that is active when the mode is enabled.  It initializes the keymap with key bindings for C-DEL and C-M-DEL.

The name easy-mmode-define-minor-mode is an alias for this macro.

Mode Line Format
================

Each Emacs window (aside from minibuffer windows) typically has a mode line at the bottom, which displays status information about the buffer displayed in the window.  The mode line contains information about the buffer, such as its name, associated file, depth of recursive editing, and major and minor modes.  A window can also have a header line, which is much like the mode line but appears at the top of the window (starting in Emacs 21).

This section describes how to control the contents of the mode line and header line.  We include it in this chapter because much of the information displayed in the mode line relates to the enabled major and minor modes.

mode-line-format is a buffer-local variable that holds a template used to display the mode line of the current buffer.  All windows for the same buffer use the same mode-line-format, so their mode lines appear the same---except for scrolling percentages, and line and column numbers, since those depend on point and on how the window is scrolled.  header-line-format is used likewise for header lines.

The mode line and header line of a window are normally updated whenever a different buffer is shown in the window, or when the buffer's modified-status changes from nil to t or vice-versa.  If you modify any of the variables referenced by mode-line-format (see Mode Line Variables), or any other variables and data structures that affect how text is displayed (see Display), you may want to force an update of the mode line so as to display the new information or display it in the new way.

 -- Function: force-mode-line-update
     Force redisplay of the current buffer's mode line and header line.

The mode line is usually displayed in inverse video; see mode-line-inverse-video in Inverse Video.

The Data Structure of the Mode Line
-----------------------------------

The mode line contents are controlled by a data structure of lists, strings, symbols, and numbers kept in buffer-local variables.  The data structure is called a mode line construct, and it is built in recursive fashion out of simpler mode line constructs.  The same data structure is used for constructing frame titles (see Frame Titles) and header lines (see Header Lines).

 -- Variable: mode-line-format
     The value of this variable is a mode line construct with overall responsibility for the mode line format.  The value of this variable controls which other variables are used to form the mode line text, and where they appear.

     If you set this variable to nil in a buffer, that buffer does not have a mode line.  (This feature was added in Emacs 21.)

A mode line construct may be as simple as a fixed string of text, but it usually specifies how to use other variables to construct the text. Many of these variables are themselves defined to have mode line constructs as their values.

The default value of mode-line-format incorporates the values of variables such as mode-name and minor-mode-alist. Because of this, very few modes need to alter mode-line-format itself.  For most purposes, it is sufficient to alter some of the variables that mode-line-format refers to.

A mode line construct may be a list, a symbol, or a string.  If the value is a list, each element may be a list, a symbol, or a string.

The mode line can display various faces, if the strings that control it have the face property.  See Properties in Mode.  In addition, the face mode-line is used as a default for the whole mode line (see Standard Faces).

STRING
     A string as a mode line construct is displayed verbatim in the mode line except for %-constructs.  Decimal digits after the % specify the field width for space filling on the right (i.e., the data is left justified).  See %-Constructs.

SYMBOL
     A symbol as a mode line construct stands for its value.  The value of SYMBOL is used as a mode line construct, in place of SYMBOL. However, the symbols t and nil are ignored, as is any symbol whose value is void.

     There is one exception: if the value of SYMBOL is a string, it is displayed verbatim: the %-constructs are not recognized.

(STRING REST...) or (LIST REST...)
     A list whose first element is a string or list means to process all the elements recursively and concatenate the results.  This is the most common form of mode line construct.

(:eval FORM)
     A list whose first element is the symbol :eval says to evaluate FORM, and use the result as a string to display. (This feature is new as of Emacs 21.)

(SYMBOL THEN ELSE)
     A list whose first element is a symbol that is not a keyword specifies a conditional.  Its meaning depends on the value of SYMBOL.  If the value is non-nil, the second element, THEN, is processed recursively as a mode line element.  But if the value of SYMBOL is nil, the third element, ELSE, is processed recursively. You may omit ELSE; then the mode line element displays nothing if the value of SYMBOL is nil.

(WIDTH REST...)
     A list whose first element is an integer specifies truncation or padding of the results of REST.  The remaining elements REST are processed recursively as mode line constructs and concatenated together.  Then the result is space filled (if WIDTH is positive) or truncated (to -WIDTH columns, if WIDTH is negative) on the right.

     For example, the usual way to show what percentage of a buffer is above the top of the window is to use a list like this: (-3 "%p").

If you do alter mode-line-format itself, the new value should use the same variables that appear in the default value (see Mode Line Variables), rather than duplicating their contents or displaying the information in another fashion.  This way, customizations made by the user or by Lisp programs (such as display-time and major modes) via changes to those variables remain effective.

Here is an example of a mode-line-format that might be useful for shell-mode, since it contains the host name and default directory.

     (setq mode-line-format
       (list "-"
        'mode-line-mule-info
        'mode-line-modified
        'mode-line-frame-identification
        "%b--"

        ;; Note that this is evaluated while making the list.
        ;; It makes a mode line construct which is just a string.
        (getenv "HOST")

        ":"
        'default-directory
        "   "
        'global-mode-string
        "   %[("
        '(:eval (mode-line-mode-name))
        'mode-line-process
        'minor-mode-alist
        "%n"
        ")%]--"

        '(which-func-mode ("" which-func-format "--"))
        '(line-number-mode "L%l--")
        '(column-number-mode "C%c--")
        '(-3 . "%p")
        "-%-"))

(The variables line-number-mode, column-number-mode and which-func-mode enable particular minor modes; as usual, these variable names are also the minor mode command names.)

Variables Used in the Mode Line
-------------------------------

This section describes variables incorporated by the standard value of mode-line-format into the text of the mode line.  There is nothing inherently special about these variables; any other variables could have the same effects on the mode line if mode-line-format were changed to use them.

 -- Variable: mode-line-mule-info
     This variable holds the value of the mode-line construct that displays information about the language environment, buffer coding system, and current input method.  See Non-ASCII Characters.

 -- Variable: mode-line-modified
     This variable holds the value of the mode-line construct that displays whether the current buffer is modified.

     The default value of mode-line-modified is ("%1*%1+"). This means that the mode line displays ** if the buffer is modified, -- if the buffer is not modified, %% if the buffer is read only, and %* if the buffer is read only and modified.

     Changing this variable does not force an update of the mode line.

 -- Variable: mode-line-frame-identification
     This variable identifies the current frame.  The default value is " " if you are using a window system which can show multiple frames, or "-%F " on an ordinary terminal which shows only one frame at a time.

 -- Variable: mode-line-buffer-identification
     This variable identifies the buffer being displayed in the window.  Its default value is ("%12b"), which displays the buffer name, padded with spaces to at least 12 columns.

 -- Variable: global-mode-string
     This variable holds a mode line spec that appears in the mode line by default, just after the buffer name.  The command display-time sets global-mode-string to refer to the variable display-time-string, which holds a string containing the time and load information.

     The %M construct substitutes the value of global-mode-string, but that is obsolete, since the variable is included in the mode line from mode-line-format.

 -- Variable: mode-name
     This buffer-local variable holds the ``pretty'' name of the current buffer's major mode.  Each major mode should set this variable so that the mode name will appear in the mode line.

 -- Variable: minor-mode-alist
     This variable holds an association list whose elements specify how the mode line should indicate that a minor mode is active.  Each element of the minor-mode-alist should be a two-element list:

          (MINOR-MODE-VARIABLE MODE-LINE-STRING)

     More generally, MODE-LINE-STRING can be any mode line spec.  It appears in the mode line when the value of MINOR-MODE-VARIABLE is non-nil, and not otherwise.  These strings should begin with spaces so that they don't run together.  Conventionally, the MINOR-MODE-VARIABLE for a specific mode is set to a non-nil value when that minor mode is activated.

     The default value of minor-mode-alist is:

          minor-mode-alist
          => ((vc-mode vc-mode)
              (abbrev-mode " Abbrev")
              (overwrite-mode overwrite-mode)
              (auto-fill-function " Fill")
              (defining-kbd-macro " Def")
              (isearch-mode isearch-mode))

     minor-mode-alist itself is not buffer-local.  Each variable mentioned in the alist should be buffer-local if its minor mode can be enabled separately in each buffer.

 -- Variable: mode-line-process
     This buffer-local variable contains the mode line information on process status in modes used for communicating with subprocesses.  It is displayed immediately following the major mode name, with no intervening space.  For example, its value in the *shell* buffer is (":%s"), which allows the shell to display its status along with the major mode as: (Shell:run).  Normally this variable is nil.

Some variables are used by minor-mode-alist to display a string for various minor modes when enabled.  This is a typical example:

 -- Variable: vc-mode
     The variable vc-mode, buffer-local in each buffer, records whether the buffer's visited file is maintained with version control, and, if so, which kind.  Its value is a string that appears in the mode line, or nil for no version control.

The variable default-mode-line-format is where mode-line-format usually gets its value:

 -- Variable: default-mode-line-format
     This variable holds the default mode-line-format for buffers that do not override it.  This is the same as (default-value 'mode-line-format).

     The default value of default-mode-line-format is this list:

          ("-"
           mode-line-mule-info
           mode-line-modified
           mode-line-frame-identification
           mode-line-buffer-identification

           "   "
           global-mode-string

           "   %[("
           ;; mode-line-mode-name is a function
           ;; that copies the mode name and adds text
           ;; properties to make it mouse-sensitive.
           (:eval (mode-line-mode-name))
           mode-line-process
           minor-mode-alist
           "%n"
           ")%]--"

           (which-func-mode ("" which-func-format "--"))
           (line-number-mode "L%l--")
           (column-number-mode "C%c--")
           (-3 . "%p")
           "-%-")

%-Constructs in the Mode Line
-----------------------------

The following table lists the recognized %-constructs and what they mean.  In any construct except %%, you can add a decimal integer after the % to specify how many characters to display.

%b
     The current buffer name, obtained with the buffer-name function. See Buffer Names.

%c
     The current column number of point.

%f
     The visited file name, obtained with the buffer-file-name function.  See Buffer File Name.

%F
     The title (only on a window system) or the name of the selected frame. See Window Frame Parameters.

%l
     The current line number of point, counting within the accessible portion of the buffer.

%n
     Narrow when narrowing is in effect; nothing otherwise (see narrow-to-region in Narrowing).

%p
     The percentage of the buffer text above the top of window, or Top, Bottom or All.  Note that the default mode-line specification truncates this to three characters.

%P
     The percentage of the buffer text that is above the bottom of the window (which includes the text visible in the window, as well as the text above the top), plus Top if the top of the buffer is visible on screen; or Bottom or All.

%s
     The status of the subprocess belonging to the current buffer, obtained with process-status.  See Process Information.

%t
     Whether the visited file is a text file or a binary file.  This is a meaningful distinction only on certain operating systems (see MS-DOS File Types).

%*
     % if the buffer is read only (see buffer-read-only);

     * if the buffer is modified (see buffer-modified-p);

     - otherwise.  See Buffer Modification.

%+
     * if the buffer is modified (see buffer-modified-p);

     % if the buffer is read only (see buffer-read-only);

     - otherwise.  This differs from %* only for a modified read-only buffer.  See Buffer Modification.

%&
     * if the buffer is modified, and - otherwise.

%[
     An indication of the depth of recursive editing levels (not counting minibuffer levels): one [ for each editing level. See Recursive Editing.

%]
     One ] for each recursive editing level (not counting minibuffer levels).

%-
     Dashes sufficient to fill the remainder of the mode line.

%%
     The character %---this is how to include a literal % in a string in which %-constructs are allowed.

The following two %-constructs are still supported, but they are obsolete, since you can get the same results with the variables mode-name and global-mode-string.

%m
     The value of mode-name.

%M
     The value of global-mode-string.  Currently, only display-time modifies the value of global-mode-string.

Properties in the Mode Line
---------------------------

Starting in Emacs 21, certain text properties are meaningful in the mode line.  The face property affects the appearance of text; the help-echo property associate help strings with the text, and local-map can make the text mouse-sensitive.

There are three ways to specify text properties for text in the mode line:

 1. Put a string with the local-map property directly into the mode-line data structure.

 2. Put a local-map property on a mode-line %-construct such as %12b; then the expansion of the %-construct will have that same text property.

 3. Use a list containing :eval FORM in the mode-line data structure, and make FORM evaluate to a string that has a local-map property.

You use the local-map property to specify a keymap.  Like any keymap, it can bind character keys and function keys; but that has no effect, since it is impossible to move point into the mode line.  This keymap can only take real effect for mouse clicks.

Window Header Lines
-------------------

Starting in Emacs 21, a window can have a header line at the top, just as it can have a mode line at the bottom.  The header line feature works just like the mode line feature, except that it's controlled by different variables.

 -- Variable: header-line-format
     This variable, local in every buffer, specifies how to display the header line, for windows displaying the buffer.  The format of the value is the same as for mode-line-format (see Mode Line Data).

 -- Variable: default-header-line-format
     This variable holds the default header-line-format for buffers that do not override it.  This is the same as (default-value 'header-line-format).

     It is normally nil, so that ordinary buffers have no header line.

Imenu
=====

Imenu is a feature that lets users select a definition or section in the buffer, from a menu which lists all of them, to go directly to that location in the buffer.  Imenu works by constructing a buffer index which lists the names and buffer positions of the definitions, or other named portions of the buffer; then the user can choose one of them and move point to it.  This section explains how to customize how Imenu finds the definitions or buffer portions for a particular major mode.

The usual and simplest way is to set the variable imenu-generic-expression:

 -- Variable: imenu-generic-expression
     This variable, if non-nil, specifies regular expressions for finding definitions for Imenu.  In the simplest case, elements should look like this:

          (MENU-TITLE REGEXP SUBEXP)

     Here, if MENU-TITLE is non-nil, it says that the matches for this element should go in a submenu of the buffer index; MENU-TITLE itself specifies the name for the submenu.  If MENU-TITLE is nil, the matches for this element go directly in the top level of the buffer index.

     The second item in the list, REGEXP, is a regular expression (see Regular Expressions); anything in the buffer that it matches is considered a definition, something to mention in the buffer index.  The third item, SUBEXP, indicates which subexpression in REGEXP matches the definition's name.

     An element can also look like this:

          (MENU-TITLE REGEXP INDEX FUNCTION ARGUMENTS...)

     Each match for this element creates a special index item which, if selected by the user, calls FUNCTION with arguments consisting of the item name, the buffer position, and ARGUMENTS.

     For Emacs Lisp mode, PATTERN could look like this:

          ((nil "^\\s-*(def\\(un\\|subst\\|macro\\|advice\\)\
          \\s-+\\([-A-Za-z0-9+]+\\)" 2)

           ("*Vars*" "^\\s-*(def\\(var\\|const\\)\
          \\s-+\\([-A-Za-z0-9+]+\\)" 2)

           ("*Types*"
            "^\\s-*\
          (def\\(type\\|struct\\|class\\|ine-condition\\)\
          \\s-+\\([-A-Za-z0-9+]+\\)" 2))

     Setting this variable makes it buffer-local in the current buffer.

 -- Variable: imenu-case-fold-search
     This variable controls whether matching against IMENU-GENERIC-EXPRESSION is case-sensitive: t, the default, means matching should ignore case.

     Setting this variable makes it buffer-local in the current buffer.

 -- Variable: imenu-syntax-alist
     This variable is an alist of syntax table modifiers to use while processing imenu-generic-expression, to override the syntax table of the current buffer.  Each element should have this form:

          (CHARACTERS . SYNTAX-DESCRIPTION)

     The CAR, CHARACTERS, can be either a character or a string. The element says to give that character or characters the syntax specified by SYNTAX-DESCRIPTION, which is passed to modify-syntax-entry (see Syntax Table Functions).

     This feature is typically used to give word syntax to characters which normally have symbol syntax, and thus to simplify imenu-generic-expression and speed up matching. For example, Fortran mode uses it this way:

            (setq imenu-syntax-alist '(("_$" . "w")))

     The imenu-generic-expression patterns can then use \\sw+ instead of \\(\\sw\\|\\s_\\)+.  Note that this technique may be inconvenient when the mode needs to limit the initial character of a name to a smaller set of characters than are allowed in the rest of a name.

     Setting this variable makes it buffer-local in the current buffer.

Another way to customize Imenu for a major mode is to set the variables imenu-prev-index-position-function and imenu-extract-index-name-function:

 -- Variable: imenu-prev-index-position-function
     If this variable is non-nil, its value should be a function that finds the next ``definition'' to put in the buffer index, scanning backward in the buffer from point.  It should return nil if it doesn't find another ``definition'' before point.  Otherwise it shuould leave point at the place it finds a ``definition,'' and return any non-nil value.

     Setting this variable makes it buffer-local in the current buffer.

 -- Variable: imenu-extract-index-name-function
     If this variable is non-nil, its value should be a function to return the name for a definition, assuming point is in that definition as the imenu-prev-index-position-function function would leave it.

     Setting this variable makes it buffer-local in the current buffer.

The last way to customize Imenu for a major mode is to set the variable imenu-create-index-function:

 -- Variable: imenu-create-index-function
     This variable specifies the function to use for creating a buffer index. The function should take no arguments, and return an index for the current buffer.  It is called within save-excursion, so where it leaves point makes no difference.

     The default value is a function that uses imenu-generic-expression to produce the index alist.  If you specify a different function, then imenu-generic-expression is not used.

     Setting this variable makes it buffer-local in the current buffer.

 -- Variable: imenu-index-alist
     This variable holds the index alist for the current buffer. Setting it makes it buffer-local in the current buffer.

     Simple elements in the alist look like (INDEX-NAME . INDEX-POSITION).  Selecting a simple element has the effect of moving to position INDEX-POSITION in the buffer.

     Special elements look like (INDEX-NAME POSITION FUNCTION ARGUMENTS...).  Selecting a special element performs

          (funcall FUNCTION INDEX-NAME POSITION ARGUMENTS...)

     A nested sub-alist element looks like (INDEX-NAME SUB-ALIST).

Font Lock Mode
==============

Font Lock mode is a feature that automatically attaches face properties to certain parts of the buffer based on their syntactic role.  How it parses the buffer depends on the major mode; most major modes define syntactic criteria for which faces to use in which contexts.  This section explains how to customize Font Lock for a particular major mode.

Font Lock mode finds text to highlight in two ways: through syntactic parsing based on the syntax table, and through searching (usually for regular expressions).  Syntactic fontification happens first; it finds comments and string constants, and highlights them using font-lock-comment-face and font-lock-string-face (see Faces for Font Lock).  Search-based fontification follows.

Font Lock Basics
----------------

There are several variables that control how Font Lock mode highlights text.  But major modes should not set any of these variables directly. Instead, they should set font-lock-defaults as a buffer-local variable.  The value assigned to this variable is used, if and when Font Lock mode is enabled, to set all the other variables.

 -- Variable: font-lock-defaults
     This variable is set by major modes, as a buffer-local variable, to specify how to fontify text in that mode.  The value should look like this:

          (KEYWORDS KEYWORDS-ONLY CASE-FOLD
           SYNTAX-ALIST SYNTAX-BEGIN OTHER-VARS...)

     The first element, KEYWORDS, indirectly specifies the value of font-lock-keywords.  It can be a symbol, a variable whose value is the list to use for font-lock-keywords.  It can also be a list of several such symbols, one for each possible level of fontification.  The first symbol specifies how to do level 1 fontification, the second symbol how to do level 2, and so on.

     The second element, KEYWORDS-ONLY, specifies the value of the variable font-lock-keywords-only.  If this is non-nil, syntactic fontification (of strings and comments) is not performed.

     The third element, CASE-FOLD, specifies the value of font-lock-case-fold-search.  If it is non-nil, Font Lock mode ignores case when searching as directed by font-lock-keywords.

     If the fourth element, SYNTAX-ALIST, is non-nil, it should be a list of cons cells of the form (CHAR-OR-STRING . STRING).  These are used to set up a syntax table for fontification (see Syntax Table Functions).  The resulting syntax table is stored in font-lock-syntax-table.

     The fifth element, SYNTAX-BEGIN, specifies the value of font-lock-beginning-of-syntax-function (see below).

     All the remaining elements (if any) are collectively called OTHER-VARS.  Each of these elements should have the form (VARIABLE . VALUE)---which means, make VARIABLE buffer-local and then set it to VALUE.  You can use these OTHER-VARS to set other variables that affect fontification, aside from those you can control with the first five elements.

Search-based Fontification
--------------------------

The most important variable for customizing Font Lock mode is font-lock-keywords.  It specifies the search criteria for search-based fontification.

 -- Variable: font-lock-keywords
     This variable's value is a list of the keywords to highlight.  Be careful when composing regular expressions for this list; a poorly written pattern can dramatically slow things down!

Each element of font-lock-keywords specifies how to find certain cases of text, and how to highlight those cases.  Font Lock mode processes the elements of font-lock-keywords one by one, and for each element, it finds and handles all matches.  Ordinarily, once part of the text has been fontified already, this cannot be overridden by a subsequent match in the same text; but you can specify different behavior using the OVERRIDE element of a HIGHLIGHTER.

Each element of font-lock-keywords should have one of these forms:

REGEXP
     Highlight all matches for REGEXP using font-lock-keyword-face.  For example,

          ;; Highlight discrete occurrences of foo
          ;; using font-lock-keyword-face.
          "\\<foo\\>"

     The function regexp-opt (see Syntax of Regexps) is useful for calculating optimal regular expressions to match a number of different keywords.

FUNCTION
     Find text by calling FUNCTION, and highlight the matches it finds using font-lock-keyword-face.

     When FUNCTION is called, it receives one argument, the limit of the search.  It should return non-nil if it succeeds, and set the match data to describe the match that was found.

(MATCHER . MATCH)
     In this kind of element, MATCHER is either a regular expression or a function, as described above.  The CDR, MATCH, specifies which subexpression of MATCHER should be highlighted (instead of the entire text that MATCHER matched).

          ;; Highlight the bar in each occurrence of fubar,
          ;; using font-lock-keyword-face.
          ("fu\\(bar\\)" . 1)

     If you use regexp-opt to produce the regular expression MATCHER, then you can use regexp-opt-depth (see Syntax of Regexps) to calculate the value for MATCH.

(MATCHER . FACENAME)
     In this kind of element, FACENAME is an expression whose value specifies the face name to use for highlighting.

          ;; Highlight occurrences of fubar,
          ;; using the face which is the value of fubar-face.
          ("fubar" . fubar-face)

(MATCHER . HIGHLIGHTER)
     In this kind of element, HIGHLIGHTER is a list which specifies how to highlight matches found by MATCHER. It has the form

          (SUBEXP FACENAME OVERRIDE LAXMATCH)

     The CAR, SUBEXP, is an integer specifying which subexpression of the match to fontify (0 means the entire matching text).  The second subelement, FACENAME, specifies the face, as described above.

     The last two values in HIGHLIGHTER, OVERRIDE and LAXMATCH, are flags.  If OVERRIDE is t, this element can override existing fontification made by previous elements of font-lock-keywords.  If it is keep, then each character is fontified if it has not been fontified already by some other element. If it is prepend, the face FACENAME is added to the beginning of the face property.  If it is append, the face FACENAME is added to the end of the face property.

     If LAXMATCH is non-nil, it means there should be no error if there is no subexpression numbered SUBEXP in MATCHER. Obviously, fontification of the subexpression numbered SUBEXP will not occur.  However, fontification of other subexpressions (and other regexps) will continue.  If LAXMATCH is nil, and the specified subexpression is missing, then an error is signalled which terminates search-based fontification.

     Here are some examples of elements of this kind, and what they do:

          ;; Highlight occurrences of either foo or bar,
          ;; using foo-bar-face, even if they have already been highlighted.
          ;; foo-bar-face should be a variable whose value is a face.
          ("foo\\|bar" 0 foo-bar-face t)

          ;; Highlight the first subexpression within each occurrence
          ;; that the function fubar-match finds,
          ;; using the face which is the value of fubar-face.
          (fubar-match 1 fubar-face)

(MATCHER HIGHLIGHTERS...)
     This sort of element specifies several HIGHLIGHTER lists for a single MATCHER.  In order for this to be useful, each HIGHLIGHTER should have a different value of SUBEXP; that is, each one should apply to a different subexpression of MATCHER.

(eval . FORM)
     Here FORM is an expression to be evaluated the first time this value of font-lock-keywords is used in a buffer. Its value should have one of the forms described in this table.

Warning: Do not design an element of font-lock-keywords to match text which spans lines; this does not work reliably.  While font-lock-fontify-buffer handles multi-line patterns correctly, updating when you edit the buffer does not, since it considers text one line at a time.

Other Font Lock Variables
-------------------------

This section describes additional variables that a major mode can set by means of font-lock-defaults.

 -- Variable: font-lock-keywords-only
     Non-nil means Font Lock should not fontify comments or strings syntactically; it should only fontify based on font-lock-keywords.

 -- Variable: font-lock-keywords-case-fold-search
     Non-nil means that regular expression matching for the sake of font-lock-keywords should be case-insensitive.

 -- Variable: font-lock-syntax-table
     This variable specifies the syntax table to use for fontification of comments and strings.

 -- Variable: font-lock-beginning-of-syntax-function
     If this variable is non-nil, it should be a function to move point back to a position that is syntactically at ``top level'' and outside of strings or comments.  Font Lock uses this when necessary to get the right results for syntactic fontification.

     This function is called with no arguments.  It should leave point at the beginning of any enclosing syntactic block.  Typical values are beginning-of-line (i.e., the start of the line is known to be outside a syntactic block), or beginning-of-defun for programming modes or backward-paragraph for textual modes (i.e., the mode-dependent function is known to move outside a syntactic block).

     If the value is nil, the beginning of the buffer is used as a position outside of a syntactic block.  This cannot be wrong, but it can be slow.

 -- Variable: font-lock-mark-block-function
     If this variable is non-nil, it should be a function that is called with no arguments, to choose an enclosing range of text for refontification for the command M-g M-g (font-lock-fontify-block).

     The function should report its choice by placing the region around it. A good choice is a range of text large enough to give proper results, but not too large so that refontification becomes slow.  Typical values are mark-defun for programming modes or mark-paragraph for textual modes.

Levels of Font Lock
-------------------

Many major modes offer three different levels of fontification.  You can define multiple levels by using a list of symbols for KEYWORDS in font-lock-defaults.  Each symbol specifies one level of fontification; it is up to the user to choose one of these levels.  The chosen level's symbol value is used to initialize font-lock-keywords.

Here are the conventions for how to define the levels of fontification:

  * Level 1: highlight function declarations, file directives (such as include or import directives), strings and comments.  The idea is speed, so only the most important and top-level components are fontified.

  * Level 2: in addition to level 1, highlight all language keywords, including type names that act like keywords, as well as named constant values.  The idea is that all keywords (either syntactic or semantic) should be fontified appropriately.

  * Level 3: in addition to level 2, highlight the symbols being defined in function and variable declarations, and all builtin function names, wherever they appear.

Faces for Font Lock
-------------------

You can make Font Lock mode use any face, but several faces are defined specifically for Font Lock mode.  Each of these symbols is both a face name, and a variable whose default value is the symbol itself. Thus, the default value of font-lock-comment-face is font-lock-comment-face.  This means you can write font-lock-comment-face in a context such as font-lock-keywords where a face-name-valued expression is used.

font-lock-comment-face
     Used (typically) for comments.

font-lock-string-face
     Used (typically) for string constants.

font-lock-keyword-face
     Used (typically) for keywords---names that have special syntactic significance, like for and if in C.

font-lock-builtin-face
     Used (typically) for built-in function names.

font-lock-function-name-face
     Used (typically) for the name of a function being defined or declared, in a function definition or declaration.

font-lock-variable-name-face
     Used (typically) for the name of a variable being defined or declared, in a variable definition or declaration.

font-lock-type-face
     Used (typically) for names of user-defined data types, where they are defined and where they are used.

font-lock-constant-face
     Used (typically) for constant names.

font-lock-warning-face
     Used (typically) for constructs that are peculiar, or that greatly change the meaning of other text.  For example, this is used for ;;;###autoload cookies in Emacs Lisp, and for #error directives in C.

Syntactic Font Lock
-------------------

Font Lock mode can be used to update syntax-table properties automatically.  This is useful in languages for which a single syntax table by itself is not sufficient.

 -- Variable: font-lock-syntactic-keywords
     This variable enables and controls syntactic Font Lock.  Its value should be a list of elements of this form:

          (MATCHER SUBEXP SYNTAX OVERRIDE LAXMATCH)

     The parts of this element have the same meanings as in the corresponding sort of element of font-lock-keywords,

          (MATCHER SUBEXP FACENAME OVERRIDE LAXMATCH)

     However, instead of specifying the value FACENAME to use for the face property, it specifies the value SYNTAX to use for the syntax-table property.  Here, SYNTAX can be a variable whose value is a syntax table, a syntax entry of the form (SYNTAX-CODE . MATCHING-CHAR), or an expression whose value is one of those two types.

Hooks
=====

A hook is a variable where you can store a function or functions to be called on a particular occasion by an existing program.  Emacs provides hooks for the sake of customization.  Most often, hooks are set up in the init file (see Init File), but Lisp programs can set them also. See Standard Hooks, for a list of standard hook variables.

Most of the hooks in Emacs are normal hooks.  These variables contain lists of functions to be called with no arguments.  When the hook name ends in -hook, that tells you it is normal.  We try to make all hooks normal, as much as possible, so that you can use them in a uniform way.

Every major mode function is supposed to run a normal hook called the mode hook as the last step of initialization.  This makes it easy for a user to customize the behavior of the mode, by overriding the buffer-local variable assignments already made by the mode.  But hooks are used in other contexts too.  For example, the hook suspend-hook runs just before Emacs suspends itself (see Suspending Emacs).

The recommended way to add a hook function to a normal hook is by calling add-hook (see below).  The hook functions may be any of the valid kinds of functions that funcall accepts (see What Is a Function).  Most normal hook variables are initially void; add-hook knows how to deal with this.

If the hook variable's name does not end with -hook, that indicates it is probably an abnormal hook.  Then you should look at its documentation to see how to use the hook properly.

If the variable's name ends in -functions or -hooks, then the value is a list of functions, but it is abnormal in that either these functions are called with arguments or their values are used in some way.  You can use add-hook to add a function to the list, but you must take care in writing the function.  (A few of these variables are actually normal hooks which were named before we established the convention of using -hook for them.)

If the variable's name ends in -function, then its value is just a single function, not a list of functions.

Here's an example that uses a mode hook to turn on Auto Fill mode when in Lisp Interaction mode:

     (add-hook 'lisp-interaction-mode-hook 'turn-on-auto-fill)

At the appropriate time, Emacs uses the run-hooks function to run particular hooks.  This function calls the hook functions that have been added with add-hook.

 -- Function: run-hooks &rest hookvars
     This function takes one or more hook variable names as arguments, and runs each hook in turn.  Each argument should be a symbol that is a hook variable.  These arguments are processed in the order specified.

     If a hook variable has a non-nil value, that value may be a function or a list of functions.  If the value is a function (either a lambda expression or a symbol with a function definition), it is called. If it is a list, the elements are called, in order.  The hook functions are called with no arguments.  Nowadays, storing a single function in the hook variable is semi-obsolete; you should always use a list of functions.

     For example, here's how emacs-lisp-mode runs its mode hook:

          (run-hooks 'emacs-lisp-mode-hook)

 -- Function: run-hook-with-args hook &rest args
     This function is the way to run an abnormal hook which passes arguments to the hook functions.  It calls each of the hook functions, passing each of them the arguments ARGS.

 -- Function: run-hook-with-args-until-failure hook &rest args
     This function is the way to run an abnormal hook which passes arguments to the hook functions, and stops as soon as any hook function fails.  It calls each of the hook functions, passing each of them the arguments ARGS, until some hook function returns nil.  Then it stops, and returns nil if some hook function returned nil. Otherwise it returns a non-nil value.

 -- Function: run-hook-with-args-until-success hook &rest args
     This function is the way to run an abnormal hook which passes arguments to the hook functions, and stops as soon as any hook function succeeds. It calls each of the hook functions, passing each of them the arguments ARGS, until some hook function returns non-nil.  Then it stops, and returns whatever was returned by the last hook function that was called.

 -- Function: add-hook hook function &optional append local
     This function is the handy way to add function FUNCTION to hook variable HOOK.  The argument FUNCTION may be any valid Lisp function with the proper number of arguments.  For example,

          (add-hook 'text-mode-hook 'my-text-hook-function)

     adds my-text-hook-function to the hook called text-mode-hook.

     You can use add-hook for abnormal hooks as well as for normal hooks.

     It is best to design your hook functions so that the order in which they are executed does not matter.  Any dependence on the order is ``asking for trouble.''  However, the order is predictable: normally, FUNCTION goes at the front of the hook list, so it will be executed first (barring another add-hook call).  If the optional argument APPEND is non-nil, the new hook function goes at the end of the hook list and will be executed last.

     If LOCAL is non-nil, that says to make the new hook function buffer-local in the current buffer.  Before you can do this, you must make the hook itself buffer-local by calling make-local-hook (not make-local-variable).  If the hook itself is not buffer-local, then the value of LOCAL makes no difference---the hook function is always global.

 -- Function: remove-hook hook function &optional local
     This function removes FUNCTION from the hook variable HOOK.

     If LOCAL is non-nil, that says to remove FUNCTION from the buffer-local hook list instead of from the global hook list. If the hook variable itself is not buffer-local, then the value of LOCAL makes no difference.

 -- Function: make-local-hook hook
     This function makes the hook variable hook buffer-local in the current buffer.  When a hook variable is buffer-local, it can have buffer-local and global hook functions, and run-hooks runs all of them.

     This function works by adding t as an element of the buffer-local value.  That serves as a flag to use the hook functions listed in the default value of the hook variable, as well as those listed in the buffer-local value. Since run-hooks understands this flag, make-local-hook works with all normal hooks.  It works for only some non-normal hooks---those whose callers have been updated to understand this meaning of t.

     Do not use make-local-variable directly for hook variables; it is not sufficient.