Keymaps
*******

The bindings between input events and commands are recorded in data structures called keymaps.  Each binding in a keymap associates (or binds) an individual event type, either to another keymap or to a command.  When an event type is bound to a keymap, that keymap is used to look up the next input event; this continues until a command is found.  The whole process is called key lookup.

Key Sequences
=============

A key sequence, or key for short, is a sequence of one or more input events that form a unit.  Input events include characters, function keys, and mouse actions (see Input Events). The Emacs Lisp representation for a key sequence is a string or vector.  Unless otherwise stated, any Emacs Lisp function that accepts a key sequence as an argument can handle both representations.

In the string representation, alphanumeric characters ordinarily stand for themselves; for example, "a" represents a and and "2" represents 2.  Control character events are prefixed by the substring "\C-", and meta characters by "\M-"; for example, "\C-x" represents the key C-x. In addition, the TAB, RET, ESC, and DEL events are represented by "\t", "\r", "\e", and "\d" respectively.  The string representation of a complete key sequence is the concatenation of the string representations of the constituent events; thus, "\C-xl" represents the key sequence C-x l.

Key sequences containing function keys, mouse button events, or non-ASCII characters such as C-= or H-a cannot be represented as strings; they have to be represented as vectors.

In the vector representation, each element of the vector represents an input event, in its Lisp form.  See Input Events.  For example, the vector [?\C-x ?l] represents the key sequence C-x l.

For examples of key sequences written in string and vector representations, Init Rebinding (The GNU Emacs Manual).

 -- Macro: kbd keyseq-text
     This macro converts the text KEYSEQ-TEXT (a string constant) into a key sequence (a string or vector constant).  The contents of KEYSEQ-TEXT should describe the key sequence using almost the same syntax used in this manual.  More precisely, it uses the same syntax that Edit Macro mode uses for editing keyboard macros (see Edit Keyboard Macro (The GNU Emacs Manual)); you must surround function key names with <...>.

          (kbd "C-x") => "\C-x"
          (kbd "C-x C-f") => "\C-x\C-f"
          (kbd "C-x 4 C-f") => "\C-x4\C-f"
          (kbd "X") => "X"
          (kbd "RET") => "\^M"
          (kbd "C-c SPC") => "\C-c "
          (kbd "<f1> SPC") => [f1 32]
          (kbd "C-M-<down>") => [C-M-down]

     This macro is not meant for use with arguments that vary---only with string constants.

Keymap Basics
=============

A keymap is a Lisp data structure that specifies key bindings for various key sequences.

A single keymap directly specifies definitions for individual events.  When a key sequence consists of a single event, its binding in a keymap is the keymap's definition for that event.  The binding of a longer key sequence is found by an iterative process: first find the definition of the first event (which must itself be a keymap); then find the second event's definition in that keymap, and so on until all the events in the key sequence have been processed.

If the binding of a key sequence is a keymap, we call the key sequence a prefix key.  Otherwise, we call it a complete key (because no more events can be added to it).  If the binding is nil, we call the key undefined.  Examples of prefix keys are C-c, C-x, and C-x 4.  Examples of defined complete keys are X, RET, and C-x 4 C-f.  Examples of undefined complete keys are C-x C-g, and C-c 3.  See Prefix Keys, for more details.

The rule for finding the binding of a key sequence assumes that the intermediate bindings (found for the events before the last) are all keymaps; if this is not so, the sequence of events does not form a unit---it is not really one key sequence.  In other words, removing one or more events from the end of any valid key sequence must always yield a prefix key.  For example, C-f C-n is not a key sequence; C-f is not a prefix key, so a longer sequence starting with C-f cannot be a key sequence.

The set of possible multi-event key sequences depends on the bindings for prefix keys; therefore, it can be different for different keymaps, and can change when bindings are changed.  However, a one-event sequence is always a key sequence, because it does not depend on any prefix keys for its well-formedness.

At any time, several primary keymaps are active---that is, in use for finding key bindings.  These are the global map, which is shared by all buffers; the local keymap, which is usually associated with a specific major mode; and zero or more minor mode keymaps, which belong to currently enabled minor modes.  (Not all minor modes have keymaps.)  The local keymap bindings shadow (i.e., take precedence over) the corresponding global bindings.  The minor mode keymaps shadow both local and global keymaps.  See Active Keymaps, for details.

Format of Keymaps
=================

Each keymap is a list whose CAR is the symbol keymap.  The remaining elements of the list define the key bindings of the keymap. A symbol whose function definition is a keymap is also a keymap.  Use the function keymapp (see below) to test whether an object is a keymap.

Several kinds of elements may appear in a keymap, after the symbol keymap that begins it:

(TYPE . BINDING)
     This specifies one binding, for events of type TYPE.  Each ordinary binding applies to events of a particular event type, which is always a character or a symbol.  See Classifying Events. In this kind of binding, BINDING is a command.

(TYPE ITEM-NAME . BINDING)
     This specifies a binding which is also a menu item named ITEM-NAME.  See Simple Menu Items.

(TYPE menu-item . DETAILS)
     This specifies a binding which is also a menu item and allows use of other features.  See Extended Menu Items.

(t . BINDING)
     This specifies a default key binding; any event not bound by other elements of the keymap is given BINDING as its binding.  Default bindings allow a keymap to bind all possible event types without having to enumerate all of them.  A keymap that has a default binding completely masks any lower-precedence keymap, except for events explicitly bound to nil (see below).

CHAR-TABLE
     If an element of a keymap is a char-table, it counts as holding bindings for all character events with no modifier bits (see modifier bits): element N is the binding for the character with code N.  This is a compact way to record lots of bindings.  A keymap with such a char-table is called a full keymap.  Other keymaps are called sparse keymaps.

STRING
     Aside from bindings, a keymap can also have a string as an element. This is called the overall prompt string and makes it possible to use the keymap as a menu.  See Defining Menus.

When the binding is nil, it doesn't constitute a definition but it does take precedence over a default binding or a binding in the parent keymap.  On the other hand, a binding of nil does not override lower-precedence keymaps; thus, if the local map gives a binding of nil, Emacs uses the binding from the global map.

Keymaps do not directly record bindings for the meta characters. Instead, meta characters are regarded for purposes of key lookup as sequences of two characters, the first of which is ESC (or whatever is currently the value of meta-prefix-char).  Thus, the key M-a is internally represented as ESC a, and its global binding is found at the slot for a in esc-map (see Prefix Keys).

This conversion applies only to characters, not to function keys or other input events; thus, M-end has nothing to do with ESC end.

Here as an example is the local keymap for Lisp mode, a sparse keymap.  It defines bindings for DEL and TAB, plus C-c C-l, M-C-q, and M-C-x.

     lisp-mode-map
     =>

     (keymap
      (3 keymap
         ;; C-c C-z
         (26 . run-lisp))

      (27 keymap
          ;; M-C-x, treated as ESC C-x
          (24 . lisp-send-defun)
          keymap
          ;; M-C-q, treated as ESC C-q
          (17 . indent-sexp)))

      ;; This part is inherited from lisp-mode-shared-map.
      keymap
      ;; DEL
      (127 . backward-delete-char-untabify)

      (27 keymap
          ;; M-C-q, treated as ESC C-q
          (17 . indent-sexp))
      (9 . lisp-indent-line))

 -- Function: keymapp object
     This function returns t if OBJECT is a keymap, nil otherwise.  More precisely, this function tests for a list whose CAR is keymap, or for a symbol whose function definition satisfies keymapp.

          (keymapp '(keymap))
              => t

          (fset 'foo '(keymap))
          (keymapp 'foo)
              => t

          (keymapp (current-global-map))
              => t

Creating Keymaps
================

Here we describe the functions for creating keymaps.

 -- Function: make-sparse-keymap &optional prompt
     This function creates and returns a new sparse keymap with no entries. (A sparse keymap is the kind of keymap you usually want.)  The new keymap does not contain a char-table, unlike make-keymap, and does not bind any events.

          (make-sparse-keymap)
              => (keymap)

     If you specify PROMPT, that becomes the overall prompt string for the keymap.  You should specify this only for menu keymaps (see Defining Menus).  A keymap with an overall prompt string will always present a mouse menu or a keyboard menu if it is active for looking up the next input event.  Don't specify an overall prompt string for the main map of a major or minor mode, because that would cause the command loop to present a keyboard menu every time.

 -- Function: make-keymap &optional prompt
     This function creates and returns a new full keymap.  That keymap contains a char-table (see Char-Tables) with slots for all characters without modifiers.  The new keymap initially binds all these characters to nil, and does not bind any other kind of event.  The argument PROMPT specifies a prompt string, as in make-sparse-keymap.

          (make-keymap)
              => (keymap #^[t nil nil nil ... nil nil keymap])

     A full keymap is more efficient than a sparse keymap when it holds lots of bindings; for just a few, the sparse keymap is better.

 -- Function: copy-keymap keymap
     This function returns a copy of KEYMAP.  Any keymaps that appear directly as bindings in KEYMAP are also copied recursively, and so on to any number of levels.  However, recursive copying does not take place when the definition of a character is a symbol whose function definition is a keymap; the same symbol appears in the new copy.

          (setq map (copy-keymap (current-local-map)))
          => (keymap

               ;; (This implements meta characters.)
               (27 keymap
                   (83 . center-paragraph)
                   (115 . center-line))
               (9 . tab-to-tab-stop))

          (eq map (current-local-map))
              => nil

          (equal map (current-local-map))
              => t

Inheritance and Keymaps
=======================

A keymap can inherit the bindings of another keymap, which we call the parent keymap.  Such a keymap looks like this:

     (keymap BINDINGS... . PARENT-KEYMAP)

The effect is that this keymap inherits all the bindings of PARENT-KEYMAP, whatever they may be at the time a key is looked up, but can add to them or override them with BINDINGS.

If you change the bindings in PARENT-KEYMAP using define-key or other key-binding functions, these changes are visible in the inheriting keymap unless shadowed by BINDINGS.  The converse is not true: if you use define-key to change the inheriting keymap, that affects BINDINGS, but has no effect on PARENT-KEYMAP.

The proper way to construct a keymap with a parent is to use set-keymap-parent; if you have code that directly constructs a keymap with a parent, please convert the program to use set-keymap-parent instead.

 -- Function: keymap-parent keymap
     This returns the parent keymap of KEYMAP.  If KEYMAP has no parent, keymap-parent returns nil.

 -- Function: set-keymap-parent keymap parent
     This sets the parent keymap of KEYMAP to PARENT, and returns PARENT.  If PARENT is nil, this function gives KEYMAP no parent at all.

     If KEYMAP has submaps (bindings for prefix keys), they too receive new parent keymaps that reflect what PARENT specifies for those prefix keys.

Here is an example showing how to make a keymap that inherits from text-mode-map:

     (let ((map (make-sparse-keymap)))
       (set-keymap-parent map text-mode-map)
       map)

A non-sparse keymap can have a parent too, but this is not very useful.  A non-sparse keymap always specifies something as the binding for every numeric character code without modifier bits, even if it is nil, so these character's bindings are never inherited from the parent keymap.

Prefix Keys
===========

A prefix key is a key sequence whose binding is a keymap.  The keymap defines what to do with key sequences that extend the prefix key. For example, C-x is a prefix key, and it uses a keymap that is also stored in the variable ctl-x-map.  This keymap defines bindings for key sequences starting with C-x.

Some of the standard Emacs prefix keys use keymaps that are also found in Lisp variables:

  * esc-map is the global keymap for the ESC prefix key.  Thus, the global definitions of all meta characters are actually found here. This map is also the function definition of ESC-prefix.

  * help-map is the global keymap for the C-h prefix key.

  * mode-specific-map is the global keymap for the prefix key C-c.  This map is actually global, not mode-specific, but its name provides useful information about C-c in the output of C-h b (display-bindings), since the main use of this prefix key is for mode-specific bindings.

  * ctl-x-map is the global keymap used for the C-x prefix key. This map is found via the function cell of the symbol Control-X-prefix.

  * mule-keymap is the global keymap used for the C-x RET prefix key.

  * ctl-x-4-map is the global keymap used for the C-x 4 prefix key.

  * ctl-x-5-map is the global keymap used for the C-x 5 prefix key.

  * 2C-mode-map is the global keymap used for the C-x 6 prefix key.

  * vc-prefix-map is the global keymap used for the C-x v prefix key.

  * facemenu-keymap is the global keymap used for the M-o prefix key.

  * The other Emacs prefix keys are M-g, C-x @, C-x a i, C-x ESC and ESC ESC.  They use keymaps that have no special names.

The keymap binding of a prefix key is used for looking up the event that follows the prefix key.  (It may instead be a symbol whose function definition is a keymap.  The effect is the same, but the symbol serves as a name for the prefix key.)  Thus, the binding of C-x is the symbol Control-X-prefix, whose function cell holds the keymap for C-x commands.  (The same keymap is also the value of ctl-x-map.)

Prefix key definitions can appear in any active keymap.  The definitions of C-c, C-x, C-h and ESC as prefix keys appear in the global map, so these prefix keys are always available.  Major and minor modes can redefine a key as a prefix by putting a prefix key definition for it in the local map or the minor mode's map.  See Active Keymaps.

If a key is defined as a prefix in more than one active map, then its various definitions are in effect merged: the commands defined in the minor mode keymaps come first, followed by those in the local map's prefix definition, and then by those from the global map.

In the following example, we make C-p a prefix key in the local keymap, in such a way that C-p is identical to C-x.  Then the binding for C-p C-f is the function find-file, just like C-x C-f.  The key sequence C-p 6 is not found in any active keymap.

     (use-local-map (make-sparse-keymap))
         => nil

     (local-set-key "\C-p" ctl-x-map)
         => nil

     (key-binding "\C-p\C-f")
         => find-file

     (key-binding "\C-p6")
         => nil

 -- Function: define-prefix-command symbol &optional mapvar prompt
     This function prepares SYMBOL for use as a prefix key's binding: it creates a sparse keymap and stores it as SYMBOL's function definition.  Subsequently binding a key sequence to SYMBOL will make that key sequence into a prefix key.  The return value is symbol.

     This function also sets SYMBOL as a variable, with the keymap as its value.  But if MAPVAR is non-nil, it sets MAPVAR as a variable instead.

     If PROMPT is non-nil, that becomes the overall prompt string for the keymap.  The prompt string should be given for menu keymaps (see Defining Menus).

Active Keymaps
==============

Emacs normally contains many keymaps; at any given time, just a few of them are active, meaning that they participate in the interpretation of user input.  All the active keymaps are used together to determine what command to execute when a key is entered.

Normally the active keymaps are the keymap property keymap, the keymaps of any enabled minor modes, the current buffer's local keymap, and the global keymap, in that order.  Emacs searches for each input key sequence in all these keymaps.  See Searching Keymaps, for more details of this procedure.

When the key sequence starts with a mouse event (optionally preceded by a symbolic prefix), the active keymaps are determined based on the position in that event.  If the event happened on a string embedded with a display, before-string, or after-string property (see Special Properties), the non-nil map properties of the string override those of the buffer.

The global keymap holds the bindings of keys that are defined regardless of the current buffer, such as C-f.  The variable global-map holds this keymap, which is always active.

Each buffer may have another keymap, its local keymap, which may contain new or overriding definitions for keys.  The current buffer's local keymap is always active except when overriding-local-map overrides it.  The local-map text or overlay property can specify an alternative local keymap for certain parts of the buffer; see Special Properties.

Each minor mode can have a keymap; if it does, the keymap is active when the minor mode is enabled.  Modes for emulation can specify additional active keymaps through the variable emulation-mode-map-alists.

The highest precedence normal keymap comes from the keymap text or overlay property.  If that is non-nil, it is the first keymap to be processed, in normal circumstances.

However, there are also special ways for programs to substitute other keymaps for some of those.  The variable overriding-local-map, if non-nil, specifies a keymap that replaces all the usual active keymaps except the global keymap. Another way to do this is with overriding-terminal-local-map; it operates on a per-terminal basis.  These variables are documented below.

Since every buffer that uses the same major mode normally uses the same local keymap, you can think of the keymap as local to the mode.  A change to the local keymap of a buffer (using local-set-key, for example) is seen also in the other buffers that share that keymap.

The local keymaps that are used for Lisp mode and some other major modes exist even if they have not yet been used.  These local keymaps are the values of variables such as lisp-mode-map.  For most major modes, which are less frequently used, the local keymap is constructed only when the mode is used for the first time in a session.

The minibuffer has local keymaps, too; they contain various completion and exit commands.  See Intro to Minibuffers.

Emacs has other keymaps that are used in a different way---translating events within read-key-sequence.  See Translation Keymaps.

See Standard Keymaps, for a list of standard keymaps.

 -- Function: current-active-maps &optional olp
     This returns the list of active keymaps that would be used by the command loop in the current circumstances to look up a key sequence. Normally it ignores overriding-local-map and overriding-terminal-local-map, but if OLP is non-nil then it pays attention to them.

 -- Function: key-binding key &optional accept-defaults no-remap position
     This function returns the binding for KEY according to the current active keymaps.  The result is nil if KEY is undefined in the keymaps.

     The argument ACCEPT-DEFAULTS controls checking for default bindings, as in lookup-key (above).

     When commands are remapped (see Remapping Commands), key-binding normally processes command remappings so as to returns the remapped command that will actually be executed.  However, if NO-REMAP is non-nil, key-binding ignores remappings and returns the binding directly specified for KEY.

     If KEY starts with a mouse event (perhaps following a prefix event), the maps to be consulted are determined based on the event's position.  Otherwise, they are determined based on the value of point. However, you can override either of them by specifying POSITION. If POSITION is non-nil, it should be either a buffer position or an event position like the value of event-start. Then the maps consulted are determined based on POSITION.

     An error is signaled if KEY is not a string or a vector.

          (key-binding "\C-x\C-f")
              => find-file

Searching the Active Keymaps
============================

After translation of event subsequences (see Translation Keymaps) Emacs looks for them in the active keymaps.  Here is a pseudo-Lisp description of the order and conditions for searching them:

     (or (if overriding-terminal-local-map
             (FIND-IN overriding-terminal-local-map)
           (if overriding-local-map
               (FIND-IN overriding-local-map)
             (or (FIND-IN (get-char-property (point) 'keymap))
                 (FIND-IN-ANY emulation-mode-map-alists)
                 (FIND-IN-ANY minor-mode-overriding-map-alist)
                 (FIND-IN-ANY minor-mode-map-alist)
                 (if (get-text-property (point) 'local-map)
                     (FIND-IN (get-char-property (point) 'local-map))
                   (FIND-IN (current-local-map))))))
         (FIND-IN (current-global-map)))

The FIND-IN and FIND-IN-ANY are pseudo functions that search in one keymap and in an alist of keymaps, respectively. (Searching a single keymap for a binding is called key lookup; see Key Lookup.)  If the key sequence starts with a mouse event, or a symbolic prefix event followed by a mouse event, that event's position is used instead of point and the current buffer.  Mouse events on an embedded string use non-nil text properties from that string instead of the buffer.

 1. The function finally found may be remapped (see Remapping Commands).

 2. Characters that are bound to self-insert-command are translated according to translation-table-for-input before insertion.

 3. current-active-maps returns a list of the currently active keymaps at point.

 4. When a match is found (see Key Lookup), if the binding in the keymap is a function, the search is over.  However if the keymap entry is a symbol with a value or a string, Emacs replaces the input key sequences with the variable's value or the string, and restarts the search of the active keymaps.

Controlling the Active Keymaps
==============================

 -- Variable: global-map
     This variable contains the default global keymap that maps Emacs keyboard input to commands.  The global keymap is normally this keymap.  The default global keymap is a full keymap that binds self-insert-command to all of the printing characters.

     It is normal practice to change the bindings in the global keymap, but you should not assign this variable any value other than the keymap it starts out with.

 -- Function: current-global-map
     This function returns the current global keymap.  This is the same as the value of global-map unless you change one or the other.

          (current-global-map)
          => (keymap [set-mark-command beginning-of-line ...
                      delete-backward-char])

 -- Function: current-local-map
     This function returns the current buffer's local keymap, or nil if it has none.  In the following example, the keymap for the *scratch* buffer (using Lisp Interaction mode) is a sparse keymap in which the entry for ESC, ASCII code 27, is another sparse keymap.

          (current-local-map)
          => (keymap
              (10 . eval-print-last-sexp)
              (9 . lisp-indent-line)
              (127 . backward-delete-char-untabify)

              (27 keymap
                  (24 . eval-defun)
                  (17 . indent-sexp)))

 -- Function: current-minor-mode-maps
     This function returns a list of the keymaps of currently enabled minor modes.

 -- Function: use-global-map keymap
     This function makes KEYMAP the new current global keymap.  It returns nil.

     It is very unusual to change the global keymap.

 -- Function: use-local-map keymap
     This function makes KEYMAP the new local keymap of the current buffer.  If KEYMAP is nil, then the buffer has no local keymap.  use-local-map returns nil.  Most major mode commands use this function.

 -- Variable: minor-mode-map-alist
     This variable is an alist describing keymaps that may or may not be active according to the values of certain variables.  Its elements look like this:

          (VARIABLE . KEYMAP)

     The keymap KEYMAP is active whenever VARIABLE has a non-nil value.  Typically VARIABLE is the variable that enables or disables a minor mode.  See Keymaps and Minor Modes.

     Note that elements of minor-mode-map-alist do not have the same structure as elements of minor-mode-alist.  The map must be the CDR of the element; a list with the map as the second element will not do.  The CDR can be either a keymap (a list) or a symbol whose function definition is a keymap.

     When more than one minor mode keymap is active, the earlier one in minor-mode-map-alist takes priority.  But you should design minor modes so that they don't interfere with each other.  If you do this properly, the order will not matter.

     See Keymaps and Minor Modes, for more information about minor modes.  See also minor-mode-key-binding (see Functions for Key Lookup).

 -- Variable: minor-mode-overriding-map-alist
     This variable allows major modes to override the key bindings for particular minor modes.  The elements of this alist look like the elements of minor-mode-map-alist: (VARIABLE . KEYMAP).

     If a variable appears as an element of minor-mode-overriding-map-alist, the map specified by that element totally replaces any map specified for the same variable in minor-mode-map-alist.

     minor-mode-overriding-map-alist is automatically buffer-local in all buffers.

 -- Variable: overriding-local-map
     If non-nil, this variable holds a keymap to use instead of the buffer's local keymap, any text property or overlay keymaps, and any minor mode keymaps.  This keymap, if specified, overrides all other maps that would have been active, except for the current global map.

 -- Variable: overriding-terminal-local-map
     If non-nil, this variable holds a keymap to use instead of overriding-local-map, the buffer's local keymap, text property or overlay keymaps, and all the minor mode keymaps.

     This variable is always local to the current terminal and cannot be buffer-local.  See Multiple Displays.  It is used to implement incremental search mode.

 -- Variable: overriding-local-map-menu-flag
     If this variable is non-nil, the value of overriding-local-map or overriding-terminal-local-map can affect the display of the menu bar.  The default value is nil, so those map variables have no effect on the menu bar.

     Note that these two map variables do affect the execution of key sequences entered using the menu bar, even if they do not affect the menu bar display.  So if a menu bar key sequence comes in, you should clear the variables before looking up and executing that key sequence. Modes that use the variables would typically do this anyway; normally they respond to events that they do not handle by ``unreading'' them and exiting.

 -- Variable: special-event-map
     This variable holds a keymap for special events.  If an event type has a binding in this keymap, then it is special, and the binding for the event is run directly by read-event.  See Special Events.

 -- Variable: emulation-mode-map-alists
     This variable holds a list of keymap alists to use for emulations modes.  It is intended for modes or packages using multiple minor-mode keymaps.  Each element is a keymap alist which has the same format and meaning as minor-mode-map-alist, or a symbol with a variable binding which is such an alist.  The ``active'' keymaps in each alist are used before minor-mode-map-alist and minor-mode-overriding-map-alist.

Key Lookup
==========

Key lookup is the process of finding the binding of a key sequence from a given keymap.  The execution or use of the binding is not part of key lookup.

Key lookup uses just the event type of each event in the key sequence; the rest of the event is ignored.  In fact, a key sequence used for key lookup may designate a mouse event with just its types (a symbol) instead of the entire event (a list).  See Input Events.  Such a ``key sequence'' is insufficient for command-execute to run, but it is sufficient for looking up or rebinding a key.

When the key sequence consists of multiple events, key lookup processes the events sequentially: the binding of the first event is found, and must be a keymap; then the second event's binding is found in that keymap, and so on until all the events in the key sequence are used up.  (The binding thus found for the last event may or may not be a keymap.)  Thus, the process of key lookup is defined in terms of a simpler process for looking up a single event in a keymap.  How that is done depends on the type of object associated with the event in that keymap.

Let's use the term keymap entry to describe the value found by looking up an event type in a keymap.  (This doesn't include the item string and other extra elements in menu key bindings, because lookup-key and other key lookup functions don't include them in the returned value.)  While any Lisp object may be stored in a keymap as a keymap entry, not all make sense for key lookup.  Here is a table of the meaningful kinds of keymap entries:

nil
     nil means that the events used so far in the lookup form an undefined key.  When a keymap fails to mention an event type at all, and has no default binding, that is equivalent to a binding of nil for that event type.

COMMAND
     The events used so far in the lookup form a complete key, and COMMAND is its binding.  See What Is a Function.

ARRAY
     The array (either a string or a vector) is a keyboard macro.  The events used so far in the lookup form a complete key, and the array is its binding.  See Keyboard Macros, for more information.

KEYMAP
     The events used so far in the lookup form a prefix key.  The next event of the key sequence is looked up in KEYMAP.

LIST
     The meaning of a list depends on the types of the elements of the list.

       * If the CAR of LIST is the symbol keymap, then the list is a keymap, and is treated as a keymap (see above).

       * If the CAR of LIST is lambda, then the list is a lambda expression.  This is presumed to be a function, and is treated as such (see above).  In order to execute properly as a key binding, this function must be a command---it must have an interactive specification.  See Defining Commands.

       * If the CAR of LIST is a keymap and the CDR is an event type, then this is an indirect entry:

               (OTHERMAP . OTHERTYPE)

          When key lookup encounters an indirect entry, it looks up instead the binding of OTHERTYPE in OTHERMAP and uses that.

          This feature permits you to define one key as an alias for another key. For example, an entry whose CAR is the keymap called esc-map and whose CDR is 32 (the code for SPC) means, ``Use the global binding of Meta-SPC, whatever that may be.''

SYMBOL
     The function definition of SYMBOL is used in place of SYMBOL.  If that too is a symbol, then this process is repeated, any number of times.  Ultimately this should lead to an object that is a keymap, a command, or a keyboard macro.  A list is allowed if it is a keymap or a command, but indirect entries are not understood when found via symbols.

     Note that keymaps and keyboard macros (strings and vectors) are not valid functions, so a symbol with a keymap, string, or vector as its function definition is invalid as a function.  It is, however, valid as a key binding.  If the definition is a keyboard macro, then the symbol is also valid as an argument to command-execute (see Interactive Call).

     The symbol undefined is worth special mention: it means to treat the key as undefined.  Strictly speaking, the key is defined, and its binding is the command undefined; but that command does the same thing that is done automatically for an undefined key: it rings the bell (by calling ding) but does not signal an error.

     undefined is used in local keymaps to override a global key binding and make the key ``undefined'' locally.  A local binding of nil would fail to do this because it would not override the global binding.

ANYTHING ELSE
     If any other type of object is found, the events used so far in the lookup form a complete key, and the object is its binding, but the binding is not executable as a command.

In short, a keymap entry may be a keymap, a command, a keyboard macro, a symbol that leads to one of them, or an indirection or nil. Here is an example of a sparse keymap with two characters bound to commands and one bound to another keymap.  This map is the normal value of emacs-lisp-mode-map.  Note that 9 is the code for TAB, 127 for DEL, 27 for ESC, 17 for C-q and 24 for C-x.

     (keymap (9 . lisp-indent-line)
             (127 . backward-delete-char-untabify)
             (27 keymap (17 . indent-sexp) (24 . eval-defun)))

Functions for Key Lookup
========================

Here are the functions and variables pertaining to key lookup.

 -- Function: lookup-key keymap key &optional accept-defaults
     This function returns the definition of KEY in KEYMAP.  All the other functions described in this chapter that look up keys use lookup-key.  Here are examples:

          (lookup-key (current-global-map) "\C-x\C-f")
              => find-file

          (lookup-key (current-global-map) (kbd "C-x C-f"))
              => find-file

          (lookup-key (current-global-map) "\C-x\C-f12345")
              => 2

     If the string or vector KEY is not a valid key sequence according to the prefix keys specified in KEYMAP, it must be ``too long'' and have extra events at the end that do not fit into a single key sequence.  Then the value is a number, the number of events at the front of KEY that compose a complete key.

     If ACCEPT-DEFAULTS is non-nil, then lookup-key considers default bindings as well as bindings for the specific events in KEY.  Otherwise, lookup-key reports only bindings for the specific sequence KEY, ignoring default bindings except when you explicitly ask about them.  (To do this, supply t as an element of KEY; see Format of Keymaps.)

     If KEY contains a meta character (not a function key), that character is implicitly replaced by a two-character sequence: the value of meta-prefix-char, followed by the corresponding non-meta character.  Thus, the first example below is handled by conversion into the second example.

          (lookup-key (current-global-map) "\M-f")
              => forward-word

          (lookup-key (current-global-map) "\ef")
              => forward-word

     Unlike read-key-sequence, this function does not modify the specified events in ways that discard information (see Key Sequence Input).  In particular, it does not convert letters to lower case and it does not change drag events to clicks.

 -- Command: undefined
     Used in keymaps to undefine keys.  It calls ding, but does not cause an error.

 -- Function: local-key-binding key &optional accept-defaults
     This function returns the binding for KEY in the current local keymap, or nil if it is undefined there.

     The argument ACCEPT-DEFAULTS controls checking for default bindings, as in lookup-key (above).

 -- Function: global-key-binding key &optional accept-defaults
     This function returns the binding for command KEY in the current global keymap, or nil if it is undefined there.

     The argument ACCEPT-DEFAULTS controls checking for default bindings, as in lookup-key (above).

 -- Function: minor-mode-key-binding key &optional accept-defaults
     This function returns a list of all the active minor mode bindings of KEY.  More precisely, it returns an alist of pairs (MODENAME . BINDING), where MODENAME is the variable that enables the minor mode, and BINDING is KEY's binding in that mode.  If KEY has no minor-mode bindings, the value is nil.

     If the first binding found is not a prefix definition (a keymap or a symbol defined as a keymap), all subsequent bindings from other minor modes are omitted, since they would be completely shadowed.  Similarly, the list omits non-prefix bindings that follow prefix bindings.

     The argument ACCEPT-DEFAULTS controls checking for default bindings, as in lookup-key (above).

 -- Variable: meta-prefix-char
     This variable is the meta-prefix character code.  It is used for translating a meta character to a two-character sequence so it can be looked up in a keymap.  For useful results, the value should be a prefix event (see Prefix Keys).  The default value is 27, which is the ASCII code for ESC.

     As long as the value of meta-prefix-char remains 27, key lookup translates M-b into ESC b, which is normally defined as the backward-word command.  However, if you were to set meta-prefix-char to 24, the code for C-x, then Emacs will translate M-b into C-x b, whose standard binding is the switch-to-buffer command.  (Don't actually do this!)  Here is an illustration of what would happen:

          meta-prefix-char                    ; The default value.
               => 27

          (key-binding "\M-b")
               => backward-word

          ?\C-x                               ; The print representation
               => 24                          ;   of a character.

          (setq meta-prefix-char 24)
               => 24

          (key-binding "\M-b")
               => switch-to-buffer            ; Now, typing M-b is
                                              ;   like typing C-x b.

          (setq meta-prefix-char 27)          ; Avoid confusion!
               => 27                          ; Restore the default value!

     This translation of one event into two happens only for characters, not for other kinds of input events.  Thus, M-F1, a function key, is not converted into ESC F1.

Changing Key Bindings
=====================

The way to rebind a key is to change its entry in a keymap.  If you change a binding in the global keymap, the change is effective in all buffers (though it has no direct effect in buffers that shadow the global binding with a local one).  If you change the current buffer's local map, that usually affects all buffers using the same major mode. The global-set-key and local-set-key functions are convenient interfaces for these operations (see Key Binding Commands).  You can also use define-key, a more general function; then you must specify explicitly the map to change.

When choosing the key sequences for Lisp programs to rebind, please follow the Emacs conventions for use of various keys (see Key Binding Conventions).

In writing the key sequence to rebind, it is good to use the special escape sequences for control and meta characters (see String Type). The syntax \C- means that the following character is a control character and \M- means that the following character is a meta character.  Thus, the string "\M-x" is read as containing a single M-x, "\C-f" is read as containing a single C-f, and "\M-\C-x" and "\C-\M-x" are both read as containing a single C-M-x.  You can also use this escape syntax in vectors, as well as others that aren't allowed in strings; one example is [?\C-\H-x home].  See Character Type.

The key definition and lookup functions accept an alternate syntax for event types in a key sequence that is a vector: you can use a list containing modifier names plus one base event (a character or function key name).  For example, (control ?a) is equivalent to ?\C-a and (hyper control left) is equivalent to C-H-left.  One advantage of such lists is that the precise numeric codes for the modifier bits don't appear in compiled files.

The functions below signal an error if KEYMAP is not a keymap, or if KEY is not a string or vector representing a key sequence. You can use event types (symbols) as shorthand for events that are lists.  The kbd macro (see Key Sequences) is a convenient way to specify the key sequence.

 -- Function: define-key keymap key binding
     This function sets the binding for KEY in KEYMAP.  (If KEY is more than one event long, the change is actually made in another keymap reached from KEYMAP.)  The argument BINDING can be any Lisp object, but only certain types are meaningful.  (For a list of meaningful types, see Key Lookup.) The value returned by define-key is BINDING.

     If KEY is [t], this sets the default binding in KEYMAP.  When an event has no binding of its own, the Emacs command loop uses the keymap's default binding, if there is one.

     Every prefix of KEY must be a prefix key (i.e., bound to a keymap) or undefined; otherwise an error is signaled.  If some prefix of KEY is undefined, then define-key defines it as a prefix key so that the rest of KEY can be defined as specified.

     If there was previously no binding for KEY in KEYMAP, the new binding is added at the beginning of KEYMAP.  The order of bindings in a keymap makes no difference for keyboard input, but it does matter for menu keymaps (see Menu Keymaps).

Here is an example that creates a sparse keymap and makes a number of bindings in it:

     (setq map (make-sparse-keymap))
         => (keymap)

     (define-key map "\C-f" 'forward-char)
         => forward-char

     map
         => (keymap (6 . forward-char))

     ;; Build sparse submap for C-x and bind f in that.
     (define-key map (kbd "C-x f") 'forward-word)
         => forward-word

     map
     => (keymap
         (24 keymap                ; C-x
             (102 . forward-word)) ;      f
         (6 . forward-char))       ; C-f

     ;; Bind C-p to the ctl-x-map.
     (define-key map (kbd "C-p") ctl-x-map)
     ;; ctl-x-map
     => [nil ... find-file ... backward-kill-sentence]

     ;; Bind C-f to foo in the ctl-x-map.
     (define-key map (kbd "C-p C-f") 'foo)
     => 'foo

     map
     => (keymap     ; Note foo in ctl-x-map.
         (16 keymap [nil ... foo ... backward-kill-sentence])
         (24 keymap
             (102 . forward-word))
         (6 . forward-char))

Note that storing a new binding for C-p C-f actually works by changing an entry in ctl-x-map, and this has the effect of changing the bindings of both C-p C-f and C-x C-f in the default global map.

The function substitute-key-definition scans a keymap for keys that have a certain binding and rebinds them with a different binding.  Another feature which is cleaner and can often produce the same results to remap one command into another (see Remapping Commands).

 -- Function: substitute-key-definition olddef newdef keymap &optional oldmap
     This function replaces OLDDEF with NEWDEF for any keys in KEYMAP that were bound to OLDDEF.  In other words, OLDDEF is replaced with NEWDEF wherever it appears.  The function returns nil.

     For example, this redefines C-x C-f, if you do it in an Emacs with standard bindings:

          (substitute-key-definition
           'find-file 'find-file-read-only (current-global-map))

     If OLDMAP is non-nil, that changes the behavior of substitute-key-definition: the bindings in OLDMAP determine which keys to rebind.  The rebindings still happen in KEYMAP, not in OLDMAP.  Thus, you can change one map under the control of the bindings in another.  For example,

          (substitute-key-definition
            'delete-backward-char 'my-funny-delete
            my-map global-map)

     puts the special deletion command in my-map for whichever keys are globally bound to the standard deletion command.

     Here is an example showing a keymap before and after substitution:

          (setq map '(keymap
                      (?1 . olddef-1)
                      (?2 . olddef-2)
                      (?3 . olddef-1)))
          => (keymap (49 . olddef-1) (50 . olddef-2) (51 . olddef-1))

          (substitute-key-definition 'olddef-1 'newdef map)
          => nil

          map
          => (keymap (49 . newdef) (50 . olddef-2) (51 . newdef))

 -- Function: suppress-keymap keymap &optional nodigits
     This function changes the contents of the full keymap KEYMAP by remapping self-insert-command to the command undefined (see Remapping Commands).  This has the effect of undefining all printing characters, thus making ordinary insertion of text impossible. suppress-keymap returns nil.

     If NODIGITS is nil, then suppress-keymap defines digits to run digit-argument, and - to run negative-argument.  Otherwise it makes them undefined like the rest of the printing characters.

     The suppress-keymap function does not make it impossible to modify a buffer, as it does not suppress commands such as yank and quoted-insert.  To prevent any modification of a buffer, make it read-only (see Read Only Buffers).

     Since this function modifies KEYMAP, you would normally use it on a newly created keymap.  Operating on an existing keymap that is used for some other purpose is likely to cause trouble; for example, suppressing global-map would make it impossible to use most of Emacs.

     Most often, suppress-keymap is used to initialize local keymaps of modes such as Rmail and Dired where insertion of text is not desirable and the buffer is read-only.  Here is an example taken from the file emacs/lisp/dired.el, showing how the local keymap for Dired mode is set up:

          (setq dired-mode-map (make-keymap))
          (suppress-keymap dired-mode-map)
          (define-key dired-mode-map "r" 'dired-rename-file)
          (define-key dired-mode-map "\C-d" 'dired-flag-file-deleted)
          (define-key dired-mode-map "d" 'dired-flag-file-deleted)
          (define-key dired-mode-map "v" 'dired-view-file)
          (define-key dired-mode-map "e" 'dired-find-file)
          (define-key dired-mode-map "f" 'dired-find-file)
          ...

Remapping Commands
==================

A special kind of key binding, using a special ``key sequence'' which includes a command name, has the effect of remapping that command into another.  Here's how it works.  You make a key binding for a key sequence that starts with the dummy event remap, followed by the command name you want to remap.  Specify the remapped definition as the definition in this binding.  The remapped definition is usually a command name, but it can be any valid definition for a key binding.

Here's an example.  Suppose that My mode uses special commands my-kill-line and my-kill-word, which should be invoked instead of kill-line and kill-word.  It can establish this by making these two command-remapping bindings in its keymap:

     (define-key my-mode-map [remap kill-line] 'my-kill-line)
     (define-key my-mode-map [remap kill-word] 'my-kill-word)

Whenever my-mode-map is an active keymap, if the user types C-k, Emacs will find the standard global binding of kill-line (assuming nobody has changed it).  But my-mode-map remaps kill-line to my-kill-line, so instead of running kill-line, Emacs runs my-kill-line.

Remapping only works through a single level.  In other words,

     (define-key my-mode-map [remap kill-line] 'my-kill-line)
     (define-key my-mode-map [remap my-kill-line] 'my-other-kill-line)

does not have the effect of remapping kill-line into my-other-kill-line.  If an ordinary key binding specifies kill-line, this keymap will remap it to my-kill-line; if an ordinary binding specifies my-kill-line, this keymap will remap it to my-other-kill-line.

 -- Function: command-remapping command &optional position
     This function returns the remapping for COMMAND (a symbol), given the current active keymaps.  If COMMAND is not remapped (which is the usual situation), or not a symbol, the function returns nil.  position can optionally specify a buffer position or an event position to determine the keymaps to use, as in key-binding.

Keymaps for Translating Sequences of Events
===========================================

This section describes keymaps that are used during reading a key sequence, to translate certain event sequences into others. read-key-sequence checks every subsequence of the key sequence being read, as it is read, against function-key-map and then against key-translation-map.

 -- Variable: function-key-map
     This variable holds a keymap that describes the character sequences sent by function keys on an ordinary character terminal.  This keymap has the same structure as other keymaps, but is used differently: it specifies translations to make while reading key sequences, rather than bindings for key sequences.

     If function-key-map ``binds'' a key sequence K to a vector V, then when K appears as a subsequence anywhere in a key sequence, it is replaced with the events in V.

     For example, VT100 terminals send ESC O P when the keypad PF1 key is pressed.  Therefore, we want Emacs to translate that sequence of events into the single event pf1.  We accomplish this by ``binding'' ESC O P to [pf1] in function-key-map, when using a VT100.

     Thus, typing C-c PF1 sends the character sequence C-c ESC O P; later the function read-key-sequence translates this back into C-c PF1, which it returns as the vector [?\C-c pf1].

     Entries in function-key-map are ignored if they conflict with bindings made in the minor mode, local, or global keymaps.  The intent is that the character sequences that function keys send should not have command bindings in their own right---but if they do, the ordinary bindings take priority.

     The value of function-key-map is usually set up automatically according to the terminal's Terminfo or Termcap entry, but sometimes those need help from terminal-specific Lisp files.  Emacs comes with terminal-specific files for many common terminals; their main purpose is to make entries in function-key-map beyond those that can be deduced from Termcap and Terminfo.  See Terminal-Specific.

 -- Variable: key-translation-map
     This variable is another keymap used just like function-key-map to translate input events into other events.  It differs from function-key-map in two ways:

       * key-translation-map goes to work after function-key-map is finished; it receives the results of translation by function-key-map.

       * Non-prefix bindings in key-translation-map override actual key bindings.  For example, if C-x f has a non-prefix binding in key-translation-map, that translation takes effect even though C-x f also has a key binding in the global map.

     Note however that actual key bindings can have an effect on key-translation-map, even though they are overridden by it. Indeed, actual key bindings override function-key-map and thus may alter the key sequence that key-translation-map receives. Clearly, it is better to avoid this type of situation.

     The intent of key-translation-map is for users to map one character set to another, including ordinary characters normally bound to self-insert-command.

You can use function-key-map or key-translation-map for more than simple aliases, by using a function, instead of a key sequence, as the ``translation'' of a key.  Then this function is called to compute the translation of that key.

The key translation function receives one argument, which is the prompt that was specified in read-key-sequence---or nil if the key sequence is being read by the editor command loop.  In most cases you can ignore the prompt value.

If the function reads input itself, it can have the effect of altering the event that follows.  For example, here's how to define C-c h to turn the character that follows into a Hyper character:

     (defun hyperify (prompt)
       (let ((e (read-event)))
         (vector (if (numberp e)
                     (logior (lsh 1 24) e)
                   (if (memq 'hyper (event-modifiers e))
                       e
                     (add-event-modifier "H-" e))))))

     (defun add-event-modifier (string e)
       (let ((symbol (if (symbolp e) e (car e))))
         (setq symbol (intern (concat string
                                      (symbol-name symbol))))

         (if (symbolp e)
             symbol
           (cons symbol (cdr e)))))

     (define-key function-key-map "\C-ch" 'hyperify)

If you have enabled keyboard character set decoding using set-keyboard-coding-system, decoding is done after the translations listed above.  See Terminal I/O Encoding.  However, in future Emacs versions, character set decoding may be done at an earlier stage.

Commands for Binding Keys
=========================

This section describes some convenient interactive interfaces for changing key bindings.  They work by calling define-key.

People often use global-set-key in their init files (see Init File) for simple customization.  For example,

     (global-set-key (kbd "C-x C-\\") 'next-line)

or

     (global-set-key [?\C-x ?\C-\\] 'next-line)

or

     (global-set-key [(control ?x) (control ?\\)] 'next-line)

redefines C-x C-\ to move down a line.

     (global-set-key [M-mouse-1] 'mouse-set-point)

redefines the first (leftmost) mouse button, entered with the Meta key, to set point where you click.

Be careful when using non-ASCII text characters in Lisp specifications of keys to bind.  If these are read as multibyte text, as they usually will be in a Lisp file (see Loading Non-ASCII), you must type the keys as multibyte too.  For instance, if you use this:

     (global-set-key "ö" 'my-function) ; bind o-umlaut

or

     (global-set-key ?ö 'my-function) ; bind o-umlaut

and your language environment is multibyte Latin-1, these commands actually bind the multibyte character with code 2294, not the unibyte Latin-1 character with code 246 (M-v).  In order to use this binding, you need to enter the multibyte Latin-1 character as keyboard input.  One way to do this is by using an appropriate input method (see Input Methods (The GNU Emacs Manual)).

If you want to use a unibyte character in the key binding, you can construct the key sequence string using multibyte-char-to-unibyte or string-make-unibyte (see Converting Representations).

 -- Command: global-set-key key binding
     This function sets the binding of KEY in the current global map to BINDING.

          (global-set-key KEY BINDING)
          ==
          (define-key (current-global-map) KEY BINDING)

 -- Command: global-unset-key key
     This function removes the binding of KEY from the current global map.

     One use of this function is in preparation for defining a longer key that uses KEY as a prefix---which would not be allowed if KEY has a non-prefix binding.  For example:

          (global-unset-key "\C-l")
              => nil

          (global-set-key "\C-l\C-l" 'redraw-display)
              => nil

     This function is implemented simply using define-key:

          (global-unset-key KEY)
          ==
          (define-key (current-global-map) KEY nil)

 -- Command: local-set-key key binding
     This function sets the binding of KEY in the current local keymap to BINDING.

          (local-set-key KEY BINDING)
          ==
          (define-key (current-local-map) KEY BINDING)

 -- Command: local-unset-key key
     This function removes the binding of KEY from the current local map.

          (local-unset-key KEY)
          ==
          (define-key (current-local-map) KEY nil)

Scanning Keymaps
================

This section describes functions used to scan all the current keymaps for the sake of printing help information.

 -- Function: accessible-keymaps keymap &optional prefix
     This function returns a list of all the keymaps that can be reached (via zero or more prefix keys) from KEYMAP.  The value is an association list with elements of the form (KEY . MAP), where KEY is a prefix key whose definition in KEYMAP is MAP.

     The elements of the alist are ordered so that the KEY increases in length.  The first element is always ([] . KEYMAP), because the specified keymap is accessible from itself with a prefix of no events.

     If PREFIX is given, it should be a prefix key sequence; then accessible-keymaps includes only the submaps whose prefixes start with PREFIX.  These elements look just as they do in the value of (accessible-keymaps); the only difference is that some elements are omitted.

     In the example below, the returned alist indicates that the key ESC, which is displayed as ^[, is a prefix key whose definition is the sparse keymap (keymap (83 . center-paragraph) (115 . foo)).

          (accessible-keymaps (current-local-map))
          =>(([] keymap
                (27 keymap   ; Note this keymap for ESC is repeated below.
                    (83 . center-paragraph)
                    (115 . center-line))
                (9 . tab-to-tab-stop))

             ("^[" keymap
              (83 . center-paragraph)
              (115 . foo)))

     In the following example, C-h is a prefix key that uses a sparse keymap starting with (keymap (118 . describe-variable)...). Another prefix, C-x 4, uses a keymap which is also the value of the variable ctl-x-4-map.  The event mode-line is one of several dummy events used as prefixes for mouse actions in special parts of a window.

          (accessible-keymaps (current-global-map))
          => (([] keymap [set-mark-command beginning-of-line ...
                             delete-backward-char])

              ("^H" keymap (118 . describe-variable) ...
               (8 . help-for-help))

              ("^X" keymap [x-flush-mouse-queue ...
               backward-kill-sentence])

              ("^[" keymap [mark-sexp backward-sexp ...
               backward-kill-word])

              ("^X4" keymap (15 . display-buffer) ...)

              ([mode-line] keymap
               (S-mouse-2 . mouse-split-window-horizontally) ...))

     These are not all the keymaps you would see in actuality.

 -- Function: map-keymap function keymap
     The function map-keymap calls FUNCTION once for each binding in KEYMAP.  It passes two arguments, the event type and the value of the binding.  If KEYMAP has a parent, the parent's bindings are included as well. This works recursively: if the parent has itself a parent, then the grandparent's bindings are also included and so on.

     This function is the cleanest way to examine all the bindings in a keymap.

 -- Function: where-is-internal command &optional keymap firstonly noindirect no-remap
     This function is a subroutine used by the where-is command (see Help (The GNU Emacs Manual)).  It returns a list of all key sequences (of any length) that are bound to COMMAND in a set of keymaps.

     The argument COMMAND can be any object; it is compared with all keymap entries using eq.

     If KEYMAP is nil, then the maps used are the current active keymaps, disregarding overriding-local-map (that is, pretending its value is nil).  If KEYMAP is a keymap, then the maps searched are KEYMAP and the global keymap.  If KEYMAP is a list of keymaps, only those keymaps are searched.

     Usually it's best to use overriding-local-map as the expression for KEYMAP.  Then where-is-internal searches precisely the keymaps that are active.  To search only the global map, pass (keymap) (an empty keymap) as KEYMAP.

     If FIRSTONLY is non-ascii, then the value is a single vector representing the first key sequence found, rather than a list of all possible key sequences.  If FIRSTONLY is t, then the value is the first key sequence, except that key sequences consisting entirely of ASCII characters (or meta variants of ASCII characters) are preferred to all other key sequences and that the return value can never be a menu binding.

     If NOINDIRECT is non-nil, where-is-internal doesn't follow indirect keymap bindings.  This makes it possible to search for an indirect definition itself.

     When command remapping is in effect (see Remapping Commands), where-is-internal figures out when a command will be run due to remapping and reports keys accordingly.  It also returns nil if COMMAND won't really be run because it has been remapped to some other command.  However, if NO-REMAP is non-nil. where-is-internal ignores remappings.

          (where-is-internal 'describe-function)
              => ("\^hf" "\^hd")

 -- Command: describe-bindings &optional prefix buffer-or-name
     This function creates a listing of all current key bindings, and displays it in a buffer named *Help*.  The text is grouped by modes---minor modes first, then the major mode, then global bindings.

     If PREFIX is non-nil, it should be a prefix key; then the listing includes only keys that start with PREFIX.

     The listing describes meta characters as ESC followed by the corresponding non-meta character.

     When several characters with consecutive ASCII codes have the same definition, they are shown together, as FIRSTCHAR..LASTCHAR.  In this instance, you need to know the ASCII codes to understand which characters this means. For example, in the default global map, the characters SPC .. ~ are described by a single line.  SPC is ASCII 32, ~ is ASCII 126, and the characters between them include all the normal printing characters, (e.g., letters, digits, punctuation, etc.); all these characters are bound to self-insert-command.

     If BUFFER-OR-NAME is non-nil, it should be a buffer or a buffer name.  Then describe-bindings lists that buffer's bindings, instead of the current buffer's.

Menu Keymaps
============

A keymap can operate as a menu as well as defining bindings for keyboard keys and mouse buttons.  Menus are usually actuated with the mouse, but they can function with the keyboard also.  If a menu keymap is active for the next input event, that activates the keyboard menu feature.

Defining Menus
--------------

A keymap acts as a menu if it has an overall prompt string, which is a string that appears as an element of the keymap. (see Format of Keymaps.)  The string should describe the purpose of the menu's commands.  Emacs displays the overall prompt string as the menu title in some cases, depending on the toolkit (if any) used for displaying menus. (It is required for menus which do not use a toolkit, e.g. under MS-DOS.)  Keyboard menus also display the overall prompt string.

The easiest way to construct a keymap with a prompt string is to specify the string as an argument when you call make-keymap, make-sparse-keymap (see Creating Keymaps), or define-prefix-command (see Definition of define-prefix-command).  If you do not want the keymap to operate as a menu, don't specify a prompt string for it.

 -- Function: keymap-prompt keymap
     This function returns the overall prompt string of KEYMAP, or nil if it has none.

The menu's items are the bindings in the keymap.  Each binding associates an event type to a definition, but the event types have no significance for the menu appearance.  (Usually we use pseudo-events, symbols that the keyboard cannot generate, as the event types for menu item bindings.)  The menu is generated entirely from the bindings that correspond in the keymap to these events.

The order of items in the menu is the same as the order of bindings in the keymap.  Since define-key puts new bindings at the front, you should define the menu items starting at the bottom of the menu and moving to the top, if you care about the order.  When you add an item to an existing menu, you can specify its position in the menu using define-key-after (see Modifying Menus).

Simple Menu Items
.................

The simpler (and original) way to define a menu item is to bind some event type (it doesn't matter what event type) to a binding like this:

     (ITEM-STRING . REAL-BINDING)

The CAR, ITEM-STRING, is the string to be displayed in the menu.  It should be short---preferably one to three words.  It should describe the action of the command it corresponds to.  Note that it is not generally possible to display non-ASCII text in menus.  It will work for keyboard menus and will work to a large extent when Emacs is built with the Gtk+ toolkit. (In this case, the text is first encoded using the utf-8 coding system and then rendered by the toolkit as it sees fit.)

You can also supply a second string, called the help string, as follows:

     (ITEM-STRING HELP . REAL-BINDING)

HELP specifies a ``help-echo'' string to display while the mouse is on that item in the same way as help-echo text properties (see Help display).

As far as define-key is concerned, ITEM-STRING and HELP-STRING are part of the event's binding.  However, lookup-key returns just REAL-BINDING, and only REAL-BINDING is used for executing the key.

If REAL-BINDING is nil, then ITEM-STRING appears in the menu but cannot be selected.

If REAL-BINDING is a symbol and has a non-nil menu-enable property, that property is an expression that controls whether the menu item is enabled.  Every time the keymap is used to display a menu, Emacs evaluates the expression, and it enables the menu item only if the expression's value is non-nil.  When a menu item is disabled, it is displayed in a ``fuzzy'' fashion, and cannot be selected.

The menu bar does not recalculate which items are enabled every time you look at a menu.  This is because the X toolkit requires the whole tree of menus in advance.  To force recalculation of the menu bar, call force-mode-line-update (see Mode Line Format).

You've probably noticed that menu items show the equivalent keyboard key sequence (if any) to invoke the same command.  To save time on recalculation, menu display caches this information in a sublist in the binding, like this:

     (ITEM-STRING [HELP] (KEY-BINDING-DATA) . REAL-BINDING)

Don't put these sublists in the menu item yourself; menu display calculates them automatically.  Don't mention keyboard equivalents in the item strings themselves, since that is redundant.

Extended Menu Items
...................

An extended-format menu item is a more flexible and also cleaner alternative to the simple format.  You define an event type with a binding that's a list starting with the symbol menu-item. For a non-selectable string, the binding looks like this:

     (menu-item ITEM-NAME)

A string starting with two or more dashes specifies a separator line; see Menu Separators.

To define a real menu item which can be selected, the extended format binding looks like this:

     (menu-item ITEM-NAME REAL-BINDING
         . ITEM-PROPERTY-LIST)

Here, ITEM-NAME is an expression which evaluates to the menu item string.  Thus, the string need not be a constant.  The third element, REAL-BINDING, is the command to execute.  The tail of the list, ITEM-PROPERTY-LIST, has the form of a property list which contains other information.  Here is a table of the properties that are supported:

:enable FORM
     The result of evaluating FORM determines whether the item is enabled (non-nil means yes).  If the item is not enabled, you can't really click on it.

:visible FORM
     The result of evaluating FORM determines whether the item should actually appear in the menu (non-nil means yes).  If the item does not appear, then the menu is displayed as if this item were not defined at all.

:help HELP
     The value of this property, HELP, specifies a ``help-echo'' string to display while the mouse is on that item.  This is displayed in the same way as help-echo text properties (see Help display). Note that this must be a constant string, unlike the help-echo property for text and overlays.

:button (TYPE . SELECTED)
     This property provides a way to define radio buttons and toggle buttons. The CAR, TYPE, says which: it should be :toggle or :radio.  The CDR, SELECTED, should be a form; the result of evaluating it says whether this button is currently selected.

     A toggle is a menu item which is labeled as either ``on'' or ``off'' according to the value of SELECTED.  The command itself should toggle SELECTED, setting it to t if it is nil, and to nil if it is t.  Here is how the menu item to toggle the debug-on-error flag is defined:

          (menu-item "Debug on Error" toggle-debug-on-error
                     :button (:toggle
                              . (and (boundp 'debug-on-error)
                                     debug-on-error)))

     This works because toggle-debug-on-error is defined as a command which toggles the variable debug-on-error.

     Radio buttons are a group of menu items, in which at any time one and only one is ``selected.''  There should be a variable whose value says which one is selected at any time.  The SELECTED form for each radio button in the group should check whether the variable has the right value for selecting that button.  Clicking on the button should set the variable so that the button you clicked on becomes selected.

:key-sequence KEY-SEQUENCE
     This property specifies which key sequence is likely to be bound to the same command invoked by this menu item.  If you specify the right key sequence, that makes preparing the menu for display run much faster.

     If you specify the wrong key sequence, it has no effect; before Emacs displays KEY-SEQUENCE in the menu, it verifies that KEY-SEQUENCE is really equivalent to this menu item.

:key-sequence nil
     This property indicates that there is normally no key binding which is equivalent to this menu item.  Using this property saves time in preparing the menu for display, because Emacs does not need to search the keymaps for a keyboard equivalent for this menu item.

     However, if the user has rebound this item's definition to a key sequence, Emacs ignores the :keys property and finds the keyboard equivalent anyway.

:keys STRING
     This property specifies that STRING is the string to display as the keyboard equivalent for this menu item.  You can use the \\[...] documentation construct in STRING.

:filter FILTER-FN
     This property provides a way to compute the menu item dynamically. The property value FILTER-FN should be a function of one argument; when it is called, its argument will be REAL-BINDING.  The function should return the binding to use instead.

     Emacs can call this function at any time that it does redisplay or operates on menu data structures, so you should write it so it can safely be called at any time.

When an equivalent key binding is cached, the binding looks like this.

     (menu-item ITEM-NAME REAL-BINDING (KEY-BINDING-DATA)
         . ITEM-PROPERTY-LIST)

Menu Separators
...............

A menu separator is a kind of menu item that doesn't display any text---instead, it divides the menu into subparts with a horizontal line. A separator looks like this in the menu keymap:

     (menu-item SEPARATOR-TYPE)

where SEPARATOR-TYPE is a string starting with two or more dashes.

In the simplest case, SEPARATOR-TYPE consists of only dashes. That specifies the default kind of separator.  (For compatibility, "" and - also count as separators.)

Certain other values of SEPARATOR-TYPE specify a different style of separator.  Here is a table of them:

"--no-line"
"--space"
     An extra vertical space, with no actual line.

"--single-line"
     A single line in the menu's foreground color.

"--double-line"
     A double line in the menu's foreground color.

"--single-dashed-line"
     A single dashed line in the menu's foreground color.

"--double-dashed-line"
     A double dashed line in the menu's foreground color.

"--shadow-etched-in"
     A single line with a 3D sunken appearance.  This is the default, used separators consisting of dashes only.

"--shadow-etched-out"
     A single line with a 3D raised appearance.

"--shadow-etched-in-dash"
     A single dashed line with a 3D sunken appearance.

"--shadow-etched-out-dash"
     A single dashed line with a 3D raised appearance.

"--shadow-double-etched-in"
     Two lines with a 3D sunken appearance.

"--shadow-double-etched-out"
     Two lines with a 3D raised appearance.

"--shadow-double-etched-in-dash"
     Two dashed lines with a 3D sunken appearance.

"--shadow-double-etched-out-dash"
     Two dashed lines with a 3D raised appearance.

You can also give these names in another style, adding a colon after the double-dash and replacing each single dash with capitalization of the following word.  Thus, "--:singleLine", is equivalent to "--single-line".

Some systems and display toolkits don't really handle all of these separator types.  If you use a type that isn't supported, the menu displays a similar kind of separator that is supported.

Alias Menu Items
................

Sometimes it is useful to make menu items that use the ``same'' command but with different enable conditions.  The best way to do this in Emacs now is with extended menu items; before that feature existed, it could be done by defining alias commands and using them in menu items.  Here's an example that makes two aliases for toggle-read-only and gives them different enable conditions:

     (defalias 'make-read-only 'toggle-read-only)
     (put 'make-read-only 'menu-enable '(not buffer-read-only))
     (defalias 'make-writable 'toggle-read-only)
     (put 'make-writable 'menu-enable 'buffer-read-only)

When using aliases in menus, often it is useful to display the equivalent key bindings for the ``real'' command name, not the aliases (which typically don't have any key bindings except for the menu itself).  To request this, give the alias symbol a non-nil menu-alias property.  Thus,

     (put 'make-read-only 'menu-alias t)
     (put 'make-writable 'menu-alias t)

causes menu items for make-read-only and make-writable to show the keyboard bindings for toggle-read-only.

Menus and the Mouse
-------------------

The usual way to make a menu keymap produce a menu is to make it the definition of a prefix key.  (A Lisp program can explicitly pop up a menu and receive the user's choice---see Pop-Up Menus.)

If the prefix key ends with a mouse event, Emacs handles the menu keymap by popping up a visible menu, so that the user can select a choice with the mouse.  When the user clicks on a menu item, the event generated is whatever character or symbol has the binding that brought about that menu item.  (A menu item may generate a series of events if the menu has multiple levels or comes from the menu bar.)

It's often best to use a button-down event to trigger the menu.  Then the user can select a menu item by releasing the button.

A single keymap can appear as multiple menu panes, if you explicitly arrange for this.  The way to do this is to make a keymap for each pane, then create a binding for each of those maps in the main keymap of the menu.  Give each of these bindings an item string that starts with @.  The rest of the item string becomes the name of the pane. See the file lisp/mouse.el for an example of this.  Any ordinary bindings with @-less item strings are grouped into one pane, which appears along with the other panes explicitly created for the submaps.

X toolkit menus don't have panes; instead, they can have submenus. Every nested keymap becomes a submenu, whether the item string starts with @ or not.  In a toolkit version of Emacs, the only thing special about @ at the beginning of an item string is that the @ doesn't appear in the menu item.

Multiple keymaps that define the same menu prefix key produce separate panes or separate submenus.

Menus and the Keyboard
----------------------

When a prefix key ending with a keyboard event (a character or function key) has a definition that is a menu keymap, the keymap operates as a keyboard menu; the user specifies the next event by choosing a menu item with the keyboard.

Emacs displays the keyboard menu with the map's overall prompt string, followed by the alternatives (the item strings of the map's bindings), in the echo area.  If the bindings don't all fit at once, the user can type SPC to see the next line of alternatives. Successive uses of SPC eventually get to the end of the menu and then cycle around to the beginning.  (The variable menu-prompt-more-char specifies which character is used for this; SPC is the default.)

When the user has found the desired alternative from the menu, he or she should type the corresponding character---the one whose binding is that alternative.

This way of using menus in an Emacs-like editor was inspired by the Hierarkey system.

 -- Variable: menu-prompt-more-char
     This variable specifies the character to use to ask to see the next line of a menu.  Its initial value is 32, the code for SPC.

Menu Example
------------

Here is a complete example of defining a menu keymap.  It is the definition of the Replace submenu in the Edit menu in the menu bar, and it uses the extended menu item format (see Extended Menu Items).  First we create the keymap, and give it a name:

     (defvar menu-bar-replace-menu (make-sparse-keymap "Replace"))

Next we define the menu items:

     (define-key menu-bar-replace-menu [tags-repl-continue]
       '(menu-item "Continue Replace" tags-loop-continue
     	      :help "Continue last tags replace operation"))
     (define-key menu-bar-replace-menu [tags-repl]
       '(menu-item "Replace in tagged files" tags-query-replace
     	      :help "Interactively replace a regexp in all tagged files"))
     (define-key menu-bar-replace-menu [separator-replace-tags]
       '(menu-item "--"))
     ;; ...

Note the symbols which the bindings are ``made for''; these appear inside square brackets, in the key sequence being defined.  In some cases, this symbol is the same as the command name; sometimes it is different.  These symbols are treated as ``function keys,'' but they are not real function keys on the keyboard.  They do not affect the functioning of the menu itself, but they are ``echoed'' in the echo area when the user selects from the menu, and they appear in the output of where-is and apropos.

The menu in this example is intended for use with the mouse.  If a menu is intended for use with the keyboard, that is, if it is bound to a key sequence ending with a keyboard event, then the menu items should be bound to characters or ``real'' function keys, that can be typed with the keyboard.

The binding whose definition is ("--") is a separator line. Like a real menu item, the separator has a key symbol, in this case separator-replace-tags.  If one menu has two separators, they must have two different key symbols.

Here is how we make this menu appear as an item in the parent menu:

     (define-key menu-bar-edit-menu [replace]
       (list 'menu-item "Replace" menu-bar-replace-menu))

Note that this incorporates the submenu keymap, which is the value of the variable menu-bar-replace-menu, rather than the symbol menu-bar-replace-menu itself.  Using that symbol in the parent menu item would be meaningless because menu-bar-replace-menu is not a command.

If you wanted to attach the same replace menu to a mouse click, you can do it this way:

     (define-key global-map [C-S-down-mouse-1]
        menu-bar-replace-menu)

The Menu Bar
------------

Most window systems allow each frame to have a menu bar---a permanently displayed menu stretching horizontally across the top of the frame.  The items of the menu bar are the subcommands of the fake ``function key'' menu-bar, as defined in the active keymaps.

To add an item to the menu bar, invent a fake ``function key'' of your own (let's call it KEY), and make a binding for the key sequence [menu-bar KEY].  Most often, the binding is a menu keymap, so that pressing a button on the menu bar item leads to another menu.

When more than one active keymap defines the same fake function key for the menu bar, the item appears just once.  If the user clicks on that menu bar item, it brings up a single, combined menu containing all the subcommands of that item---the global subcommands, the local subcommands, and the minor mode subcommands.

The variable overriding-local-map is normally ignored when determining the menu bar contents.  That is, the menu bar is computed from the keymaps that would be active if overriding-local-map were nil.  See Active Keymaps.

In order for a frame to display a menu bar, its menu-bar-lines parameter must be greater than zero.  Emacs uses just one line for the menu bar itself; if you specify more than one line, the other lines serve to separate the menu bar from the windows in the frame.  We recommend 1 or 2 as the value of menu-bar-lines.  See Layout Parameters.

Here's an example of setting up a menu bar item:

     (modify-frame-parameters (selected-frame)
                              '((menu-bar-lines . 2)))

     ;; Make a menu keymap (with a prompt string)
     ;; and make it the menu bar item's definition.
     (define-key global-map [menu-bar words]
       (cons "Words" (make-sparse-keymap "Words")))

     ;; Define specific subcommands in this menu.
     (define-key global-map
       [menu-bar words forward]
       '("Forward word" . forward-word))

     (define-key global-map
       [menu-bar words backward]
       '("Backward word" . backward-word))

A local keymap can cancel a menu bar item made by the global keymap by rebinding the same fake function key with undefined as the binding.  For example, this is how Dired suppresses the Edit menu bar item:

     (define-key dired-mode-map [menu-bar edit] 'undefined)

edit is the fake function key used by the global map for the Edit menu bar item.  The main reason to suppress a global menu bar item is to regain space for mode-specific items.

 -- Variable: menu-bar-final-items
     Normally the menu bar shows global items followed by items defined by the local maps.

     This variable holds a list of fake function keys for items to display at the end of the menu bar rather than in normal sequence.  The default value is (help-menu); thus, the Help menu item normally appears at the end of the menu bar, following local menu items.

 -- Variable: menu-bar-update-hook
     This normal hook is run by redisplay to update the menu bar contents, before redisplaying the menu bar.  You can use it to update submenus whose contents should vary.  Since this hook is run frequently, we advise you to ensure that the functions it calls do not take much time in the usual case.

Tool bars
---------

A tool bar is a row of icons at the top of a frame, that execute commands when you click on them---in effect, a kind of graphical menu bar.

The frame parameter tool-bar-lines (X resource toolBar) controls how many lines' worth of height to reserve for the tool bar.  A zero value suppresses the tool bar.  If the value is nonzero, and auto-resize-tool-bars is non-nil, the tool bar expands and contracts automatically as needed to hold the specified contents.

The tool bar contents are controlled by a menu keymap attached to a fake ``function key'' called tool-bar (much like the way the menu bar is controlled).  So you define a tool bar item using define-key, like this:

     (define-key global-map [tool-bar KEY] ITEM)

where KEY is a fake ``function key'' to distinguish this item from other items, and ITEM is a menu item key binding (see Extended Menu Items), which says how to display this item and how it behaves.

The usual menu keymap item properties, :visible, :enable, :button, and :filter, are useful in tool bar bindings and have their normal meanings.  The REAL-BINDING in the item must be a command, not a keymap; in other words, it does not work to define a tool bar icon as a prefix key.

The :help property specifies a ``help-echo'' string to display while the mouse is on that item.  This is displayed in the same way as help-echo text properties (see Help display).

In addition, you should use the :image property; this is how you specify the image to display in the tool bar:

:image IMAGE
     IMAGES is either a single image specification or a vector of four image specifications.  If you use a vector of four, one of them is used, depending on circumstances:

     item 0
          Used when the item is enabled and selected.

     item 1
          Used when the item is enabled and deselected.

     item 2
          Used when the item is disabled and selected.

     item 3
          Used when the item is disabled and deselected.

If IMAGE is a single image specification, Emacs draws the tool bar button in disabled state by applying an edge-detection algorithm to the image.

The default tool bar is defined so that items specific to editing do not appear for major modes whose command symbol has a mode-class property of special (see Major Mode Conventions).  Major modes may add items to the global bar by binding [tool-bar FOO] in their local map.  It makes sense for some major modes to replace the default tool bar items completely, since not many can be accommodated conveniently, and the default bindings make this easy by using an indirection through tool-bar-map.

 -- Variable: tool-bar-map
     By default, the global map binds [tool-bar] as follows:

          (global-set-key [tool-bar]
          		'(menu-item "tool bar" ignore
          			    :filter (lambda (ignore) tool-bar-map)))

     Thus the tool bar map is derived dynamically from the value of variable tool-bar-map and you should normally adjust the default (global) tool bar by changing that map.  Major modes may replace the global bar completely by making tool-bar-map buffer-local and set to a keymap containing only the desired items.  Info mode provides an example.

There are two convenience functions for defining tool bar items, as follows.

 -- Function: tool-bar-add-item icon def key &rest props
     This function adds an item to the tool bar by modifying tool-bar-map.  The image to use is defined by ICON, which is the base name of an XPM, XBM or PBM image file to be located by find-image.  Given a value "exit", say, exit.xpm, exit.pbm and exit.xbm would be searched for in that order on a color display.  On a monochrome display, the search order is .pbm, .xbm and .xpm.  The binding to use is the command DEF, and KEY is the fake function key symbol in the prefix keymap.  The remaining arguments PROPS are additional property list elements to add to the menu item specification.

     To define items in some local map, bind tool-bar-map with let around calls of this function:

          (defvar foo-tool-bar-map
            (let ((tool-bar-map (make-sparse-keymap)))
              (tool-bar-add-item ...)
              ...
              tool-bar-map))

 -- Function: tool-bar-add-item-from-menu command icon &optional map &rest props
     This function is a convenience for defining tool bar items which are consistent with existing menu bar bindings.  The binding of COMMAND is looked up in the menu bar in MAP (default global-map) and modified to add an image specification for ICON, which is found in the same way as by tool-bar-add-item.  The resulting binding is then placed in tool-bar-map, so use this function only for global tool bar items.

     MAP must contain an appropriate keymap bound to [menu-bar].  The remaining arguments PROPS are additional property list elements to add to the menu item specification.

 -- Function: tool-bar-local-item-from-menu command icon in-map &optional from-map &rest props
     This function is used for making non-global tool bar items.  Use it like tool-bar-add-item-from-menu except that IN-MAP specifies the local map to make the definition in.  The argument FROM-MAP is like the MAP argument of tool-bar-add-item-from-menu.

 -- Variable: auto-resize-tool-bar
     If this variable is non-nil, the tool bar automatically resizes to show all defined tool bar items---but not larger than a quarter of the frame's height.

 -- Variable: auto-raise-tool-bar-buttons
     If this variable is non-nil, tool bar items display in raised form when the mouse moves over them.

 -- Variable: tool-bar-button-margin
     This variable specifies an extra margin to add around tool bar items. The value is an integer, a number of pixels.  The default is 4.

 -- Variable: tool-bar-button-relief
     This variable specifies the shadow width for tool bar items. The value is an integer, a number of pixels.  The default is 1.

 -- Variable: tool-bar-border
     This variable specifies the height of the border drawn below the tool bar area.  An integer value specifies height as a number of pixels. If the value is one of internal-border-width (the default) or border-width, the tool bar border height corresponds to the corresponding frame parameter.

You can define a special meaning for clicking on a tool bar item with the shift, control, meta, etc., modifiers.  You do this by setting up additional items that relate to the original item through the fake function keys.  Specifically, the additional items should use the modified versions of the same fake function key used to name the original item.

Thus, if the original item was defined this way,

     (define-key global-map [tool-bar shell]
       '(menu-item "Shell" shell
                   :image (image :type xpm :file "shell.xpm")))

then here is how you can define clicking on the same tool bar image with the shift modifier:

     (define-key global-map [tool-bar S-shell] 'some-command)

See Function Keys, for more information about how to add modifiers to function keys.

Modifying Menus
---------------

When you insert a new item in an existing menu, you probably want to put it in a particular place among the menu's existing items.  If you use define-key to add the item, it normally goes at the front of the menu.  To put it elsewhere in the menu, use define-key-after:

 -- Function: define-key-after map key binding &optional after
     Define a binding in MAP for KEY, with value BINDING, just like define-key, but position the binding in MAP after the binding for the event AFTER.  The argument KEY should be of length one---a vector or string with just one element.  But AFTER should be a single event type---a symbol or a character, not a sequence.  The new binding goes after the binding for AFTER.  If AFTER is t or is omitted, then the new binding goes last, at the end of the keymap.  However, new bindings are added before any inherited keymap.

     Here is an example:

          (define-key-after my-menu [drink]
            '("Drink" . drink-command) 'eat)

     makes a binding for the fake function key DRINK and puts it right after the binding for EAT.

     Here is how to insert an item called Work in the Signals menu of Shell mode, after the item break:

          (define-key-after
            (lookup-key shell-mode-map [menu-bar signals])
            [work] '("Work" . work-command) 'break)