Emacs Display
*************

This chapter describes a number of features related to the display that Emacs presents to the user.

Refreshing the Screen
=====================

The function redraw-frame redisplays the entire contents of a given frame (see Frames).

 -- Function: redraw-frame frame
     This function clears and redisplays frame FRAME.

Even more powerful is redraw-display:

 -- Command: redraw-display
     This function clears and redisplays all visible frames.

Processing user input takes absolute priority over redisplay.  If you call these functions when input is available, they do nothing immediately, but a full redisplay does happen eventually---after all the input has been processed.

Normally, suspending and resuming Emacs also refreshes the screen. Some terminal emulators record separate contents for display-oriented programs such as Emacs and for ordinary sequential display.  If you are using such a terminal, you might want to inhibit the redisplay on resumption.

 -- Variable: no-redraw-on-reenter
     This variable controls whether Emacs redraws the entire screen after it has been suspended and resumed.  Non-nil means there is no need to redraw, nil means redrawing is needed.  The default is nil.

Forcing Redisplay
=================

Emacs redisplay normally stops if input arrives, and does not happen at all if input is available before it starts.  Most of the time, this is exactly what you want.  However, you can prevent preemption by binding redisplay-dont-pause to a non-nil value.

 -- Variable: redisplay-dont-pause
     If this variable is non-nil, pending input does not prevent or halt redisplay; redisplay occurs, and finishes, regardless of whether input is available.  This feature is available as of Emacs 21.

You can request a display update, but only if no input is pending, with (sit-for 0).  To force a display update even when input is pending, do this:

     (let ((redisplay-dont-pause t))
       (sit-for 0))

Truncation
==========

When a line of text extends beyond the right edge of a window, the line can either be continued on the next screen line, or truncated to one screen line.  The additional screen lines used to display a long text line are called continuation lines.  Normally, a $ in the rightmost column of the window indicates truncation; a \ on the rightmost column indicates a line that ``wraps'' onto the next line, which is also called continuing the line.  (The display table can specify alternative indicators; see Display Tables.)

Note that continuation is different from filling; continuation happens on the screen only, not in the buffer contents, and it breaks a line precisely at the right margin, not at a word boundary.  See Filling.

 -- User Option: truncate-lines
     This buffer-local variable controls how Emacs displays lines that extend beyond the right edge of the window.  The default is nil, which specifies continuation.  If the value is non-nil, then these lines are truncated.

     If the variable truncate-partial-width-windows is non-nil, then truncation is always used for side-by-side windows (within one frame) regardless of the value of truncate-lines.

 -- User Option: default-truncate-lines
     This variable is the default value for truncate-lines, for buffers that do not have buffer-local values for it.

 -- User Option: truncate-partial-width-windows
     This variable controls display of lines that extend beyond the right edge of the window, in side-by-side windows (see Splitting Windows). If it is non-nil, these lines are truncated; otherwise, truncate-lines says what to do with them.

When horizontal scrolling (see Horizontal Scrolling) is in use in a window, that forces truncation.

You can override the glyphs that indicate continuation or truncation using the display table; see Display Tables.

If your buffer contains very long lines, and you use continuation to display them, just thinking about them can make Emacs redisplay slow.  The column computation and indentation functions also become slow.  Then you might find it advisable to set cache-long-line-scans to t.

 -- Variable: cache-long-line-scans
     If this variable is non-nil, various indentation and motion functions, and Emacs redisplay, cache the results of scanning the buffer, and consult the cache to avoid rescanning regions of the buffer unless they are modified.

     Turning on the cache slows down processing of short lines somewhat.

     This variable is automatically buffer-local in every buffer.

The Echo Area
=============

The echo area is used for displaying messages made with the message primitive, and for echoing keystrokes.  It is not the same as the minibuffer, despite the fact that the minibuffer appears (when active) in the same place on the screen as the echo area.  The GNU Emacs Manual specifies the rules for resolving conflicts between the echo area and the minibuffer for use of that screen space (see The Minibuffer (The GNU Emacs Manual)). Error messages appear in the echo area; see Errors.

You can write output in the echo area by using the Lisp printing functions with t as the stream (see Output Functions), or as follows:

 -- Function: message string &rest arguments
     This function displays a one-line message in the echo area.  The argument STRING is similar to a C language printf control string.  See format in String Conversion, for the details on the conversion specifications.  message returns the constructed string.

     In batch mode, message prints the message text on the standard error stream, followed by a newline.

     If STRING, or strings among the ARGUMENTS, have face text properties, these affect the way the message is displayed.

     If STRING is nil, message clears the echo area; if the echo area has been expanded automatically, this brings it back to its normal size.  If the minibuffer is active, this brings the minibuffer contents back onto the screen immediately.

          (message "Minibuffer depth is %d."
                   (minibuffer-depth))
           -| Minibuffer depth is 0.
          => "Minibuffer depth is 0."

          ---------- Echo Area ----------
          Minibuffer depth is 0.
          ---------- Echo Area ----------

 -- Macro: with-temp-message message &rest body
     This construct displays a message in the echo area temporarily, during the execution of BODY.  It displays MESSAGE, executes BODY, then returns the value of the last body form while restoring the previous echo area contents.

 -- Function: message-or-box string &rest arguments
     This function displays a message like message, but may display it in a dialog box instead of the echo area.  If this function is called in a command that was invoked using the mouse---more precisely, if last-nonmenu-event (see Command Loop Info) is either nil or a list---then it uses a dialog box or pop-up menu to display the message.  Otherwise, it uses the echo area.  (This is the same criterion that y-or-n-p uses to make a similar decision; see Yes-or-No Queries.)

     You can force use of the mouse or of the echo area by binding last-nonmenu-event to a suitable value around the call.

 -- Function: message-box string &rest arguments
     This function displays a message like message, but uses a dialog box (or a pop-up menu) whenever that is possible.  If it is impossible to use a dialog box or pop-up menu, because the terminal does not support them, then message-box uses the echo area, like message.

 -- Function: current-message
     This function returns the message currently being displayed in the echo area, or nil if there is none.

 -- Variable: cursor-in-echo-area
     This variable controls where the cursor appears when a message is displayed in the echo area.  If it is non-nil, then the cursor appears at the end of the message.  Otherwise, the cursor appears at point---not in the echo area at all.

     The value is normally nil; Lisp programs bind it to t for brief periods of time.

 -- Variable: echo-area-clear-hook
     This normal hook is run whenever the echo area is cleared---either by (message nil) or for any other reason.

Almost all the messages displayed in the echo area are also recorded in the *Messages* buffer.

 -- User Option: message-log-max
     This variable specifies how many lines to keep in the *Messages* buffer.  The value t means there is no limit on how many lines to keep.  The value nil disables message logging entirely.  Here's how to display a message and prevent it from being logged:

          (let (message-log-max)
            (message ...))

 -- Variable: echo-keystrokes
     This variable determines how much time should elapse before command characters echo.  Its value must be an integer, which specifies the number of seconds to wait before echoing.  If the user types a prefix key (such as C-x) and then delays this many seconds before continuing, the prefix key is echoed in the echo area.  (Once echoing begins in a key sequence, all subsequent characters in the same key sequence are echoed immediately.)

     If the value is zero, then command input is not echoed.

Invisible Text
==============

You can make characters invisible, so that they do not appear on the screen, with the invisible property.  This can be either a text property (see Text Properties) or a property of an overlay (see Overlays).

In the simplest case, any non-nil invisible property makes a character invisible.  This is the default case---if you don't alter the default value of buffer-invisibility-spec, this is how the invisible property works.

More generally, you can use the variable buffer-invisibility-spec to control which values of the invisible property make text invisible.  This permits you to classify the text into different subsets in advance, by giving them different invisible values, and subsequently make various subsets visible or invisible by changing the value of buffer-invisibility-spec.

Controlling visibility with buffer-invisibility-spec is especially useful in a program to display the list of entries in a database.  It permits the implementation of convenient filtering commands to view just a part of the entries in the database.  Setting this variable is very fast, much faster than scanning all the text in the buffer looking for properties to change.

 -- Variable: buffer-invisibility-spec
     This variable specifies which kinds of invisible properties actually make a character invisible.

     t
          A character is invisible if its invisible property is non-nil.  This is the default.

     a list
          Each element of the list specifies a criterion for invisibility; if a character's invisible property fits any one of these criteria, the character is invisible.  The list can have two kinds of elements:

          ATOM
               A character is invisible if its invisible property value is ATOM or if it is a list with ATOM as a member.

          (ATOM . t)
               A character is invisible if its invisible property value is ATOM or if it is a list with ATOM as a member. Moreover, if this character is at the end of a line and is followed by a visible newline, it displays an ellipsis.

Two functions are specifically provided for adding elements to buffer-invisibility-spec and removing elements from it.

 -- Function: add-to-invisibility-spec element
     Add the element ELEMENT to buffer-invisibility-spec (if it is not already present in that list).

 -- Function: remove-from-invisibility-spec element
     Remove the element ELEMENT from buffer-invisibility-spec. This does nothing if ELEMENT is not in the list.

One convention about the use of buffer-invisibility-spec is that a major mode should use the mode's own name as an element of buffer-invisibility-spec and as the value of the invisible property:

     ;; If you want to display an ellipsis:
     (add-to-invisibility-spec '(my-symbol . t))
     ;; If you don't want ellipsis:
     (add-to-invisibility-spec 'my-symbol)

     (overlay-put (make-overlay beginning end)
                  'invisible 'my-symbol)

     ;; When done with the overlays:
     (remove-from-invisibility-spec '(my-symbol . t))
     ;; Or respectively:
     (remove-from-invisibility-spec 'my-symbol)

Ordinarily, commands that operate on text or move point do not care whether the text is invisible.  The user-level line motion commands explicitly ignore invisible newlines if line-move-ignore-invisible is non-nil, but only because they are explicitly programmed to do so.

Incremental search can make invisible overlays visible temporarily and/or permanently when a match includes invisible text.  To enable this, the overlay should have a non-nil isearch-open-invisible property.  The property value should be a function to be called with the overlay as an argument.  This function should make the overlay visible permanently; it is used when the match overlaps the overlay on exit from the search.

During the search, such overlays are made temporarily visible by temporarily modifying their invisible and intangible properties.  If you want this to be done differently for a certain overlay, give it an isearch-open-invisible-temporary property which is a function. The function is called with two arguments: the first is the overlay, and the second is nil to make the overlay visible, or t to make it invisible again.

Selective Display
=================

Selective display refers to a pair of related features for hiding certain lines on the screen.

The first variant, explicit selective display, is designed for use in a Lisp program: it controls which lines are hidden by altering the text. The invisible text feature (see Invisible Text) has partially replaced this feature.

In the second variant, the choice of lines to hide is made automatically based on indentation.  This variant is designed to be a user-level feature.

The way you control explicit selective display is by replacing a newline (control-j) with a carriage return (control-m).  The text that was formerly a line following that newline is now invisible.  Strictly speaking, it is temporarily no longer a line at all, since only newlines can separate lines; it is now part of the previous line.

Selective display does not directly affect editing commands.  For example, C-f (forward-char) moves point unhesitatingly into invisible text.  However, the replacement of newline characters with carriage return characters affects some editing commands.  For example, next-line skips invisible lines, since it searches only for newlines.  Modes that use selective display can also define commands that take account of the newlines, or that make parts of the text visible or invisible.

When you write a selectively displayed buffer into a file, all the control-m's are output as newlines.  This means that when you next read in the file, it looks OK, with nothing invisible.  The selective display effect is seen only within Emacs.

 -- Variable: selective-display
     This buffer-local variable enables selective display.  This means that lines, or portions of lines, may be made invisible.

       * If the value of selective-display is t, then the character control-m marks the start of invisible text; the control-m, and the rest of the line following it, are not displayed.  This is explicit selective display.

       * If the value of selective-display is a positive integer, then lines that start with more than that many columns of indentation are not displayed.

     When some portion of a buffer is invisible, the vertical movement commands operate as if that portion did not exist, allowing a single next-line command to skip any number of invisible lines. However, character movement commands (such as forward-char) do not skip the invisible portion, and it is possible (if tricky) to insert or delete text in an invisible portion.

     In the examples below, we show the display appearance of the buffer foo, which changes with the value of selective-display.  The contents of the buffer do not change.

          (setq selective-display nil)
               => nil

          ---------- Buffer: foo ----------
          1 on this column
           2on this column
            3n this column
            3n this column
           2on this column
          1 on this column
          ---------- Buffer: foo ----------

          (setq selective-display 2)
               => 2

          ---------- Buffer: foo ----------
          1 on this column
           2on this column
           2on this column
          1 on this column
          ---------- Buffer: foo ----------

 -- Variable: selective-display-ellipses
     If this buffer-local variable is non-nil, then Emacs displays ... at the end of a line that is followed by invisible text. This example is a continuation of the previous one.

          (setq selective-display-ellipses t)
               => t

          ---------- Buffer: foo ----------
          1 on this column
           2on this column ...
           2on this column
          1 on this column
          ---------- Buffer: foo ----------

     You can use a display table to substitute other text for the ellipsis (...).  See Display Tables.

The Overlay Arrow
=================

The overlay arrow is useful for directing the user's attention to a particular line in a buffer.  For example, in the modes used for interface to debuggers, the overlay arrow indicates the line of code about to be executed.

 -- Variable: overlay-arrow-string
     This variable holds the string to display to call attention to a particular line, or nil if the arrow feature is not in use.

 -- Variable: overlay-arrow-position
     This variable holds a marker that indicates where to display the overlay arrow.  It should point at the beginning of a line.  The arrow text appears at the beginning of that line, overlaying any text that would otherwise appear.  Since the arrow is usually short, and the line usually begins with indentation, normally nothing significant is overwritten.

     The overlay string is displayed only in the buffer that this marker points into.  Thus, only one buffer can have an overlay arrow at any given time.

You can do a similar job by creating an overlay with a before-string property.  See Overlay Properties.

Temporary Displays
==================

Temporary displays are used by Lisp programs to put output into a buffer and then present it to the user for perusal rather than for editing.  Many help commands use this feature.

 -- Special Form: with-output-to-temp-buffer buffer-name forms...
     This function executes FORMS while arranging to insert any output they print into the buffer named BUFFER-NAME, which is first created if necessary, and put into Help mode.  Finally, the buffer is displayed in some window, but not selected.

     If the FORMS do not change the major mode in the output buffer, so that it is still Help mode at the end of their execution, then with-output-to-temp-buffer makes this buffer read-only at the end, and also scans it for function and variable names to make them into clickable cross-references.

     The string BUFFER-NAME specifies the temporary buffer, which need not already exist.  The argument must be a string, not a buffer. The buffer is erased initially (with no questions asked), and it is marked as unmodified after with-output-to-temp-buffer exits.

     with-output-to-temp-buffer binds standard-output to the temporary buffer, then it evaluates the forms in FORMS.  Output using the Lisp output functions within FORMS goes by default to that buffer (but screen display and messages in the echo area, although they are ``output'' in the general sense of the word, are not affected). See Output Functions.

     Several hooks are available for customizing the behavior of this construct; they are listed below.

     The value of the last form in FORMS is returned.

          ---------- Buffer: foo ----------
           This is the contents of foo.
          ---------- Buffer: foo ----------

          (with-output-to-temp-buffer "foo"
              (print 20)
              (print standard-output))
          => #<buffer foo>

          ---------- Buffer: foo ----------
          20

          #<buffer foo>

          ---------- Buffer: foo ----------

 -- Variable: temp-buffer-show-function
     If this variable is non-nil, with-output-to-temp-buffer calls it as a function to do the job of displaying a help buffer.  The function gets one argument, which is the buffer it should display.

     It is a good idea for this function to run temp-buffer-show-hook just as with-output-to-temp-buffer normally would, inside of save-selected-window and with the chosen window and buffer selected.

 -- Variable: temp-buffer-setup-hook
     This normal hook is run by with-output-to-temp-buffer before evaluating BODY.  When the hook runs, the help buffer is current. This hook is normally set up with a function to put the buffer in Help mode.

 -- Variable: temp-buffer-show-hook
     This normal hook is run by with-output-to-temp-buffer after displaying the help buffer.  When the hook runs, the help buffer is current, and the window it was displayed in is selected.  This hook is normally set up with a function to make the buffer read only, and find function names and variable names in it, provided the major mode is still Help mode.

 -- Function: momentary-string-display string position &optional char message
     This function momentarily displays STRING in the current buffer at POSITION.  It has no effect on the undo list or on the buffer's modification status.

     The momentary display remains until the next input event.  If the next input event is CHAR, momentary-string-display ignores it and returns.  Otherwise, that event remains buffered for subsequent use as input.  Thus, typing CHAR will simply remove the string from the display, while typing (say) C-f will remove the string from the display and later (presumably) move point forward.  The argument CHAR is a space by default.

     The return value of momentary-string-display is not meaningful.

     If the string STRING does not contain control characters, you can do the same job in a more general way by creating (and then subsequently deleting) an overlay with a before-string property. See Overlay Properties.

     If MESSAGE is non-nil, it is displayed in the echo area while STRING is displayed in the buffer.  If it is nil, a default message says to type CHAR to continue.

     In this example, point is initially located at the beginning of the second line:

          ---------- Buffer: foo ----------
          This is the contents of foo.
          -!-Second line.
          ---------- Buffer: foo ----------

          (momentary-string-display
            "**** Important Message! ****"
            (point) ?\r
            "Type RET when done reading")
          => t

          ---------- Buffer: foo ----------
          This is the contents of foo.
          **** Important Message! ****Second line.
          ---------- Buffer: foo ----------

          ---------- Echo Area ----------
          Type RET when done reading
          ---------- Echo Area ----------

Overlays
========

You can use overlays to alter the appearance of a buffer's text on the screen, for the sake of presentation features.  An overlay is an object that belongs to a particular buffer, and has a specified beginning and end.  It also has properties that you can examine and set; these affect the display of the text within the overlay.

Overlay Properties
------------------

Overlay properties are like text properties in that the properties that alter how a character is displayed can come from either source.  But in most respects they are different.  Text properties are considered a part of the text; overlays are specifically considered not to be part of the text.  Thus, copying text between various buffers and strings preserves text properties, but does not try to preserve overlays.  Changing a buffer's text properties marks the buffer as modified, while moving an overlay or changing its properties does not.  Unlike text property changes, overlay changes are not recorded in the buffer's undo list. See Text Properties, for comparison.

These functions are used for reading and writing the properties of an overlay:

 -- Function: overlay-get overlay prop
     This function returns the value of property PROP recorded in OVERLAY, if any.  If OVERLAY does not record any value for that property, but it does have a category property which is a symbol, that symbol's PROP property is used.  Otherwise, the value is nil.

 -- Function: overlay-put overlay prop value
     This function sets the value of property PROP recorded in OVERLAY to VALUE.  It returns VALUE.

See also the function get-char-property which checks both overlay properties and text properties for a given character. See Examining Properties.

Many overlay properties have special meanings; here is a table of them:

priority
     This property's value (which should be a nonnegative number) determines the priority of the overlay.  The priority matters when two or more overlays cover the same character and both specify a face for display; the one whose priority value is larger takes priority over the other, and its face attributes override the face attributes of the lower priority overlay.

     Currently, all overlays take priority over text properties.  Please avoid using negative priority values, as we have not yet decided just what they should mean.

window
     If the window property is non-nil, then the overlay applies only on that window.

category
     If an overlay has a category property, we call it the category of the overlay.  It should be a symbol.  The properties of the symbol serve as defaults for the properties of the overlay.

face
     This property controls the way text is displayed---for example, which font and which colors.  See Faces, for more information.

     In the simplest case, the value is a face name.  It can also be a list; then each element can be any of these possibilities:

       * A face name (a symbol or string).

       * Starting in Emacs 21, a property list of face attributes.  This has the form (KEYWORD VALUE ...), where each KEYWORD is a face attribute name and VALUE is a meaningful value for that attribute.  With this feature, you do not need to create a face each time you want to specify a particular attribute for certain text. See Face Attributes.

       * A cons cell of the form (foreground-color . COLOR-NAME) or (background-color . COLOR-NAME).  These elements specify just the foreground color or just the background color.

          (foreground-color . COLOR-NAME) is equivalent to (:foreground COLOR-NAME), and likewise for the background.

mouse-face
     This property is used instead of face when the mouse is within the range of the overlay.

display
     This property activates various features that change the way text is displayed.  For example, it can make text appear taller or shorter, higher or lower, wider or narror, or replaced with an image. See Display Property.

help-echo
     If an overlay has a string as its help-echo property, then when you move the mouse onto the text in the overlay, Emacs displays that string in the echo area, or in the tooltip window.  This feature is available starting in Emacs 21.

modification-hooks
     This property's value is a list of functions to be called if any character within the overlay is changed or if text is inserted strictly within the overlay.

     The hook functions are called both before and after each change. If the functions save the information they receive, and compare notes between calls, they can determine exactly what change has been made in the buffer text.

     When called before a change, each function receives four arguments: the overlay, nil, and the beginning and end of the text range to be modified.

     When called after a change, each function receives five arguments: the overlay, t, the beginning and end of the text range just modified, and the length of the pre-change text replaced by that range. (For an insertion, the pre-change length is zero; for a deletion, that length is the number of characters deleted, and the post-change beginning and end are equal.)

insert-in-front-hooks
     This property's value is a list of functions to be called before and after inserting text right at the beginning of the overlay.  The calling conventions are the same as for the modification-hooks functions.

insert-behind-hooks
     This property's value is a list of functions to be called before and after inserting text right at the end of the overlay.  The calling conventions are the same as for the modification-hooks functions.

invisible
     The invisible property can make the text in the overlay invisible, which means that it does not appear on the screen. See Invisible Text, for details.

intangible
     The intangible property on an overlay works just like the intangible text property.  See Special Properties, for details.

isearch-open-invisible
     This property tells incremental search how to make an invisible overlay visible, permanently, if the final match overlaps it.  See Invisible Text.

isearch-open-invisible-temporary
     This property tells incremental search how to make an invisible overlay visible, temporarily, during the search.  See Invisible Text.

before-string
     This property's value is a string to add to the display at the beginning of the overlay.  The string does not appear in the buffer in any sense---only on the screen.

after-string
     This property's value is a string to add to the display at the end of the overlay.  The string does not appear in the buffer in any sense---only on the screen.

evaporate
     If this property is non-nil, the overlay is deleted automatically if it ever becomes empty (i.e., if it spans no characters).

local-map
     If this property is non-nil, it specifies a keymap for a portion of the text.  The property's value replaces the buffer's local map, when the character after point is within the overlay.  See Active Keymaps.

Managing Overlays
-----------------

This section describes the functions to create, delete and move overlays, and to examine their contents.

 -- Function: make-overlay start end &optional buffer front-advance rear-advance
     This function creates and returns an overlay that belongs to BUFFER and ranges from START to END.  Both START and END must specify buffer positions; they may be integers or markers.  If BUFFER is omitted, the overlay is created in the current buffer.

     The arguments FRONT-ADVANCE and REAR-ADVANCE specify the insertion type for the start of the overlay and for the end of the overlay, respectively.  See Marker Insertion Types.

 -- Function: overlay-start overlay
     This function returns the position at which OVERLAY starts, as an integer.

 -- Function: overlay-end overlay
     This function returns the position at which OVERLAY ends, as an integer.

 -- Function: overlay-buffer overlay
     This function returns the buffer that OVERLAY belongs to.

 -- Function: delete-overlay overlay
     This function deletes OVERLAY.  The overlay continues to exist as a Lisp object, and its property list is unchanged, but it ceases to be attached to the buffer it belonged to, and ceases to have any effect on display.

     A deleted overlay is not permanently disconnected.  You can give it a position in a buffer again by calling move-overlay.

 -- Function: move-overlay overlay start end &optional buffer
     This function moves OVERLAY to BUFFER, and places its bounds at START and END.  Both arguments START and END must specify buffer positions; they may be integers or markers.

     If BUFFER is omitted, OVERLAY stays in the same buffer it was already associated with; if OVERLAY was deleted, it goes into the current buffer.

     The return value is OVERLAY.

     This is the only valid way to change the endpoints of an overlay.  Do not try modifying the markers in the overlay by hand, as that fails to update other vital data structures and can cause some overlays to be ``lost''.

Here are some examples:

     ;; Create an overlay.
     (setq foo (make-overlay 1 10))
          => #<overlay from 1 to 10 in display.texi>
     (overlay-start foo)
          => 1
     (overlay-end foo)
          => 10
     (overlay-buffer foo)
          => #<buffer display.texi>
     ;; Give it a property we can check later.
     (overlay-put foo 'happy t)
          => t
     ;; Verify the property is present.
     (overlay-get foo 'happy)
          => t
     ;; Move the overlay.
     (move-overlay foo 5 20)
          => #<overlay from 5 to 20 in display.texi>
     (overlay-start foo)
          => 5
     (overlay-end foo)
          => 20
     ;; Delete the overlay.
     (delete-overlay foo)
          => nil
     ;; Verify it is deleted.
     foo
          => #<overlay in no buffer>
     ;; A deleted overlay has no position.
     (overlay-start foo)
          => nil
     (overlay-end foo)
          => nil
     (overlay-buffer foo)
          => nil
     ;; Undelete the overlay.
     (move-overlay foo 1 20)
          => #<overlay from 1 to 20 in display.texi>
     ;; Verify the results.
     (overlay-start foo)
          => 1
     (overlay-end foo)
          => 20
     (overlay-buffer foo)
          => #<buffer display.texi>
     ;; Moving and deleting the overlay don't change its properties.
     (overlay-get foo 'happy)
          => t

Searching for Overlays
----------------------

 -- Function: overlays-at pos
     This function returns a list of all the overlays that cover the character at position POS in the current buffer.  The list is in no particular order.  An overlay contains position POS if it begins at or before POS, and ends after POS.

     To illustrate usage, here is a Lisp function that returns a list of the overlays that specify property PROP for the character at point:

          (defun find-overlays-specifying (prop)
            (let ((overlays (overlays-at (point)))
                  found)
              (while overlays
                (let ((overlay (cdr overlays)))
                  (if (overlay-get overlay prop)
                      (setq found (cons overlay found))))
                (setq overlays (cdr overlays)))
              found))

 -- Function: overlays-in beg end
     This function returns a list of the overlays that overlap the region BEG through END.  ``Overlap'' means that at least one character is contained within the overlay and also contained within the specified region; however, empty overlays are included in the result if they are located at BEG, or strictly between BEG and END.

 -- Function: next-overlay-change pos
     This function returns the buffer position of the next beginning or end of an overlay, after POS.

 -- Function: previous-overlay-change pos
     This function returns the buffer position of the previous beginning or end of an overlay, before POS.

Here's an easy way to use next-overlay-change to search for the next character which gets a non-nil happy property from either its overlays or its text properties (see Property Search):

     (defun find-overlay-prop (prop)
       (save-excursion
         (while (and (not (eobp))
                     (not (get-char-property (point) 'happy)))
           (goto-char (min (next-overlay-change (point))
                           (next-single-property-change (point) 'happy))))
         (point)))

Width
=====

Since not all characters have the same width, these functions let you check the width of a character.  See Primitive Indent, and Screen Lines, for related functions.

 -- Function: char-width char
     This function returns the width in columns of the character CHAR, if it were displayed in the current buffer and the selected window.

 -- Function: string-width string
     This function returns the width in columns of the string STRING, if it were displayed in the current buffer and the selected window.

 -- Function: truncate-string-to-width string width &optional start-column padding
     This function returns the part of STRING that fits within WIDTH columns, as a new string.

     If STRING does not reach WIDTH, then the result ends where STRING ends.  If one multi-column character in STRING extends across the column WIDTH, that character is not included in the result.  Thus, the result can fall short of WIDTH but cannot go beyond it.

     The optional argument START-COLUMN specifies the starting column. If this is non-nil, then the first START-COLUMN columns of the string are omitted from the value.  If one multi-column character in STRING extends across the column START-COLUMN, that character is not included.

     The optional argument PADDING, if non-nil, is a padding character added at the beginning and end of the result string, to extend it to exactly WIDTH columns.  The padding character is used at the end of the result if it falls short of WIDTH.  It is also used at the beginning of the result if one multi-column character in STRING extends across the column START-COLUMN.

          (truncate-string-to-width "\tab\t" 12 4)
               => "ab"
          (truncate-string-to-width "\tab\t" 12 4 ?\ )
               => "    ab  "

Faces
=====

A face is a named collection of graphical attributes: font family, foreground color, background color, optional underlining, and many others.  Faces are used in Emacs to control the style of display of particular parts of the text or the frame.

Each face has its own face number, which distinguishes faces at low levels within Emacs.  However, for most purposes, you refer to faces in Lisp programs by their names.

 -- Function: facep object
     This function returns t if OBJECT is a face name symbol (or if it is a vector of the kind used internally to record face data).  It returns nil otherwise.

Each face name is meaningful for all frames, and by default it has the same meaning in all frames.  But you can arrange to give a particular face name a special meaning in one frame if you wish.

Standard Faces
--------------

This table lists all the standard faces and their uses.  Most of them are used for displaying certain parts of the frames or certain kinds of text; you can control how those places look by customizing these faces.

default
     This face is used for ordinary text.

mode-line
     This face is used for mode lines, and for menu bars when toolkit menus are not used---but only if mode-line-inverse-video is non-nil.

modeline
     This is an alias for the mode-line face, for compatibility with old Emacs versions.

header-line
     This face is used for the header lines of windows that have them.

menu
     This face controls the display of menus, both their colors and their font.  (This works only on certain systems.)

fringe
     This face controls the colors of window fringes, the thin areas on either side that are used to display continuation and truncation glyphs.

scroll-bar
     This face controls the colors for display of scroll bars.

tool-bar
     This face is used for display of the tool bar, if any.

region
     This face is used for highlighting the region in Transient Mark mode.

secondary-selection
     This face is used to show any secondary selection you have made.

highlight
     This face is meant to be used for highlighting for various purposes.

trailing-whitespace
     This face is used to display excess whitespace at the end of a line, if show-trailing-whitespace is non-nil.

In contrast, these faces are provided to change the appearance of text in specific ways.  You can use them on specific text, when you want the effects they produce.

bold
     This face uses a bold font, if possible.  It uses the bold variant of the frame's font, if it has one.  It's up to you to choose a default font that has a bold variant, if you want to use one.

italic
     This face uses the italic variant of the frame's font, if it has one.

bold-italic
     This face uses the bold italic variant of the frame's font, if it has one.

underline
     This face underlines text.

fixed-patch
     This face forces use of a particular fixed-width font.

variable-patch
     This face forces use of a particular variable-width font.  It's reasonable to customize this to use a different variable-width font, if you like, but you should not make it a fixed-width font.

 -- Variable: show-trailing-whitespace
     If this variable is non-nil, Emacs uses the trailing-whitespace face to display any spaces and tabs at the end of a line.

Defining Faces
--------------

The way to define a new face is with defface.  This creates a kind of customization item (see Customization) which the user can customize using the Customization buffer (see Easy Customization (The GNU Emacs Manual)).

 -- Macro: defface face spec doc [keyword value]...
     This declares FACE as a customizable face that defaults according to SPEC.  You should not quote the symbol FACE.  The argument DOC specifies the face documentation.  The keywords you can use in defface are the same ones that are meaningful in both defgroup and defcustom (see Common Keywords).

     When defface executes, it defines the face according to SPEC, then uses any customizations that were read from the init file (see Init File) to override that specification.

     The purpose of SPEC is to specify how the face should appear on different kinds of terminals.  It should be an alist whose elements have the form (DISPLAY ATTS).  Each element's CAR, DISPLAY, specifies a class of terminals.  The element's second element, ATTS, is a list of face attributes and their values; it specifies what the face should look like on that kind of terminal.  The possible attributes are defined in the value of custom-face-attributes.

     The DISPLAY part of an element of SPEC determines which frames the element applies to.  If more than one element of SPEC matches a given frame, the first matching element is the only one used for that frame.  There are two possibilities for DISPLAY:

     t
          This element of SPEC matches all frames.  Therefore, any subsequent elements of SPEC are never used.  Normally t is used in the last (or only) element of SPEC.

     a list
          If DISPLAY is a list, each element should have the form (CHARACTERISTIC VALUE...).  Here CHARACTERISTIC specifies a way of classifying frames, and the VALUEs are possible classifications which DISPLAY should apply to.  Here are the possible values of CHARACTERISTIC:

          type
               The kind of window system the frame uses---either x, pc (for the MS-DOS console), w32 (for MS Windows 9X/NT), or tty.

          class
               What kinds of colors the frame supports---either color, grayscale, or mono.

          background
               The kind of background---either light or dark.

          If an element of DISPLAY specifies more than one VALUE for a given CHARACTERISTIC, any of those values is acceptable.  If DISPLAY has more than one element, each element should specify a different CHARACTERISTIC; then each characteristic of the frame must match one of the VALUEs specified for it in DISPLAY.

Here's how the standard face region is defined:

     (defface region
       `((((type tty) (class color))
          (:background "blue" :foreground "white"))

         (((type tty) (class mono))
          (:inverse-video t))
         (((class color) (background dark))
          (:background "blue"))
         (((class color) (background light))
          (:background "lightblue"))
         (t (:background "gray")))

       "Basic face for highlighting the region."
       :group 'basic-faces)

Internally, defface uses the symbol property face-defface-spec to record the face attributes specified in defface, saved-face for the attributes saved by the user with the customization buffer, and face-documentation for the documentation string.

 -- User Option: frame-background-mode
     This option, if non-nil, specifies the background type to use for interpreting face definitions.  If it is dark, then Emacs treats all frames as if they had a dark background, regardless of their actual background colors.  If it is light, then Emacs treats all frames as if they had a light background.

Face Attributes
---------------

The effect of using a face is determined by a fixed set of face attributes.  This table lists all the face attributes, and what they mean.  Note that in general, more than one face can be specified for a given piece of text; when that happens, the attributes of all the faces are merged to specify how to display the text.  See Merging Faces.

In Emacs 21, any attribute in a face can have the value unspecified.  This means the face doesn't specify that attribute. In face merging, when the first face fails to specify a particular attribute, that means the next face gets a chance.  However, the default face must specify all attributes.

Some of these font attributes are meaningful only on certain kinds of displays---if your display cannot handle a certain attribute, the attribute is ignored.  (The attributes :family, :width, :height, :weight, and :slant correspond to parts of an X Logical Font Descriptor.)

:family
     Font family name, or fontset name (see Fontsets).  If you specify a font family name, the wild-card characters * and ? are allowed.

:width
     Relative proportionate width, also known as the character set width or set width.  This should be one of the symbols ultra-condensed, extra-condensed, condensed, semi-condensed, normal, semi-expanded, expanded, extra-expanded, or ultra-expanded.

:height
     Font height, an integer in units of 1/10 point.

:weight
     Font weight---a symbol from this series (from most dense to most faint): ultra-bold, extra-bold, bold, semi-bold, normal, semi-light, light, extra-light, or ultra-light.

     On a text-only terminal, any weight greater than normal is displayed as extra bright, and any weight less than normal is displayed as half-bright (This is provided the terminal supports the feature.)

     On a text-only terminal, any weight greater than normal is displayed as extra bright, and any weight less than normal is displayed as half-bright (provided the terminal supports the feature).

:slant
     Font slant---one of the symbols italic, oblique, normal, reverse-italic, or reverse-oblique.

     On a text-only terminal, slanted text is displayed as half-bright, if the terminal supports the feature.

:foreground
     Foreground color, a string.

:background
     Background color, a string.

:inverse-video
     Whether or not characters should be displayed in inverse video.  The value should be t (yes) or nil (no).

:stipple
     The background stipple, a bitmap.

     The value can be a string; that should be the name of a file containing external-format X bitmap data.  The file is found in the directories listed in the variable x-bitmap-file-path.

     Alternatively, the value can specify the bitmap directly, with a list of the form (WIDTH HEIGHT DATA).  Here, WIDTH and HEIGHT specify the size in pixels, and DATA is a string containing the raw bits of the bitmap, row by row.  Each row occupies (WIDTH + 7) / 8 consecutie bytes in the string (which should be a unibyte string for best results).

     If the value is nil, that means use no stipple pattern.

     Normally you do not need to set the stipple attribute, because it is used automatically to handle certain shades of gray.

:underline
     Whether or not characters should be underlined, and in what color.  If the value is t, underlining uses the foreground color of the face.  If the value is a string, underlining uses that color.  The value nil means do not underline.

:overline
     Whether or not characters should be overlined, and in what color. The value is used like that of :underline.

:strike-through
     Whether or not characters should be strike-through, and in what color.  The value is used like that of :underline.

:box
     Whether or not a box should be drawn around characters, its color, the width of the box lines, and 3D appearance.

Here are the possible values of the :box attribute, and what they mean:

nil
     Don't draw a box.

t
     Draw a box with lines of width 1, in the foreground color.

COLOR
     Draw a box with lines of width 1, in color COLOR.

(:line-width WIDTH :color COLOR :style STYLE)
     This way you can explicitly specify all aspects of the box.  The value WIDTH specifies the width of the lines to draw; it defaults to 1.

     The value COLOR specifies the color to draw with.  The default is the foreground color of the face for simple boxes, and the background color of the face for 3D boxes.

     The value STYLE specifies whether to draw a 3D box.  If it is released-button, the box looks like a 3D button that is not being pressed.  If it is pressed-button, the box looks like a 3D button that is being pressed.  If it is nil or omitted, a plain 2D box is used.

The attributes :overline, :strike-through and :box are new in Emacs 21.  The attributes :family, :height, :width, :weight, :slant are also new; previous versions used the following attributes, now semi-obsolete, to specify some of the same information:

:font
     This attribute specifies the font name.

:bold
     A non-nil value specifies a bold font.

:italic
     A non-nil value specifies an italic font.

For compatibility, you can still set these ``attributes'' in Emacs 21, even though they are not real face attributes.  Here is what that does:

:font
     You can specify an X font name as the ``value'' of this ``attribute''; that sets the :family, :width, :height, :weight, and :slant attributes according to the font name.

     If the value is a pattern with wildcards, the first font that matches the pattern is used to set these attributes.

:bold
     A non-nil makes the face bold; nil makes it normal. This actually works by setting the :weight attribute.

:italic
     A non-nil makes the face italic; nil makes it normal. This actually works by setting the :slant attribute.

 -- Variable: x-bitmap-file-path
     This variable specifies a list of directories for searching for bitmap files, for the :stipple attribute.

 -- Function: bitmap-spec-p object
     This returns t if OBJECT is a valid bitmap specification, suitable for use with :stipple. It returns nil otherwise.

Face Attribute Functions
------------------------

You can modify the attributes of an existing face with the following functions.  If you specify FRAME, they affect just that frame; otherwise, they affect all frames as well as the defaults that apply to new frames.

 -- Function: set-face-attribute face frame &rest arguments
     This function sets one or more attributes of face FACE for frame FRAME.  If FRAME is nil, it sets the attribute for all frames, and the defaults for new frames.

     The extra arguments ARGUMENTS specify the attributes to set, and the values for them.  They should consist of alternating attribute names (such as :family or :underline) and corresponding values. Thus,

          (set-face-attribute 'foo nil
                              :width :extended
                              :weight :bold
                              :underline "red")

     sets the attributes :width, :weight and :underline to the corresponding values.

 -- Function: face-attribute face attribute &optional frame
     This returns the value of the ATTRIBUTE attribute of face FACE on FRAME.  If FRAME is nil, that means the selected frame.

     If FRAME is t, the value is the default for FACE for new frames.

     For example,

          (face-attribute 'bold :weight)
               => bold

The functions above did not exist before Emacs 21.  For compatibility with older Emacs versions, you can use the following functions to set and examine the face attributes which existed in those versions.

 -- Function: set-face-foreground face color &optional frame
 -- Function: set-face-background face color &optional frame
     These functions set the foreground (or background, respectively) color of face FACE to COLOR.  The argument COLOR should be a string, the name of a color.

     Certain shades of gray are implemented by stipple patterns on black-and-white screens.

 -- Function: set-face-stipple face pattern &optional frame
     This function sets the background stipple pattern of face FACE to PATTERN.  The argument PATTERN should be the name of a stipple pattern defined by the X server, or nil meaning don't use stipple.

     Normally there is no need to pay attention to stipple patterns, because they are used automatically to handle certain shades of gray.

 -- Function: set-face-font face font &optional frame
     This function sets the font of face FACE.

     In Emacs 21, this actually sets the attributes :family, :width, :height, :weight, and :slant according to the font name FONT.

     In Emacs 20, this sets the font attribute.  Once you set the font explicitly, the bold and italic attributes cease to have any effect, because the precise font that you specified is used.

 -- Function: set-face-bold-p face bold-p &optional frame
     This function specifies whether FACE should be bold.  If BOLD-P is non-nil, that means yes; nil means no.

     In Emacs 21, this sets the :weight attribute. In Emacs 20, it sets the :bold attribute.

 -- Function: set-face-italic-p face italic-p &optional frame
     This function specifies whether FACE should be italic.  If ITALIC-P is non-nil, that means yes; nil means no.

     In Emacs 21, this sets the :slant attribute. In Emacs 20, it sets the :italic attribute.

 -- Function: set-face-underline-p face underline-p &optional frame
     This function sets the underline attribute of face FACE. Non-nil means do underline; nil means don't.

 -- Function: invert-face face &optional frame
     This function inverts the :inverse-video attribute of face FACE.  If the attribute is nil, this function sets it to t, and vice versa.

These functions examine the attributes of a face.  If you don't specify FRAME, they refer to the default data for new frames. They return the symbol unspecified if the face doesn't define any value for that attribute.

 -- Function: face-foreground face &optional frame
 -- Function: face-background face &optional frame
     These functions return the foreground color (or background color, respectively) of face FACE, as a string.

 -- Function: face-stipple face &optional frame
     This function returns the name of the background stipple pattern of face FACE, or nil if it doesn't have one.

 -- Function: face-font face &optional frame
     This function returns the name of the font of face FACE.

 -- Function: face-bold-p face &optional frame
     This function returns t if FACE is bold---that is, if it is bolder than normal.  It returns nil otherwise.

 -- Function: face-italic-p face &optional frame
     This function returns t if FACE is italic or oblique, nil otherwise.

 -- Function: face-underline-p face &optional frame
     This function returns the :underline attribute of face FACE.

 -- Function: face-inverse-video-p face &optional frame
     This function returns the :inverse-video attribute of face FACE.

Merging Faces for Display
-------------------------

Here are the ways to specify which faces to use for display of text:

  * With defaults.  The default face is used as the ultimate default for all text.  (In Emacs 19 and 20, the default face is used only when no other face is specified.)

     For a mode line or header line, the face modeline or header-line is used just before default.

  * With text properties.  A character can have a face property; if so, the faces and face attributes specified there apply.  See Special Properties.

     If the character has a mouse-face property, that is used instead of the face property when the mouse is ``near enough'' to the character.

  * With overlays.  An overlay can have face and mouse-face properties too; they apply to all the text covered by the overlay.

  * With a region that is active.  In Transient Mark mode, the region is highlighted with the face region (see Standard Faces).

  * With special glyphs.  Each glyph can specify a particular face number.  See Glyphs.

If these various sources together specify more than one face for a particular character, Emacs merges the attributes of the various faces specified.  The attributes of the faces of special glyphs come first; then comes the face for region highlighting, if appropriate; then come attributes of faces from overlays, followed by those from text properties, and last the default face.

When multiple overlays cover one character, an overlay with higher priority overrides those with lower priority.  See Overlays.

In Emacs 20, if an attribute such as the font or a color is not specified in any of the above ways, the frame's own font or color is used.  In newer Emacs versions, this cannot happen, because the default face specifies all attributes---in fact, the frame's own font and colors are synonymous with those of the default face.

Font Selection
--------------

Selecting a font means mapping the specified face attributes for a character to a font that is available on a particular display.  The face attributes, as determined by face merging, specify most of the font choice, but not all.  Part of the choice depends on what character it is.

For multibyte characters, typically each font covers only one character set.  So each character set (see Character Sets) specifies a registry and encoding to use, with the character set's x-charset-registry property.  Its value is a string containing the registry and the encoding, with a dash between them:

     (plist-get (charset-plist 'latin-iso8859-1)
                'x-charset-registry)
          => "ISO8859-1"

Unibyte text does not have character sets, so displaying a unibyte character takes the registry and encoding from the variable face-default-registry.

 -- Variable: face-default-registry
     This variable specifies which registry and encoding to use in choosing fonts for unibyte characters.  The value is initialized at Emacs startup time from the font the user specified for Emacs.

If the face specifies a fontset name, that fontset determines a pattern for fonts of the given charset.  If the face specifies a font family, a font pattern is constructed.

Emacs tries to find an available font for the given face attributes and character's registry and encoding.  If there is a font that matches exactly, it is used, of course.  The hard case is when no available font exactly fits the specification.  Then Emacs looks for one that is ``close''---one attribute at a time.  You can specify the order to consider the attributes.

 -- Variable: face-font-selection-order
     This variable specifies the order of importance of the face attributes :width, :height, :weight, and :slant.  The value should be a list containing those four symbols, in order of decreasing importance.

     Font selection first finds the best available matches for the first attribute listed; then, among the fonts which are best in that way, it searches for the best matches in the second attribute, and so on.

     The attributes :weight and :width have symbolic values in a range centered around normal.  Matches that are more extreme (farther from normal) are somewhat preferred to matches that are less extreme (closer to normal); this is designed to ensure that non-normal faces contrast with normal ones, whenever possible.

     The default is (:width :height :weight :slant), which means first find the fonts closest to the specified :width, then---among the fonts with that width---find a best match for the specified font height, and so on.

     One example of a case where this variable makes a difference is when the default font has no italic equivalent.  With the default ordering, the italic face will use a non-italic font that is similar to the default one.  But if you put :slant before :height, the italic face will use an italic font, even if its height is not quite right.

 -- Variable: face-alternative-font-family-alist
     This variable lets you specify alternative font families to try, if a given family is specified and doesn't exist.  Each element should have this form:

          (FAMILY ALTERNATE-FAMILIES...)

     If FAMILY is specified but not available, Emacs will try the other families given in ALTERNATE-FAMILIES, one by one, until it finds a family that does exist.

Emacs can make use of scalable fonts, but by default it does not use them, since the use of too many or too big scalable fonts can crash XFree86 servers.

 -- Variable: scalable-fonts-allowed
     This variable controls which scalable fonts to use.  A value of nil, the default, means do not use scalable fonts.  t means to use any scalable font that seems appropriate for the text.

     Otherwise, the value must be a list of regular expressions.  Then a scalable font is enabled for use if its name matches any regular expression in the list.  For example,

          (setq scalable-fonts-allowed '("muleindian-2$"))

     allows the use of scalable fonts with registry muleindian-2.

 -- Function: clear-face-cache &optional unload-p
     This function clears the face cache for all frames. If UNLOAD-P is non-nil, that means to unload all unused fonts as well.

Functions for Working with Faces
--------------------------------

Here are additional functions for creating and working with faces.

 -- Function: make-face name
     This function defines a new face named NAME, initially with all attributes nil.  It does nothing if there is already a face named NAME.

 -- Function: face-list
     This function returns a list of all defined face names.

 -- Function: copy-face old-face new-name &optional frame new-frame
     This function defines the face NEW-NAME as a copy of the existing face named OLD-FACE.  It creates the face NEW-NAME if that doesn't already exist.

     If the optional argument FRAME is given, this function applies only to that frame.  Otherwise it applies to each frame individually, copying attributes from OLD-FACE in each frame to NEW-FACE in the same frame.

     If the optional argument NEW-FRAME is given, then copy-face copies the attributes of OLD-FACE in FRAME to NEW-NAME in NEW-FRAME.

 -- Function: face-id face
     This function returns the face number of face FACE.

 -- Function: face-documentation face
     This function returns the documentation string of face FACE, or nil if none was specified for it.

 -- Function: face-equal face1 face2 &optional frame
     This returns t if the faces FACE1 and FACE2 have the same attributes for display.

 -- Function: face-differs-from-default-p face &optional frame
     This returns t if the face FACE displays differently from the default face.  A face is considered to be ``the same'' as the default face if each attribute is either the same as that of the default face, or unspecified (meaning to inherit from the default).

Automatic Face Assignment
-------------------------

Starting with Emacs 21, a hook is available for automatically assigning faces to text in the buffer.  This hook is used for part of the implementation of Font-Lock mode.

 -- Variable: fontification-functions
     This variable holds a list of functions that are called by Emacs redisplay as needed to assign faces automatically to text in the buffer.

     The functions are called in the order listed, with one argument, a buffer position POS.  Each function should attempt to assign faces to the text in the current buffer starting at POS.

     Each function should record the faces they assign by setting the face property.  It should also add a non-nil fontified property for all the text it has assigned faces to. That property tells redisplay that faces have been assigned to that text already.

     It is probably a good idea for each function to do nothing if the character after POS already has a non-nil fontified property, but this is not required.  If one function overrides the assignments made by a previous one, the properties as they are after the last function finishes are the ones that really matter.

     For efficiency, we recommend writing these functions so that they usually assign faces to around 400 to 600 characters at each call.

Looking Up Fonts
----------------

 -- Function: x-list-fonts pattern &optional face frame maximum
     This function returns a list of available font names that match PATTERN.  If the optional arguments FACE and FRAME are specified, then the list is limited to fonts that are the same size as FACE currently is on FRAME.

     The argument PATTERN should be a string, perhaps with wildcard characters: the * character matches any substring, and the ? character matches any single character.  Pattern matching of font names ignores case.

     If you specify FACE and FRAME, FACE should be a face name (a symbol) and FRAME should be a frame.

     The optional argument MAXIMUM sets a limit on how many fonts to return.  If this is non-nil, then the return value is truncated after the first MAXIMUM matching fonts.  Specifying a small value for MAXIMUM can make this function much faster, in cases where many fonts match the pattern.

These additional functions are available starting in Emacs 21.

 -- Function: x-family-fonts &optional family frame
     This function returns a list describing the available fonts for family FAMILY on FRAME.  If FAMILY is omitted or nil, this list applies to all families, and therefore, it contains all available fonts.  Otherwise, FAMILY must be a string; it may contain the wildcards ? and *.

     The list describes the display that FRAME is on; if FRAME is omitted or nil, it applies to the selected frame's display.

     The list contains a vector of the following form for each font:

          [FAMILY WIDTH POINT-SIZE WEIGHT SLANT
           FIXED-P FULL REGISTRY-AND-ENCODING]

     The first five elements correspond to face attributes; if you specify these attributes for a face, it will use this font.

     The last three elements give additional information about the font. FIXED-P is non-nil if the font is fixed-pitch.  FULL is the full name of the font, and REGISTRY-AND-ENCODING is a string giving the registry and encoding of the font.

     The result list is sorted according to the current face font sort order.

 -- Function: x-font-family-list &optional frame
     This function returns a list of the font families available for FRAME's display.  If FRAME is omitted or nil, it describes the selected frame's display.

     The value is a list of elements of this form:

          (FAMILY . FIXED-P)

     Here FAMILY is a font family, and FIXED-P is non-nil if fonts of that family are fixed-pitch.

 -- Variable: font-list-limit
     This variable specifies maximum number of fonts to consider in font matching.  The function x-family-fonts will not return more than that many fonts, and font selection will consider only that many fonts when searching a matching font for face attributes.  The default is currently 100.

Fontsets
--------

A fontset is a list of fonts, each assigned to a range of character codes.  An individual font cannot display the whole range of characters that Emacs supports, but a fontset can.  Fontsets have names, just as fonts do, and you can use a fontset name in place of a font name when you specify the ``font'' for a frame or a face.  Here is information about defining a fontset under Lisp program control.

 -- Function: create-fontset-from-fontset-spec fontset-spec &optional style-variant-p noerror
     This function defines a new fontset according to the specification string FONTSET-SPEC.  The string should have this format:

          FONTPATTERN, [CHARSETNAME:FONTNAME]...

     Whitespace characters before and after the commas are ignored.

     The first part of the string, FONTPATTERN, should have the form of a standard X font name, except that the last two fields should be fontset-ALIAS.

     The new fontset has two names, one long and one short.  The long name is FONTPATTERN in its entirety.  The short name is fontset-ALIAS.  You can refer to the fontset by either name.  If a fontset with the same name already exists, an error is signaled, unless NOERROR is non-nil, in which case this function does nothing.

     If optional argument STYLE-VARIANT-P is non-nil, that says to create bold, italic and bold-italic variants of the fontset as well. These variant fontsets do not have a short name, only a long one, which is made by altering FONTPATTERN to indicate the bold or italic status.

     The specification string also says which fonts to use in the fontset. See below for the details.

The construct CHARSET:FONT specifies which font to use (in this fontset) for one particular character set.  Here, CHARSET is the name of a character set, and FONT is the font to use for that character set.  You can use this construct any number of times in the specification string.

For the remaining character sets, those that you don't specify explicitly, Emacs chooses a font based on FONTPATTERN: it replaces fontset-ALIAS with a value that names one character set. For the ASCII character set, fontset-ALIAS is replaced with ISO8859-1.

In addition, when several consecutive fields are wildcards, Emacs collapses them into a single wildcard.  This is to prevent use of auto-scaled fonts.  Fonts made by scaling larger fonts are not usable for editing, and scaling a smaller font is not useful because it is better to use the smaller font in its own size, which Emacs does.

Thus if FONTPATTERN is this,

     -*-fixed-medium-r-normal-*-24-*-*-*-*-*-fontset-24

the font specification for ASCII characters would be this:

     -*-fixed-medium-r-normal-*-24-*-ISO8859-1

and the font specification for Chinese GB2312 characters would be this:

     -*-fixed-medium-r-normal-*-24-*-gb2312*-*

You may not have any Chinese font matching the above font specification.  Most X distributions include only Chinese fonts that have song ti or fangsong ti in the FAMILY field.  In such a case, Fontset-N can be specified as below:

     Emacs.Fontset-0: -*-fixed-medium-r-normal-*-24-*-*-*-*-*-fontset-24,\
             chinese-gb2312:-*-*-medium-r-normal-*-24-*-gb2312*-*

Then, the font specifications for all but Chinese GB2312 characters have fixed in the FAMILY field, and the font specification for Chinese GB2312 characters has a wild card * in the FAMILY field.

The display Property
====================

The display text property (or overlay property) is used to insert images into text, and also control other aspects of how text displays.  These features are available starting in Emacs 21.  The value of the display property should be a display specification, or a list or vector containing several display specifications.  The rest of this section describes several kinds of display specifications and what they mean.

Specified Spaces
----------------

To display a space of specified width and/or height, use a display specification of the form (space . PROPS), where PROPS is a property list (a list of alternating properties and values).  You can put this property on one or more consecutive characters; a space of the specified height and width is displayed in place of all of those characters.  These are the properties you can use to specify the weight of the space:

:width WIDTH
     Specifies that the space width should be WIDTH times the normal character width.  WIDTH can be an integer or floating point number.

:relative-width FACTOR
     Specifies that the width of the stretch should be computed from the first character in the group of consecutive characters that have the same display property.  The space width is the width of that character, multiplied by FACTOR.

:align-to HPOS
     Specifies that the space should be wide enough to reach HPOS.  The value HPOS is measured in units of the normal character width.  It may be an interer or a floating point number.

Exactly one of the above properties should be used.  You can also specify the height of the space, with other properties:

:height HEIGHT
     Specifies the height of the space, as HEIGHT, measured in terms of the normal line height.

:relative-height FACTOR
     Specifies the height of the space, multiplying the ordinary height of the text having this display specification by FACTOR.

:ascent ASCENT
     Specifies that ASCENT percent of the height of the space should be considered as the ascent of the space---that is, the part above the baseline.  The value of ASCENT must be a non-negative number no greater than 100.

You should not use both :height and :relative-height together.

Other Display Specifications
----------------------------

(image . IMAGE-PROPS)
     This is in fact an image descriptor (see Images).  When used as a display specification, it means to display the image instead of the text that has the display specification.

(space-width FACTOR)
     This display specification affects all the space characters within the text that has the specification.  It displays all of these spaces FACTOR times as wide as normal.  The element FACTOR should be an integer or float.  Characters other than spaces are not affected at all; in particular, this has no effect on tab characters.

(height HEIGHT)
     This display specification makes the text taller or shorter. Here are the possibilities for HEIGHT:

     (+ N)
          This means to use a font that is N steps larger.  A ``step'' is defined by the set of available fonts---specifically, those that match what was otherwise specified for this text, in all attributes except height.  Each size for which a suitable font is available counts as another step.  N should be an integer.

     (- N)
          This means to use a font that is N steps smaller.

     a number, FACTOR
          A number, FACTOR, means to use a font that is FACTOR times as tall as the default font.

     a symbol, FUNCTION
          A symbol is a function to compute the height.  It is called with the current height as argument, and should return the new height to use.

     anything else, FORM
          If the HEIGHT value doesn't fit the previous possibilities, it is a form.  Emacs evaluates it to get the new height, with the symbol height bound to the current specified font height.

(raise FACTOR)
     This kind of display specification raises or lowers the text it applies to, relative to the baseline of the line.

     FACTOR must be a number, which is interpreted as a multiple of the height of the affected text.  If it is positive, that means to display the characters raised.  If it is negative, that means to display them lower down.

     If the text also has a height display specification, that does not affect the amount of raising or lowering, which is based on the faces used for the text.

Displaying in the Margins
-------------------------

A buffer can have blank areas called display margins on the left and on the right.  Ordinary text never appears in these areas, but you can put things into the display margins using the display property.

To put text in the left or right display margin of the window, use a display specification of the form (margin right-margin) or (margin left-margin) on it.  To put an image in a display margin, use that display specification along with the display specification for the image.

Before the display margins can display anything, you must give them a nonzero width.  The usual way to do that is to set these variables:

 -- Variable: left-margin-width
     This variable specifies the width of the left margin. It is buffer-local in all buffers.

 -- Variable: right-margin-width
     This variable specifies the width of the right margin. It is buffer-local in all buffers.

Setting these variables does not immediately affect the window.  These variables are checked when a new buffer is displayed in the window. Thus, you can make changes take effect by calling set-window-buffer.

You can also set the margin widths immediately.

 -- Function: set-window-margins window left right
     This function specifies the margin widths for window WINDOW. The argument LEFT controls the left margin and RIGHT controls the right margin.

 -- Function: window-margins &optional window
     This function returns the left and right margins of WINDOW as a cons cell of the form (LEFT . RIGHT). If WINDOW is nil, the selected window is used.

Conditional Display Specifications
----------------------------------

You can make any display specification conditional.  To do that, package it in another list of the form (when CONDITION SPEC).  Then the specification SPEC applies only when CONDITION evaluates to a non-nil value.  During the evaluation, point is temporarily set at the end position of the text having this conditional display specification.

Images
======

To display an image in an Emacs buffer, you must first create an image descriptor, then use it as a display specifier in the display property of text that is displayed (see Display Property).  Like the display property, this feature is available starting in Emacs 21.

Emacs can display a number of different image formats; some of them are supported only if particular support libraries are installed on your machine.  The supported image formats include XBM, XPM (needing the libraries libXpm version 3.4k and libz), GIF (needing libungif 4.1.0), Postscript, PBM, JPEG (needing the libjpeg library version v6a), TIFF (needing libtiff v3.4), and PNG (needing libpng 1.0.2).

You specify one of these formats with an image type symbol.  The image type symbols are xbm, xpm, gif, postscript, pbm, jpeg, tiff, and png.

 -- Variable: image-types
     This variable contains a list of those image type symbols that are supported in the current configuration.

Image Descriptors
-----------------

An image description is a list of the form (image . PROPS), where PROPS is a property list containing alternating keyword symbols (symbols whose names start with a colon) and their values.  You can use any Lisp object as a property, but the only properties that have any special meaning are certain symbols, all of them keywords.

Every image descriptor must contain the property :type TYPE to specify the format of the image.  The value of TYPE should be an image type symbol; for example, xpm for an image in XPM format.

Here is a list of other properties that are meaningful for all image types:

:ascent ASCENT
     The :ascent property specifies the percentage of the image's height to use for its ascent---that is, the part above the baseline.  The value, ASCENT, must be a number in the range 0 to 100.  If this property is omitted, it defaults to 50.

:margin MARGIN
     The :margin property specifies how many pixels to add as an extra margin around the image.  The value, MARGIN, must be a non-negative number; if it is not specified, the default is zero.

:relief RELIEF
     The :relief property, if non-nil, adds a shadow rectangle around the image.  The value, RELIEF, specifies the width of the shadow lines, in pixels.  If RELIEF is negative, shadows are drawn so that the image appears as a pressed button; otherwise, it appears as an unpressed button.

:algorithm ALGORITHM
     The :algorithm property, if non-nil, specifies a conversion algorithm that should be applied to the image before it is displayed; the value, ALGORITHM, specifies which algorithm.

     Currently, the only meaningful value for ALGORITHM (aside from nil) is laplace; this applies the Laplace edge detection algorithm, which blurs out small differences in color while highlighting larger differences.  People sometimes consider this useful for displaying the image for a ``disabled'' button.

:heuristic-mask TRANSPARENT-COLOR
     The :heuristic-mask property, if non-nil, specifies that a certain color in the image should be transparent.  Each pixel where this color appears will actually allow the frame's background to show through.

     If TRANSPARENT-COLOR is t, then determine the transparent color by looking at the four corners of the image.  This uses the color that occurs most frequently near the corners as the transparent color.

     Otherwise, HEURISTIC-MASK should specify the transparent color directly, as a list of three integers in the form (RED GREEN BLUE).

:file FILE
     The :file property specifies to load the image from file FILE.  If FILE is not an absolute file name, it is expanded in data-directory.

:data DATA
     The :data property specifies the actual contents of the image. Each image must use either :data or :file, but not both. However, only certain image types support :data; for other types, you must use :file.

     The formats that support :data include XBM and XPM. Before using :data, see the section describing the specific format you wish to use for further information.

XBM Images
----------

To use XBM format, specify xbm as the image type.  This image format doesn't require an external library, so images of this type are always supported.

Additional image properties supported for the xbm image type are:

:foreground FOREGROUND
     The value, FOREGROUND, should be a string specifying the image foreground color.  This color is used for each pixel in the XBM that is 1.  The default is the frame's foreground color.

:background BACKGROUND
     The value, BACKGROUND, should be a string specifying the image background color.  This color is used for each pixel in the XBM that is 0.  The default is the frame's background color.

You can specify an XBM image using data within Emacs instead of an external file.  To do this, don't use :file; instead, use the following three properties (all of them):

:width WIDTH
     The value, WIDTH, specifies the width the image in pixels.

:height HEIGHT
     The value, HEIGHT, specifies the height of the image in pixels.

:data DATA
     The value, DATA, is normally a string or a bool-vector.  Either way, it must contain enough bits for the area of the image: at least WIDTH * height.

     Alternatively, DATA can be a vector of strings or bool-vectors, each specifying one line of the image.

XPM Images
----------

To use XPM format, specify xpm as the image type.  These additional image properties are meaningful with the xpm image type:

:color-symbols SYMBOLS
     The value, SYMBOLS, should be an alist whose elements have the form (NAME . COLOR).  In each element, NAME is the name of a color as it appears in the image file, and COLOR specifies the actual color to use for displaying that name.

:data DATA
     XPM images can be displayed from data instead of files.  In that case, use the :data property instead of the :file property.

     The value DATA must be a string containing an XPM image.  The contents of the string have same format as an external XPM file.

GIF Images
----------

For GIF images, specify image type gif.  Because of the patents in the US covering the LZW algorithm, the continued use of GIF format is a problem for the whole Internet; to end this problem, it is a good idea for everyone, even outside the US, to stop using GIFS right away (http://www.burnallgifs.org/).  But if you still want to use them, Emacs can display them.

:index INDEX
     You can use :index to specify one image from a GIF file that contains more than one image.  This property specifies use of image number INDEX from the file.  An error is signaled if the GIF file doesn't contain an image with index INDEX.

Postscript Images
-----------------

To use Postscript for an image, specify image type postscript. This works only if you have Ghostscript installed.  You must always use these three properties:

:pt-width WIDTH
     The value, WIDTH, specifies the width of the image measured in points (1/72 inch).  WIDTH must be an integer.

:pt-height HEIGHT
     The value, HEIGHT, specifies the height of the image in points (1/72 inch).  HEIGHT must be an integer.

:bounding-box BOX
     The value, BOX, must be a list or vector of four integers, which specifying the bounding box of the Postscript image, analogous to the BoundingBox comment found in Postscript files.

          %%BoundingBox: 22 171 567 738

Other Image Types
-----------------

For PBM images, specify image type pbm.  Color, gray-scale and monochromatic images are supported.

For JPEG images, specify image type jpeg.  There are no additional image properties defined.

For TIFF images, specify image type tiff.

For PNG images, specify image type png.

Defining Images
---------------

The functions create-image and defimage provide convenient ways to create image descriptors.

 -- Function: create-image file &optional type &rest props
     This function creates and returns an image descriptor which uses the data in FILE.

     The optional argument TYPE is a symbol specifying the image type. If TYPE is omitted or nil, create-image tries to determine the image type from the file's first few bytes, or else from the file's name.

     The remaining arguments, PROPS, specify additional image properties---for example,

          (create-image "foo.xpm" 'xpm :heuristic-mask t)

     The function returns nil if images of this type are not supported.  Otherwise it returns an image descriptor.

 -- Macro: defimage variable doc &rest specs
     This macro defines VARIABLE as an image name.  The second argument, DOC, is an optional documentation string.  The remaining arguments, SPECS, specify alternative ways to display the image.

     Each argument in SPECS has the form of a property list, and each one should specify at least the :type property and the :file property.  Here is an example:

          (defimage test-image
            '((:type xpm :file "~/test1.xpm")
              (:type xbm :file "~/test1.xbm")))

     defimage tests each argument, one by one, to see if it is usable---that is, if the type is supported and the file exists.  The first usable argument is used to make an image descriptor which is stored in the variable VARIABLE.

     If none of the alternatives will work, then VARIABLE is defined as nil.

Showing Images
--------------

You can use an image descriptor by setting up the display property yourself, but it is easier to use the functions in this section.

 -- Function: insert-image image string &optional area
     This function inserts IMAGE in the current buffer at point.  The value IMAGE should be an image descriptor; it could be a value returned by create-image, or the value of a symbol defined with defimage.  The argument STRING specifies the text to put in the buffer to hold the image.

     The argument AREA specifies whether to put the image in a margin. If it is left-margin, the image appears in the left margin; right-margin specifies the right margin.  If AREA is nil or omitted, the image is displayed at point within the buffer's text.

     Internally, this function inserts STRING in the buffer, and gives it a display property which specifies IMAGE.  See Display Property.

 -- Function: put-image image pos string &optional area
     This function puts image IMAGE in front of POS in the current buffer.  The argument POS should be an integer or a marker.  It specifies the buffer position where the image should appear. The argument STRING specifies the text that should hold the image.

     The argument IMAGE must be an image descriptor, perhaps returned by create-image or stored by defimage.

     The argument AREA specifies whether to put the image in a margin. If it is left-margin, the image appears in the left margin; right-margin specifies the right margin.  If AREA is nil or omitted, the image is displayed at point within the buffer's text.

     Internally, this function creates an overlay, and gives it a before-string property containing text that has a display property whose value is the image.  (Whew!)

 -- Function: remove-images start end &optional buffer
     This function removes images in BUFFER between positions START and END.  If BUFFER is omitted or nil, images are removed from the current buffer.

     This remove only images that were put into BUFFER the way put-image does it, not images that were inserted with insert-image or in other ways.

Image Cache
-----------

Emacs stores images in an image cache when it displays them, so it can display them again more efficiently.  It removes an image from the cache when it hasn't been displayed for a specified period of time.

 -- Variable: image-cache-eviction-delay
     This variable specifies the number of seconds an image can remain in the cache without being displayed.  When an image is not displayed for this length of time, Emacs removes it from the image cache.

     If the value is nil, Emacs does not remove images from the cache except when you explicitly clear it.  This mode can be useful for debugging.

 -- Function: clear-image-cache &optional frame
     This function clears the image cache.  If FRAME is non-nil, only the cache for that frame is cleared.  Otherwise all frames' caches are cleared.

Blinking Parentheses
====================

This section describes the mechanism by which Emacs shows a matching open parenthesis when the user inserts a close parenthesis.

 -- Variable: blink-paren-function
     The value of this variable should be a function (of no arguments) to be called whenever a character with close parenthesis syntax is inserted. The value of blink-paren-function may be nil, in which case nothing is done.

 -- User Option: blink-matching-paren
     If this variable is nil, then blink-matching-open does nothing.

 -- User Option: blink-matching-paren-distance
     This variable specifies the maximum distance to scan for a matching parenthesis before giving up.

 -- User Option: blink-matching-delay
     This variable specifies the number of seconds for the cursor to remain at the matching parenthesis.  A fraction of a second often gives good results, but the default is 1, which works on all systems.

 -- Command: blink-matching-open
     This function is the default value of blink-paren-function.  It assumes that point follows a character with close parenthesis syntax and moves the cursor momentarily to the matching opening character.  If that character is not already on the screen, it displays the character's context in the echo area.  To avoid long delays, this function does not search farther than blink-matching-paren-distance characters.

     Here is an example of calling this function explicitly.

          (defun interactive-blink-matching-open ()
            "Indicate momentarily the start of sexp before point."
            (interactive)

            (let ((blink-matching-paren-distance
                   (buffer-size))
                  (blink-matching-paren t))
              (blink-matching-open)))

Inverse Video
=============

 -- User Option: inverse-video
     This variable controls whether Emacs uses inverse video for all text on the screen.  Non-nil means yes, nil means no.  The default is nil.

 -- User Option: mode-line-inverse-video
     This variable controls the use of inverse video for mode lines and menu bars.  If it is non-nil, then these lines are displayed in inverse video.  Otherwise, they lines are displayed normally, just like other text.  The default is t.

     For window frames, this feature actually applies the face named mode-line; that face is normally set up as the inverse of the default face, unless you change it.

Usual Display Conventions
=========================

The usual display conventions define how to display each character code.  You can override these conventions by setting up a display table (see Display Tables).  Here are the usual display conventions:

  * Character codes 32 through 126 map to glyph codes 32 through 126. Normally this means they display as themselves.

  * Character code 9 is a horizontal tab.  It displays as whitespace up to a position determined by tab-width.

  * Character code 10 is a newline.

  * All other codes in the range 0 through 31, and code 127, display in one of two ways according to the value of ctl-arrow.  If it is non-nil, these codes map to sequences of two glyphs, where the first glyph is the ASCII code for ^.  (A display table can specify a glyph to use instead of ^.)  Otherwise, these codes map just like the codes in the range 128 to 255.

     On MS-DOS terminals, Emacs arranges by default for the character code 127 to be mapped to the glyph code 127, which normally displays as an empty polygon.  This glyph is used to display non-ASCII characters that the MS-DOS terminal doesn't support.  See MS-DOS and MULE (The GNU Emacs Manual).

  * Character codes 128 through 255 map to sequences of four glyphs, where the first glyph is the ASCII code for \, and the others are digit characters representing the character code in octal.  (A display table can specify a glyph to use instead of \.)

  * Multibyte character codes above 256 are displayed as themselves, or as a question mark or empty box if the terminal cannot display that character.

The usual display conventions apply even when there is a display table, for any character whose entry in the active display table is nil.  Thus, when you set up a display table, you need only specify the characters for which you want special behavior.

These display rules apply to carriage return (character code 13), when it appears in the buffer.  But that character may not appear in the buffer where you expect it, if it was eliminated as part of end-of-line conversion (see Coding System Basics).

These variables affect the way certain characters are displayed on the screen.  Since they change the number of columns the characters occupy, they also affect the indentation functions.  These variables also affect how the mode line is displayed; if you want to force redisplay of the mode line using the new values, call the function force-mode-line-update (see Mode Line Format).

 -- User Option: ctl-arrow
     This buffer-local variable controls how control characters are displayed.  If it is non-nil, they are displayed as a caret followed by the character: ^A.  If it is nil, they are displayed as a backslash followed by three octal digits: \001.

 -- Variable: default-ctl-arrow
     The value of this variable is the default value for ctl-arrow in buffers that do not override it.  See Default Value.

 -- User Option: indicate-empty-lines
     When this is non-nil, Emacs displays a special glyph in each empty line at the end of the buffer, on terminals that support it (window systems).

 -- User Option: tab-width
     The value of this variable is the spacing between tab stops used for displaying tab characters in Emacs buffers.  The value is in units of columns, and the default is 8.  Note that this feature is completely independent of the user-settable tab stops used by the command tab-to-tab-stop.  See Indent Tabs.

Display Tables
==============

You can use the display table feature to control how all possible character codes display on the screen.  This is useful for displaying European languages that have letters not in the ASCII character set.

The display table maps each character code into a sequence of glyphs, each glyph being a graphic that takes up one character position on the screen.  You can also define how to display each glyph on your terminal, using the glyph table.

Display tables affect how the mode line is displayed; if you want to force redisplay of the mode line using a new display table, call force-mode-line-update (see Mode Line Format).

Display Table Format
--------------------

A display table is actually a char-table (see Char-Tables) with display-table as its subtype.

 -- Function: make-display-table
     This creates and returns a display table.  The table initially has nil in all elements.

The ordinary elements of the display table are indexed by character codes; the element at index C says how to display the character code C.  The value should be nil or a vector of glyph values (see Glyphs).  If an element is nil, it says to display that character according to the usual display conventions (see Usual Display).

If you use the display table to change the display of newline characters, the whole buffer will be displayed as one long ``line.''

The display table also has six ``extra slots'' which serve special purposes.  Here is a table of their meanings; nil in any slot means to use the default for that slot, as stated below.

0
     The glyph for the end of a truncated screen line (the default for this is $).  See Glyphs.  Newer Emacs versions, on some platforms, display arrows to indicate truncation---the display table has no effect in these situations.

1
     The glyph for the end of a continued line (the default is \). Newer Emacs versions, on some platforms, display curved arrows to indicate truncation---the display table has no effect in these situations.

2
     The glyph for indicating a character displayed as an octal character code (the default is \).

3
     The glyph for indicating a control character (the default is ^).

4
     A vector of glyphs for indicating the presence of invisible lines (the default is ...).  See Selective Display.

5
     The glyph used to draw the border between side-by-side windows (the default is |).  See Splitting Windows.  This takes effect only when there are no scroll bars; if scroll bars are supported and in use, a scroll bar separates the two windows.

For example, here is how to construct a display table that mimics the effect of setting ctl-arrow to a non-nil value:

     (setq disptab (make-display-table))
     (let ((i 0))
       (while (< i 32)
         (or (= i ?\t) (= i ?\n)
             (aset disptab i (vector ?^ (+ i 64))))
         (setq i (1+ i)))
       (aset disptab 127 (vector ?^ ??)))

 -- Function: display-table-slot display-table slot
     This function returns the value of the extra slot SLOT of DISPLAY-TABLE.  The argument SLOT may be a number from 0 to 5 inclusive, or a slot name (symbol).  Valid symbols are truncation, wrap, escape, control, selective-display, and vertical-border.

 -- Function: set-display-table-slot display-table slot value
     This function stores VALUE in the extra slot SLOT of DISPLAY-TABLE.  The argument SLOT may be a number from 0 to 5 inclusive, or a slot name (symbol).  Valid symbols are truncation, wrap, escape, control, selective-display, and vertical-border.

 -- Function: describe-display-table display-table
     This function displays a description of the display table DISPLAY-TABLE in a help buffer.

 -- Command: describe-current-display-table
     This command displays a description of the current display table in a help buffer.

Active Display Table
--------------------

Each window can specify a display table, and so can each buffer.  When a buffer B is displayed in window W, display uses the display table for window W if it has one; otherwise, the display table for buffer B if it has one; otherwise, the standard display table if any.  The display table chosen is called the active display table.

 -- Function: window-display-table window
     This function returns WINDOW's display table, or nil if WINDOW does not have an assigned display table.

 -- Function: set-window-display-table window table
     This function sets the display table of WINDOW to TABLE. The argument TABLE should be either a display table or nil.

 -- Variable: buffer-display-table
     This variable is automatically buffer-local in all buffers; its value in a particular buffer specifies the display table for that buffer.  If it is nil, that means the buffer does not have an assigned display table.

 -- Variable: standard-display-table
     This variable's value is the default display table, used whenever a window has no display table and neither does the buffer displayed in that window.  This variable is nil by default.

If there is no display table to use for a particular window---that is, if the window specifies none, its buffer specifies none, and standard-display-table is nil---then Emacs uses the usual display conventions for all character codes in that window.  See Usual Display.

A number of functions for changing the standard display table are defined in the library disp-table.

Glyphs
------

A glyph is a generalization of a character; it stands for an image that takes up a single character position on the screen.  Glyphs are represented in Lisp as integers, just as characters are.

The meaning of each integer, as a glyph, is defined by the glyph table, which is the value of the variable glyph-table.

 -- Variable: glyph-table
     The value of this variable is the current glyph table.  It should be a vector; the Gth element defines glyph code G.  If the value is nil instead of a vector, then all glyphs are simple (see below).

Here are the possible types of elements in the glyph table:

STRING
     Send the characters in STRING to the terminal to output this glyph.  This alternative is available on character terminals, but not under a window system.

INTEGER
     Define this glyph code as an alias for glyph code INTEGER.  You can use an alias to specify a face code for the glyph; see below.

nil
     This glyph is simple.  On an ordinary terminal, the glyph code mod 524288 is the character to output.  In a window system, the glyph code mod 524288 is the character to output, and the glyph code divided by 524288 specifies the face number (see Face Functions) to use while outputting it.  (524288 is 2**19.) See Faces.

If a glyph code is greater than or equal to the length of the glyph table, that code is automatically simple.

 -- Function: create-glyph string
     This function returns a newly-allocated glyph code which is set up to display by sending STRING to the terminal.

Beeping
=======

This section describes how to make Emacs ring the bell (or blink the screen) to attract the user's attention.  Be conservative about how often you do this; frequent bells can become irritating.  Also be careful not to use just beeping when signaling an error is more appropriate.  (see Errors.)

 -- Function: ding &optional do-not-terminate
     This function beeps, or flashes the screen (see visible-bell below). It also terminates any keyboard macro currently executing unless DO-NOT-TERMINATE is non-nil.

 -- Function: beep &optional do-not-terminate
     This is a synonym for ding.

 -- User Option: visible-bell
     This variable determines whether Emacs should flash the screen to represent a bell.  Non-nil means yes, nil means no.  This is effective on a window system, and on a character-only terminal provided the terminal's Termcap entry defines the visible bell capability (vb).

 -- Variable: ring-bell-function
     If this is non-nil, it specifies how Emacs should ``ring the bell.''  Its value should be a function of no arguments.  If this is non-nil, it takes precedence over the visible-bell variable.

Window Systems
==============

Emacs works with several window systems, most notably the X Window System.  Both Emacs and X use the term ``window'', but use it differently.  An Emacs frame is a single window as far as X is concerned; the individual Emacs windows are not known to X at all.

 -- Variable: window-system
     This variable tells Lisp programs what window system Emacs is running under.  The possible values are

     x
          Emacs is displaying using X.

     pc
          Emacs is displaying using MS-DOS.

     w32
          Emacs is displaying using Windows NT or Windows 9x.

     mac
          Emacs is displaying using a Macintosh.

     nil
          Emacs is using a character-based terminal.

 -- Variable: window-setup-hook
     This variable is a normal hook which Emacs runs after handling the initialization files.  Emacs runs this hook after it has completed loading your init file, the default initialization file (if any), and the terminal-specific Lisp code, and running the hook term-setup-hook.

     This hook is used for internal purposes: setting up communication with the window system, and creating the initial window.  Users should not interfere with it.