Operating System Interface
**************************

This chapter is about starting and getting out of Emacs, access to values in the operating system environment, and terminal input, output, and flow control.

See Building Emacs, for related information.  See also Display, for additional operating system status information pertaining to the terminal and the screen.

Starting Up Emacs
=================

This section describes what Emacs does when it is started, and how you can customize these actions.

Summary: Sequence of Actions at Startup
---------------------------------------

The order of operations performed (in startup.el) by Emacs when it is started up is as follows:

 1. It adds subdirectories to load-path, by running the file named subdirs.el in each directory in the list.  Normally this file adds the directory's subdirectories to the list, and these will be scanned in their turn.  The files subdirs.el are normally generated automatically by Emacs installation.

 2. It sets the language environment and the terminal coding system, if requested by environment variables such as LANG.

 3. It loads the initialization library for the window system, if you are using a window system.  This library's name is term/WINDOWSYSTEM-win.el.

 4. It processes the initial options.  (Some of them are handled even earlier than this.)

 5. It initializes the window frame and faces, if appropriate.

 6. It runs the normal hook before-init-hook.

 7. It loads the library site-start (if any), unless the option -Q (or --no-site-file) was specified.  The library's file name is usually site-start.el.

 8. It loads your init file (usually ~/.emacs), unless the option -q (or --no-init-file), -Q, or --batch was specified on the command line.  The -u option can specify another user whose home directory should be used instead of ~.

 9. It loads the library default (if any), unless inhibit-default-init is non-nil.  (This is not done in -batch mode, or if -Q or -q was specified on the command line.)  The library's file name is usually default.el.

 10. It runs the normal hook after-init-hook.

 11. It sets the major mode according to initial-major-mode, provided the buffer *scratch* is still current and still in Fundamental mode.

 12. It loads the terminal-specific Lisp file, if any, except when in batch mode or using a window system.

 13. It displays the initial echo area message, unless you have suppressed that with inhibit-startup-echo-area-message.

 14. It processes the action arguments from the command line.

 15. It runs emacs-startup-hook and then term-setup-hook.

 16. It calls frame-notice-user-settings, which modifies the parameters of the selected frame according to whatever the init files specify.

 17. It runs window-setup-hook.  See Window Systems.

 18. It displays copyleft, nonwarranty, and basic use information, provided the value of inhibit-startup-message is nil, you didn't specify --no-splash or -Q.

 -- User Option: inhibit-startup-message
     This variable inhibits the initial startup messages (the nonwarranty, etc.).  If it is non-nil, then the messages are not printed.

     This variable exists so you can set it in your personal init file, once you are familiar with the contents of the startup message.  Do not set this variable in the init file of a new user, or in a way that affects more than one user, because that would prevent new users from receiving the information they are supposed to see.

 -- User Option: inhibit-startup-echo-area-message
     This variable controls the display of the startup echo area message. You can suppress the startup echo area message by adding text with this form to your init file:

          (setq inhibit-startup-echo-area-message
                "YOUR-LOGIN-NAME")

     Emacs explicitly checks for an expression as shown above in your init file; your login name must appear in the expression as a Lisp string constant.  Other methods of setting inhibit-startup-echo-area-message to the same value do not inhibit the startup message.

     This way, you can easily inhibit the message for yourself if you wish, but thoughtless copying of your init file will not inhibit the message for someone else.

The Init File, .emacs
---------------------

When you start Emacs, it normally attempts to load your init file, a file in your home directory.  Its normal name is .emacs, but you can also call it .emacs.el. Alternatively, you can use a file named init.el in a subdirectory .emacs.d.  Whichever place you use, you can also compile the file (see Byte Compilation); then the actual file loaded will be .emacs.elc or init.elc.

The command-line switches -q, -Q, and -u control whether and where to find the init file; -q (and the stronger -Q) says not to load an init file, while -u USER says to load USER's init file instead of yours. See Entering Emacs (The GNU Emacs Manual).  If neither option is specified, Emacs uses the LOGNAME environment variable, or the USER (most systems) or USERNAME (MS systems) variable, to find your home directory and thus your init file; this way, even if you have su'd, Emacs still loads your own init file.  If those environment variables are absent, though, Emacs uses your user-id to find your home directory.

A site may have a default init file, which is the library named default.el.  Emacs finds the default.el file through the standard search path for libraries (see How Programs Do Loading).  The Emacs distribution does not come with this file; sites may provide one for local customizations.  If the default init file exists, it is loaded whenever you start Emacs, except in batch mode or if -q (or -Q) is specified.  But your own personal init file, if any, is loaded first; if it sets inhibit-default-init to a non-nil value, then Emacs does not subsequently load the default.el file.

Another file for site-customization is site-start.el.  Emacs loads this before the user's init file.  You can inhibit the loading of this file with the option --no-site-file.

 -- Variable: site-run-file
     This variable specifies the site-customization file to load before the user's init file.  Its normal value is "site-start".  The only way you can change it with real effect is to do so before dumping Emacs.

See Init File Examples (The GNU Emacs Manual), for examples of how to make various commonly desired customizations in your .emacs file.

 -- User Option: inhibit-default-init
     This variable prevents Emacs from loading the default initialization library file for your session of Emacs.  If its value is non-nil, then the default library is not loaded.  The default value is nil.

 -- Variable: before-init-hook
     This normal hook is run, once, just before loading all the init files (the user's init file, default.el, and/or site-start.el). (The only way to change it with real effect is before dumping Emacs.)

 -- Variable: after-init-hook
     This normal hook is run, once, just after loading all the init files (the user's init file, default.el, and/or site-start.el), before loading the terminal-specific library and processing the command-line action arguments.

 -- Variable: emacs-startup-hook
     This normal hook is run, once, just after handling the command line arguments, just before term-setup-hook.

 -- Variable: user-init-file
     This variable holds the absolute file name of the user's init file.  If the actual init file loaded is a compiled file, such as .emacs.elc, the value refers to the corresponding source file.

Terminal-Specific Initialization
--------------------------------

Each terminal type can have its own Lisp library that Emacs loads when run on that type of terminal.  The library's name is constructed by concatenating the value of the variable term-file-prefix and the terminal type (specified by the environment variable TERM). Normally, term-file-prefix has the value "term/"; changing this is not recommended.  Emacs finds the file in the normal manner, by searching the load-path directories, and trying the .elc and .el suffixes.

The usual function of a terminal-specific library is to enable special keys to send sequences that Emacs can recognize.  It may also need to set or add to function-key-map if the Termcap or Terminfo entry does not specify all the terminal's function keys. See Terminal Input.

When the name of the terminal type contains a hyphen, and no library is found whose name is identical to the terminal's name, Emacs strips from the terminal's name the last hyphen and everything that follows it, and tries again.  This process is repeated until Emacs finds a matching library or until there are no more hyphens in the name (the latter means the terminal doesn't have any library specific to it). Thus, for example, if there are no aaa-48 and aaa-30 libraries, Emacs will try the same library term/aaa.el for terminal types aaa-48 and aaa-30-rv.  If necessary, the library can evaluate (getenv "TERM") to find the full name of the terminal type.

Your init file can prevent the loading of the terminal-specific library by setting the variable term-file-prefix to nil.  This feature is useful when experimenting with your own peculiar customizations.

You can also arrange to override some of the actions of the terminal-specific library by setting the variable term-setup-hook.  This is a normal hook which Emacs runs using run-hooks at the end of Emacs initialization, after loading both your init file and any terminal-specific libraries.  You can use this variable to define initializations for terminals that do not have their own libraries.  See Hooks.

 -- Variable: term-file-prefix
     If the term-file-prefix variable is non-nil, Emacs loads a terminal-specific initialization file as follows:

          (load (concat term-file-prefix (getenv "TERM")))

     You may set the term-file-prefix variable to nil in your init file if you do not wish to load the terminal-initialization file.  To do this, put the following in your init file: (setq term-file-prefix nil).

     On MS-DOS, if the environment variable TERM is not set, Emacs uses internal as the terminal type.

 -- Variable: term-setup-hook
     This variable is a normal hook that Emacs runs after loading your init file, the default initialization file (if any) and the terminal-specific Lisp file.

     You can use term-setup-hook to override the definitions made by a terminal-specific file.

See window-setup-hook in Window Systems, for a related feature.

Command-Line Arguments
----------------------

You can use command-line arguments to request various actions when you start Emacs.  Since you do not need to start Emacs more than once per day, and will often leave your Emacs session running longer than that, command-line arguments are hardly ever used.  As a practical matter, it is best to avoid making the habit of using them, since this habit would encourage you to kill and restart Emacs unnecessarily often.  These options exist for two reasons: to be compatible with other editors (for invocation by other programs) and to enable shell scripts to run specific Lisp programs.

This section describes how Emacs processes command-line arguments, and how you can customize them.

 -- Function: command-line
     This function parses the command line that Emacs was called with, processes it, loads the user's init file and displays the startup messages.

 -- Variable: command-line-processed
     The value of this variable is t once the command line has been processed.

     If you redump Emacs by calling dump-emacs, you may wish to set this variable to nil first in order to cause the new dumped Emacs to process its new command-line arguments.

 -- Variable: command-switch-alist
     The value of this variable is an alist of user-defined command-line options and associated handler functions.  This variable exists so you can add elements to it.

     A command-line option is an argument on the command line, which has the form:

          -OPTION

     The elements of the command-switch-alist look like this:

          (OPTION . HANDLER-FUNCTION)

     The CAR, OPTION, is a string, the name of a command-line option (not including the initial hyphen).  The HANDLER-FUNCTION is called to handle OPTION, and receives the option name as its sole argument.

     In some cases, the option is followed in the command line by an argument.  In these cases, the HANDLER-FUNCTION can find all the remaining command-line arguments in the variable command-line-args-left.  (The entire list of command-line arguments is in command-line-args.)

     The command-line arguments are parsed by the command-line-1 function in the startup.el file.  See also Command Line Arguments for Emacs Invocation (The GNU Emacs Manual).

 -- Variable: command-line-args
     The value of this variable is the list of command-line arguments passed to Emacs.

 -- Variable: command-line-functions
     This variable's value is a list of functions for handling an unrecognized command-line argument.  Each time the next argument to be processed has no special meaning, the functions in this list are called, in order of appearance, until one of them returns a non-nil value.

     These functions are called with no arguments.  They can access the command-line argument under consideration through the variable argi, which is bound temporarily at this point.  The remaining arguments (not including the current one) are in the variable command-line-args-left.

     When a function recognizes and processes the argument in argi, it should return a non-nil value to say it has dealt with that argument.  If it has also dealt with some of the following arguments, it can indicate that by deleting them from command-line-args-left.

     If all of these functions return nil, then the argument is used as a file name to visit.

Getting Out of Emacs
====================

There are two ways to get out of Emacs: you can kill the Emacs job, which exits permanently, or you can suspend it, which permits you to reenter the Emacs process later.  As a practical matter, you seldom kill Emacs---only when you are about to log out.  Suspending is much more common.

Killing Emacs
-------------

Killing Emacs means ending the execution of the Emacs process.  The parent process normally resumes control.  The low-level primitive for killing Emacs is kill-emacs.

 -- Function: kill-emacs &optional exit-data
     This function exits the Emacs process and kills it.

     If EXIT-DATA is an integer, then it is used as the exit status of the Emacs process.  (This is useful primarily in batch operation; see Batch Mode.)

     If EXIT-DATA is a string, its contents are stuffed into the terminal input buffer so that the shell (or whatever program next reads input) can read them.

All the information in the Emacs process, aside from files that have been saved, is lost when the Emacs process is killed.  Because killing Emacs inadvertently can lose a lot of work, Emacs queries for confirmation before actually terminating if you have buffers that need saving or subprocesses that are running.  This is done in the function save-buffers-kill-emacs, the higher level function from which kill-emacs is usually called.

 -- Variable: kill-emacs-query-functions
     After asking the standard questions, save-buffers-kill-emacs calls the functions in the list kill-emacs-query-functions, in order of appearance, with no arguments.  These functions can ask for additional confirmation from the user.  If any of them returns nil, save-buffers-kill-emacs does not kill Emacs, and does not run the remaining functions in this hook.  Calling kill-emacs directly does not run this hook.

 -- Variable: kill-emacs-hook
     This variable is a normal hook; once save-buffers-kill-emacs is finished with all file saving and confirmation, it calls kill-emacs which runs the functions in this hook. kill-emacs does not run this hook in batch mode.

     kill-emacs may be invoked directly (that is not via save-buffers-kill-emacs) if the terminal is disconnected, or in similar situations where interaction with the user is not possible. Thus, if your hook needs to interact with the user, put it on kill-emacs-query-functions; if it needs to run regardless of how Emacs is killed, put it on kill-emacs-hook.

Suspending Emacs
----------------

Suspending Emacs means stopping Emacs temporarily and returning control to its superior process, which is usually the shell.  This allows you to resume editing later in the same Emacs process, with the same buffers, the same kill ring, the same undo history, and so on.  To resume Emacs, use the appropriate command in the parent shell---most likely fg.

Some operating systems do not support suspension of jobs; on these systems, ``suspension'' actually creates a new shell temporarily as a subprocess of Emacs.  Then you would exit the shell to return to Emacs.

Suspension is not useful with window systems, because the Emacs job may not have a parent that can resume it again, and in any case you can give input to some other job such as a shell merely by moving to a different window.  Therefore, suspending is not allowed when Emacs is using a window system (X or MS Windows).

 -- Function: suspend-emacs &optional string
     This function stops Emacs and returns control to the superior process. If and when the superior process resumes Emacs, suspend-emacs returns nil to its caller in Lisp.

     If STRING is non-nil, its characters are sent to be read as terminal input by Emacs's superior shell.  The characters in STRING are not echoed by the superior shell; only the results appear.

     Before suspending, suspend-emacs runs the normal hook suspend-hook.

     After the user resumes Emacs, suspend-emacs runs the normal hook suspend-resume-hook.  See Hooks.

     The next redisplay after resumption will redraw the entire screen, unless the variable no-redraw-on-reenter is non-nil (see Refresh Screen).

     In the following example, note that pwd is not echoed after Emacs is suspended.  But it is read and executed by the shell.

          (suspend-emacs)
               => nil

          (add-hook 'suspend-hook
                    (function (lambda ()
                                (or (y-or-n-p
                                      "Really suspend? ")
                                    (error "Suspend canceled")))))
               => (lambda nil
                    (or (y-or-n-p "Really suspend? ")
                        (error "Suspend canceled")))

          (add-hook 'suspend-resume-hook
                    (function (lambda () (message "Resumed!"))))
               => (lambda nil (message "Resumed!"))

          (suspend-emacs "pwd")
               => nil

          ---------- Buffer: Minibuffer ----------
          Really suspend? y
          ---------- Buffer: Minibuffer ----------

          ---------- Parent Shell ----------
          lewis@slug[23] % /user/lewis/manual
          lewis@slug[24] % fg

          ---------- Echo Area ----------
          Resumed!

 -- Variable: suspend-hook
     This variable is a normal hook that Emacs runs before suspending.

 -- Variable: suspend-resume-hook
     This variable is a normal hook that Emacs runs on resuming after a suspension.

Operating System Environment
============================

Emacs provides access to variables in the operating system environment through various functions.  These variables include the name of the system, the user's UID, and so on.

 -- Variable: system-configuration
     This variable holds the standard GNU configuration name for the hardware/software configuration of your system, as a string.  The convenient way to test parts of this string is with string-match.

 -- Variable: system-type
     The value of this variable is a symbol indicating the type of operating system Emacs is operating on.  Here is a table of the possible values:

     alpha-vms
          VMS on the Alpha.

     aix-v3
          AIX.

     berkeley-unix
          Berkeley BSD.

     cygwin
          Cygwin.

     dgux
          Data General DGUX operating system.

     gnu
          the GNU system (using the GNU kernel, which consists of the HURD and Mach).

     gnu/linux
          A GNU/Linux system---that is, a variant GNU system, using the Linux kernel.  (These systems are the ones people often call ``Linux,'' but actually Linux is just the kernel, not the whole system.)

     hpux
          Hewlett-Packard HPUX operating system.

     irix
          Silicon Graphics Irix system.

     ms-dos
          Microsoft MS-DOS ``operating system.''  Emacs compiled with DJGPP for MS-DOS binds system-type to ms-dos even when you run it on MS-Windows.

     next-mach
          NeXT Mach-based system.

     rtu
          Masscomp RTU, UCB universe.

     unisoft-unix
          UniSoft UniPlus.

     usg-unix-v
          AT&T System V.

     vax-vms
          VAX VMS.

     windows-nt
          Microsoft windows NT.  The same executable supports Windows 9X, but the value of system-type is windows-nt in either case.

     xenix
          SCO Xenix 386.

     We do not wish to add new symbols to make finer distinctions unless it is absolutely necessary!  In fact, we hope to eliminate some of these alternatives in the future.  We recommend using system-configuration to distinguish between different operating systems.

 -- Function: system-name
     This function returns the name of the machine you are running on.

          (system-name)
               => "www.gnu.org"

The symbol system-name is a variable as well as a function.  In fact, the function returns whatever value the variable system-name currently holds.  Thus, you can set the variable system-name in case Emacs is confused about the name of your system.  The variable is also useful for constructing frame titles (see Frame Titles).

 -- Variable: mail-host-address
     If this variable is non-nil, it is used instead of system-name for purposes of generating email addresses.  For example, it is used when constructing the default value of user-mail-address.  See User Identification.  (Since this is done when Emacs starts up, the value actually used is the one saved when Emacs was dumped.  See Building Emacs.)

 -- Command: getenv var
     This function returns the value of the environment variable VAR, as a string.  VAR should be a string.  If VAR is undefined in the environment, getenv returns nil.  If returns "" if VAR is set but null.  Within Emacs, the environment variable values are kept in the Lisp variable process-environment.

          (getenv "USER")
               => "lewis"

          lewis@slug[10] % printenv
          PATH=.:/user/lewis/bin:/usr/bin:/usr/local/bin
          USER=lewis

          TERM=ibmapa16
          SHELL=/bin/csh
          HOME=/user/lewis

 -- Command: setenv variable &optional value
     This command sets the value of the environment variable named VARIABLE to VALUE.  VARIABLE should be a string. Internally, Emacs Lisp can handle any string.  However, normally VARIABLE should be a valid shell identifier, that is, a sequence of letters, digits and underscores, starting with a letter or underscore.  Otherwise, errors may occur if subprocesses of Emacs try to access the value of VARIABLE.  If VALUE is omitted or nil, setenv removes VARIABLE from the environment. Otherwise, VALUE should be a string.

     setenv works by modifying process-environment; binding that variable with let is also reasonable practice.

     setenv returns the new value of VARIABLE, or nil if it removed VARIABLE from the environment.

 -- Variable: process-environment
     This variable is a list of strings, each describing one environment variable.  The functions getenv and setenv work by means of this variable.

          process-environment
          => ("l=/usr/stanford/lib/gnuemacs/lisp"
              "PATH=.:/user/lewis/bin:/usr/class:/nfsusr/local/bin"
              "USER=lewis"

              "TERM=ibmapa16"
              "SHELL=/bin/csh"
              "HOME=/user/lewis")

     If process-environment contains ``duplicate'' elements that specify the same environment variable, the first of these elements specifies the variable, and the other ``duplicates'' are ignored.

 -- Variable: path-separator
     This variable holds a string which says which character separates directories in a search path (as found in an environment variable).  Its value is ":" for Unix and GNU systems, and ";" for MS-DOS and MS-Windows.

 -- Function: parse-colon-path path
     This function takes a search path string such as would be the value of the PATH environment variable, and splits it at the separators, returning a list of directory names.  nil in this list stands for ``use the current directory.''  Although the function's name says ``colon,'' it actually uses the value of path-separator.

          (parse-colon-path ":/foo:/bar")
               => (nil "/foo/" "/bar/")

 -- Variable: invocation-name
     This variable holds the program name under which Emacs was invoked.  The value is a string, and does not include a directory name.

 -- Variable: invocation-directory
     This variable holds the directory from which the Emacs executable was invoked, or perhaps nil if that directory cannot be determined.

 -- Variable: installation-directory
     If non-nil, this is a directory within which to look for the lib-src and etc subdirectories.  This is non-nil when Emacs can't find those directories in their standard installed locations, but can find them in a directory related somehow to the one containing the Emacs executable.

 -- Function: load-average &optional use-float
     This function returns the current 1-minute, 5-minute, and 15-minute load averages, in a list.

     By default, the values are integers that are 100 times the system load averages, which indicate the average number of processes trying to run. If USE-FLOAT is non-nil, then they are returned as floating point numbers and without multiplying by 100.

     If it is impossible to obtain the load average, this function signals an error.  On some platforms, access to load averages requires installing Emacs as setuid or setgid so that it can read kernel information, and that usually isn't advisable.

     If the 1-minute load average is available, but the 5- or 15-minute averages are not, this function returns a shortened list containing the available averages.

          (load-average)
               => (169 48 36)

          (load-average t)
               => (1.69 0.48 0.36)

          lewis@rocky[5] % uptime
           11:55am  up 1 day, 19:37,  3 users,
           load average: 1.69, 0.48, 0.36

 -- Function: emacs-pid
     This function returns the process ID of the Emacs process, as an integer.

 -- Variable: tty-erase-char
     This variable holds the erase character that was selected in the system's terminal driver, before Emacs was started. The value is nil if Emacs is running under a window system.

 -- Function: setprv privilege-name &optional setp getprv
     This function sets or resets a VMS privilege.  (It does not exist on other systems.)  The first argument is the privilege name, as a string. The second argument, SETP, is t or nil, indicating whether the privilege is to be turned on or off.  Its default is nil.  The function returns t if successful, nil otherwise.

     If the third argument, GETPRV, is non-nil, setprv does not change the privilege, but returns t or nil indicating whether the privilege is currently enabled.

User Identification
===================

 -- Variable: init-file-user
     This variable says which user's init files should be used by Emacs---or nil if none.  "" stands for the user who originally logged in.  The value reflects command-line options such as -q or -u USER.

     Lisp packages that load files of customizations, or any other sort of user profile, should obey this variable in deciding where to find it. They should load the profile of the user name found in this variable. If init-file-user is nil, meaning that the -q option was used, then Lisp packages should not load any customization files or user profile.

 -- Variable: user-mail-address
     This holds the nominal email address of the user who is using Emacs. Emacs normally sets this variable to a default value after reading your init files, but not if you have already set it.  So you can set the variable to some other value in your init file if you do not want to use the default value.

 -- Function: user-login-name &optional uid
     If you don't specify UID, this function returns the name under which the user is logged in.  If the environment variable LOGNAME is set, that value is used.  Otherwise, if the environment variable USER is set, that value is used.  Otherwise, the value is based on the effective UID, not the real UID.

     If you specify UID, the value is the user name that corresponds to UID (which should be an integer), or nil if there is no such user.

          (user-login-name)
               => "lewis"

 -- Function: user-real-login-name
     This function returns the user name corresponding to Emacs's real UID.  This ignores the effective UID and ignores the environment variables LOGNAME and USER.

 -- Function: user-full-name &optional uid
     This function returns the full name of the logged-in user---or the value of the environment variable NAME, if that is set.

          (user-full-name)
               => "Bil Lewis"

     If the Emacs job's user-id does not correspond to any known user (and provided NAME is not set), the value is "unknown".

     If UID is non-nil, then it should be a number (a user-id) or a string (a login name).  Then user-full-name returns the full name corresponding to that user-id or login name.  If you specify a user-id or login name that isn't defined, it returns nil.

The symbols user-login-name, user-real-login-name and user-full-name are variables as well as functions.  The functions return the same values that the variables hold.  These variables allow you to ``fake out'' Emacs by telling the functions what to return.  The variables are also useful for constructing frame titles (see Frame Titles).

 -- Function: user-real-uid
     This function returns the real UID of the user. The value may be a floating point number.

          (user-real-uid)
               => 19

 -- Function: user-uid
     This function returns the effective UID of the user. The value may be a floating point number.

Time of Day
===========

This section explains how to determine the current time and the time zone.

 -- Function: current-time-string &optional time-value
     This function returns the current time and date as a human-readable string.  The format of the string is unvarying; the number of characters used for each part is always the same, so you can reliably use substring to extract pieces of it.  It is wise to count the characters from the beginning of the string rather than from the end, as additional information may some day be added at the end.

     The argument TIME-VALUE, if given, specifies a time to format instead of the current time.  The argument should be a list whose first two elements are integers.  Thus, you can use times obtained from current-time (see below) and from file-attributes (see Definition of file-attributes).  TIME-VALUE can also be a cons of two integers, but this is considered obsolete.

          (current-time-string)
               => "Wed Oct 14 22:21:05 1987"

 -- Function: current-time
     This function returns the system's time value as a list of three integers: (HIGH LOW MICROSEC).  The integers HIGH and LOW combine to give the number of seconds since 0:00 January 1, 1970 UTC (Coordinated Universal Time), which is HIGH * 2**16 + LOW.

     The third element, MICROSEC, gives the microseconds since the start of the current second (or 0 for systems that return time with the resolution of only one second).

     The first two elements can be compared with file time values such as you get with the function file-attributes. See Definition of file-attributes.

 -- Function: current-time-zone &optional time-value
     This function returns a list describing the time zone that the user is in.

     The value has the form (OFFSET NAME).  Here OFFSET is an integer giving the number of seconds ahead of UTC (east of Greenwich).  A negative value means west of Greenwich.  The second element, NAME, is a string giving the name of the time zone.  Both elements change when daylight savings time begins or ends; if the user has specified a time zone that does not use a seasonal time adjustment, then the value is constant through time.

     If the operating system doesn't supply all the information necessary to compute the value, the unknown elements of the list are nil.

     The argument TIME-VALUE, if given, specifies a time to analyze instead of the current time.  The argument should have the same form as for current-time-string (see above).  Thus, you can use times obtained from current-time (see above) and from file-attributes.  See Definition of file-attributes.

 -- Function: set-time-zone-rule tz
     This function specifies the local time zone according to TZ.  If TZ is nil, that means to use an implementation-defined default time zone.  If TZ is t, that means to use Universal Time.  Otherwise, TZ should be a string specifying a time zone rule.

 -- Function: float-time &optional time-value
     This function returns the current time as a floating-point number of seconds since the epoch.  The argument TIME-VALUE, if given, specifies a time to convert instead of the current time.  The argument should have the same form as for current-time-string (see above).  Thus, it accepts the output of current-time and file-attributes.

     Warning: Since the result is floating point, it may not be exact.  Do not use this function if precise time stamps are required.

Time Conversion
===============

These functions convert time values (lists of two or three integers) to calendrical information and vice versa.  You can get time values from the functions current-time (see Time of Day) and file-attributes (see Definition of file-attributes).

Many operating systems are limited to time values that contain 32 bits of information; these systems typically handle only the times from 1901-12-13 20:45:52 UTC through 2038-01-19 03:14:07 UTC.  However, some operating systems have larger time values, and can represent times far in the past or future.

Time conversion functions always use the Gregorian calendar, even for dates before the Gregorian calendar was introduced.  Year numbers count the number of years since the year 1 B.C., and do not skip zero as traditional Gregorian years do; for example, the year number -37 represents the Gregorian year 38 B.C.

 -- Function: decode-time &optional time
     This function converts a time value into calendrical information.  If you don't specify TIME, it decodes the current time.  The return value is a list of nine elements, as follows:

          (SECONDS MINUTES HOUR DAY MONTH YEAR DOW DST ZONE)

     Here is what the elements mean:

     seconds
          The number of seconds past the minute, as an integer between 0 and 59. On some operating systems, this is 60 for leap seconds.

     minutes
          The number of minutes past the hour, as an integer between 0 and 59.

     hour
          The hour of the day, as an integer between 0 and 23.

     day
          The day of the month, as an integer between 1 and 31.

     month
          The month of the year, as an integer between 1 and 12.

     year
          The year, an integer typically greater than 1900.

     dow
          The day of week, as an integer between 0 and 6, where 0 stands for Sunday.

     dst
          t if daylight savings time is effect, otherwise nil.

     zone
          An integer indicating the time zone, as the number of seconds east of Greenwich.

     Common Lisp Note: Common Lisp has different meanings for DOW and ZONE.

 -- Function: encode-time seconds minutes hour day month year &optional zone
     This function is the inverse of decode-time.  It converts seven items of calendrical data into a time value.  For the meanings of the arguments, see the table above under decode-time.

     Year numbers less than 100 are not treated specially.  If you want them to stand for years above 1900, or years above 2000, you must alter them yourself before you call encode-time.

     The optional argument ZONE defaults to the current time zone and its daylight savings time rules.  If specified, it can be either a list (as you would get from current-time-zone), a string as in the TZ environment variable, t for Universal Time, or an integer (as you would get from decode-time).  The specified zone is used without any further alteration for daylight savings time.

     If you pass more than seven arguments to encode-time, the first six are used as SECONDS through YEAR, the last argument is used as ZONE, and the arguments in between are ignored.  This feature makes it possible to use the elements of a list returned by decode-time as the arguments to encode-time, like this:

          (apply 'encode-time (decode-time ...))

     You can perform simple date arithmetic by using out-of-range values for the SECONDS, MINUTES, HOUR, DAY, and MONTH arguments; for example, day 0 means the day preceding the given month.

     The operating system puts limits on the range of possible time values; if you try to encode a time that is out of range, an error results. For instance, years before 1970 do not work on some systems; on others, years as early as 1901 do work.

Parsing and Formatting Times
============================

These functions convert time values (lists of two or three integers) to text in a string, and vice versa.

 -- Function: date-to-time string
     This function parses the time-string STRING and returns the corresponding time value.

 -- Function: format-time-string format-string &optional time universal
     This function converts TIME (or the current time, if TIME is omitted) to a string according to FORMAT-STRING.  The argument FORMAT-STRING may contain %-sequences which say to substitute parts of the time.  Here is a table of what the %-sequences mean:

     %a
          This stands for the abbreviated name of the day of week.

     %A
          This stands for the full name of the day of week.

     %b
          This stands for the abbreviated name of the month.

     %B
          This stands for the full name of the month.

     %c
          This is a synonym for %x %X.

     %C
          This has a locale-specific meaning.  In the default locale (named C), it is equivalent to %A, %B %e, %Y.

     %d
          This stands for the day of month, zero-padded.

     %D
          This is a synonym for %m/%d/%y.

     %e
          This stands for the day of month, blank-padded.

     %h
          This is a synonym for %b.

     %H
          This stands for the hour (00-23).

     %I
          This stands for the hour (01-12).

     %j
          This stands for the day of the year (001-366).

     %k
          This stands for the hour (0-23), blank padded.

     %l
          This stands for the hour (1-12), blank padded.

     %m
          This stands for the month (01-12).

     %M
          This stands for the minute (00-59).

     %n
          This stands for a newline.

     %p
          This stands for AM or PM, as appropriate.

     %r
          This is a synonym for %I:%M:%S %p.

     %R
          This is a synonym for %H:%M.

     %S
          This stands for the seconds (00-59).

     %t
          This stands for a tab character.

     %T
          This is a synonym for %H:%M:%S.

     %U
          This stands for the week of the year (01-52), assuming that weeks start on Sunday.

     %w
          This stands for the numeric day of week (0-6).  Sunday is day 0.

     %W
          This stands for the week of the year (01-52), assuming that weeks start on Monday.

     %x
          This has a locale-specific meaning.  In the default locale (named C), it is equivalent to %D.

     %X
          This has a locale-specific meaning.  In the default locale (named C), it is equivalent to %T.

     %y
          This stands for the year without century (00-99).

     %Y
          This stands for the year with century.

     %Z
          This stands for the time zone abbreviation.

     You can also specify the field width and type of padding for any of these %-sequences.  This works as in printf: you write the field width as digits in the middle of a %-sequences.  If you start the field width with 0, it means to pad with zeros.  If you start the field width with _, it means to pad with spaces.

     For example, %S specifies the number of seconds since the minute; %03S means to pad this with zeros to 3 positions, %_3S to pad with spaces to 3 positions.  Plain %3S pads with zeros, because that is how %S normally pads to two positions.

     The characters E and O act as modifiers when used between % and one of the letters in the table above.  E specifies using the current locale's ``alternative'' version of the date and time. In a Japanese locale, for example, %Ex might yield a date format based on the Japanese Emperors' reigns.  E is allowed in %Ec, %EC, %Ex, %EX, %Ey, and %EY.

     O means to use the current locale's ``alternative'' representation of numbers, instead of the ordinary decimal digits.  This is allowed with most letters, all the ones that output numbers.

     If UNIVERSAL is non-nil, that means to describe the time as Universal Time; nil means describe it using what Emacs believes is the local time zone (see current-time-zone).

     This function uses the C library function strftime to do most of the work.  In order to communicate with that function, it first encodes its argument using the coding system specified by locale-coding-system (see Locales); after strftime returns the resulting string, format-time-string decodes the string using that same coding system.

 -- Function: seconds-to-time seconds
     This function converts SECONDS, a floating point number of seconds since the epoch, to a time value and returns that.  To perform the inverse conversion, use float-time.

Processor Run time
==================

 -- Function: get-internal-run-time
     This function returns the processor run time used by Emacs as a list of three integers: (HIGH LOW MICROSEC).  The integers HIGH and LOW combine to give the number of seconds, which is HIGH * 2**16 + LOW.

     The third element, MICROSEC, gives the microseconds (or 0 for systems that return time with the resolution of only one second).

     If the system doesn't provide a way to determine the processor run time, get-internal-run-time returns the same time as current-time.

Time Calculations
=================

These functions perform calendrical computations using time values (the kind of list that current-time returns).

 -- Function: time-less-p t1 t2
     This returns t if time value T1 is less than time value T2.

 -- Function: time-subtract t1 t2
     This returns the time difference T1 - T2 between two time values, in the same format as a time value.

 -- Function: time-add t1 t2
     This returns the sum of two time values, one of which ought to represent a time difference rather than a point in time. Here is how to add a number of seconds to a time value:

          (time-add TIME (seconds-to-time SECONDS))

 -- Function: time-to-days time
     This function returns the number of days between the beginning of year 1 and TIME.

 -- Function: time-to-day-in-year time
     This returns the day number within the year corresponding to TIME.

 -- Function: date-leap-year-p year
     This function returns t if YEAR is a leap year.

Timers for Delayed Execution
============================

You can set up a timer to call a function at a specified future time or after a certain length of idleness.

Emacs cannot run timers at any arbitrary point in a Lisp program; it can run them only when Emacs could accept output from a subprocess: namely, while waiting or inside certain primitive functions such as sit-for or read-event which can wait.  Therefore, a timer's execution may be delayed if Emacs is busy.  However, the time of execution is very precise if Emacs is idle.

Emacs binds inhibit-quit to t before calling the timer function, because quitting out of many timer functions can leave things in an inconsistent state.  This is normally unproblematical because most timer functions don't do a lot of work.  Indeed, for a timer to call a function that takes substantial time to run is likely to be annoying.

It is usually a bad idea for timer functions to alter buffer contents.  When they do, they usually should call undo-boundary both before and after changing the buffer, to separate the timer's changes from user commands' changes and prevent a single undo entry from growing to be quite large.

If a timer function calls functions that can change the match data, it should save and restore the match data.  See Saving Match Data.

 -- Command: run-at-time time repeat function &rest args
     This sets up a timer that calls the function FUNCTION with arguments ARGS at time TIME.  If REPEAT is a number (integer or floating point), the timer also runs every REPEAT seconds after that.  If REPEAT is nil, the timer runs only once.

     TIME may specify an absolute or a relative time.

     Absolute times may be specified in a wide variety of formats; this function tries to accept all the commonly used date formats.  The most convenient formats are strings.  Valid such formats include these two,

          YEAR-MONTH-DAY HOUR:MIN:SEC TIMEZONE

          HOUR:MIN:SEC TIMEZONE MONTH/DAY/YEAR

     where in both examples all fields are numbers; the format that current-time-string returns is also allowed, and many others as well.

     To specify a relative time as a string, use numbers followed by units. For example:

     1 min
          denotes 1 minute from now.

     1 min 5 sec
          denotes 65 seconds from now.

     1 min 2 sec 3 hour 4 day 5 week 6 fortnight 7 month 8 year
          denotes exactly 103 months, 123 days, and 10862 seconds from now.

     For relative time values, Emacs considers a month to be exactly thirty days, and a year to be exactly 365.25 days.

     Not all convenient formats are strings.  If TIME is a number (integer or floating point), that specifies a relative time measured in seconds.

     In most cases, REPEAT has no effect on when first call takes place---TIME alone specifies that.  There is one exception: if TIME is t, then the timer runs whenever the time is a multiple of REPEAT seconds after the epoch.  This is useful for functions like display-time.

     The function run-at-time returns a timer value that identifies the particular scheduled future action.  You can use this value to call cancel-timer (see below).

 -- Macro: with-timeout (seconds timeout-forms...) body...
     Execute BODY, but give up after SECONDS seconds.  If BODY finishes before the time is up, with-timeout returns the value of the last form in BODY.  If, however, the execution of BODY is cut short by the timeout, then with-timeout executes all the TIMEOUT-FORMS and returns the value of the last of them.

     This macro works by setting a timer to run after SECONDS seconds.  If BODY finishes before that time, it cancels the timer.  If the timer actually runs, it terminates execution of BODY, then executes TIMEOUT-FORMS.

     Since timers can run within a Lisp program only when the program calls a primitive that can wait, with-timeout cannot stop executing BODY while it is in the midst of a computation---only when it calls one of those primitives.  So use with-timeout only with a BODY that waits for input, not one that does a long computation.

The function y-or-n-p-with-timeout provides a simple way to use a timer to avoid waiting too long for an answer.  See Yes-or-No Queries.

 -- Command: run-with-idle-timer secs repeat function &rest args
     Set up a timer which runs when Emacs has been idle for SECS seconds.  The value of SECS may be an integer or a floating point number.

     If REPEAT is nil, the timer runs just once, the first time Emacs remains idle for a long enough time.  More often REPEAT is non-nil, which means to run the timer each time Emacs remains idle for SECS seconds.

     The function run-with-idle-timer returns a timer value which you can use in calling cancel-timer (see below).

Emacs becomes ``idle'' when it starts waiting for user input, and it remains idle until the user provides some input.  If a timer is set for five seconds of idleness, it runs approximately five seconds after Emacs first becomes idle.  Even if REPEAT is non-nil, this timer will not run again as long as Emacs remains idle, because the duration of idleness will continue to increase and will not go down to five seconds again.

Emacs can do various things while idle: garbage collect, autosave or handle data from a subprocess.  But these interludes during idleness do not interfere with idle timers, because they do not reset the clock of idleness to zero.  An idle timer set for 600 seconds will run when ten minutes have elapsed since the last user command was finished, even if subprocess output has been accepted thousands of times within those ten minutes, and even if there have been garbage collections and autosaves.

When the user supplies input, Emacs becomes non-idle while executing the input.  Then it becomes idle again, and all the idle timers that are set up to repeat will subsequently run another time, one by one.

 -- Function: cancel-timer timer
     Cancel the requested action for TIMER, which should be a value previously returned by run-at-time or run-with-idle-timer. This cancels the effect of that call to one of these functions; the arrival of the specified time will not cause anything special to happen.

Terminal Input
==============

This section describes functions and variables for recording or manipulating terminal input.  See Display, for related functions.

Input Modes
-----------

 -- Function: set-input-mode interrupt flow meta &optional quit-char
     This function sets the mode for reading keyboard input.  If INTERRUPT is non-null, then Emacs uses input interrupts.  If it is nil, then it uses CBREAK mode.  The default setting is system-dependent.  Some systems always use CBREAK mode regardless of what is specified.

     When Emacs communicates directly with X, it ignores this argument and uses interrupts if that is the way it knows how to communicate.

     If FLOW is non-nil, then Emacs uses XON/XOFF (C-q, C-s) flow control for output to the terminal.  This has no effect except in CBREAK mode.

     The argument META controls support for input character codes above 127.  If META is t, Emacs converts characters with the 8th bit set into Meta characters.  If META is nil, Emacs disregards the 8th bit; this is necessary when the terminal uses it as a parity bit.  If META is neither t nor nil, Emacs uses all 8 bits of input unchanged.  This is good for terminals that use 8-bit character sets.

     If QUIT-CHAR is non-nil, it specifies the character to use for quitting.  Normally this character is C-g. See Quitting.

The current-input-mode function returns the input mode settings Emacs is currently using.

 -- Function: current-input-mode
     This function returns the current mode for reading keyboard input.  It returns a list, corresponding to the arguments of set-input-mode, of the form (INTERRUPT FLOW META QUIT) in which:

     interrupt
          is non-nil when Emacs is using interrupt-driven input.  If nil, Emacs is using CBREAK mode.

     flow
          is non-nil if Emacs uses XON/XOFF (C-q, C-s) flow control for output to the terminal.  This value is meaningful only when INTERRUPT is nil.

     meta
          is t if Emacs treats the eighth bit of input characters as the meta bit; nil means Emacs clears the eighth bit of every input character; any other value means Emacs uses all eight bits as the basic character code.

     quit
          is the character Emacs currently uses for quitting, usually C-g.

Translating Input Events
------------------------

This section describes features for translating input events into other input events before they become part of key sequences.  These features apply to each event in the order they are described here: each event is first modified according to extra-keyboard-modifiers, then translated through keyboard-translate-table (if applicable), and finally decoded with the specified keyboard coding system.  If it is being read as part of a key sequence, it is then added to the sequence being read; then subsequences containing it are checked first with function-key-map and then with key-translation-map.

 -- Variable: extra-keyboard-modifiers
     This variable lets Lisp programs ``press'' the modifier keys on the keyboard.  The value is a character.  Only the modifiers of the character matter.  Each time the user types a keyboard key, it is altered as if those modifier keys were held down.  For instance, if you bind extra-keyboard-modifiers to ?\C-\M-a, then all keyboard input characters typed during the scope of the binding will have the control and meta modifiers applied to them.  The character ?\C-@, equivalent to the integer 0, does not count as a control character for this purpose, but as a character with no modifiers. Thus, setting extra-keyboard-modifiers to zero cancels any modification.

     When using a window system, the program can ``press'' any of the modifier keys in this way.  Otherwise, only the CTL and META keys can be virtually pressed.

     Note that this variable applies only to events that really come from the keyboard, and has no effect on mouse events or any other events.

 -- Variable: keyboard-translate-table
     This variable is the translate table for keyboard characters.  It lets you reshuffle the keys on the keyboard without changing any command bindings.  Its value is normally a char-table, or else nil. (It can also be a string or vector, but this is considered obsolete.)

     If keyboard-translate-table is a char-table (see Char-Tables), then each character read from the keyboard is looked up in this char-table.  If the value found there is non-nil, then it is used instead of the actual input character.

     Note that this translation is the first thing that happens to a character after it is read from the terminal.  Record-keeping features such as recent-keys and dribble files record the characters after translation.

     Note also that this translation is done before the characters are supplied to input methods (see Input Methods).  Use translation-table-for-input (see Translation of Characters), if you want to translate characters after input methods operate.

 -- Function: keyboard-translate from to
     This function modifies keyboard-translate-table to translate character code FROM into character code TO.  It creates the keyboard translate table if necessary.

Here's an example of using the keyboard-translate-table to make C-x, C-c and C-v perform the cut, copy and paste operations:

     (keyboard-translate ?\C-x 'control-x)
     (keyboard-translate ?\C-c 'control-c)
     (keyboard-translate ?\C-v 'control-v)
     (global-set-key [control-x] 'kill-region)
     (global-set-key [control-c] 'kill-ring-save)
     (global-set-key [control-v] 'yank)

On a graphical terminal that supports extended ASCII input, you can still get the standard Emacs meanings of one of those characters by typing it with the shift key.  That makes it a different character as far as keyboard translation is concerned, but it has the same usual meaning.

The remaining translation features translate subsequences of key sequences being read.  They are implemented in read-key-sequence and have no effect on input read with read-event.

 -- Variable: function-key-map
     This variable holds a keymap that describes the character sequences sent by function keys on an ordinary character terminal.  This keymap has the same structure as other keymaps, but is used differently: it specifies translations to make while reading key sequences, rather than bindings for key sequences.

     If function-key-map ``binds'' a key sequence K to a vector V, then when K appears as a subsequence anywhere in a key sequence, it is replaced with the events in V.

     For example, VT100 terminals send ESC O P when the keypad PF1 key is pressed.  Therefore, we want Emacs to translate that sequence of events into the single event pf1.  We accomplish this by ``binding'' ESC O P to [pf1] in function-key-map, when using a VT100.

     Thus, typing C-c PF1 sends the character sequence C-c ESC O P; later the function read-key-sequence translates this back into C-c PF1, which it returns as the vector [?\C-c pf1].

     Entries in function-key-map are ignored if they conflict with bindings made in the minor mode, local, or global keymaps.  The intent is that the character sequences that function keys send should not have command bindings in their own right---but if they do, the ordinary bindings take priority.

     The value of function-key-map is usually set up automatically according to the terminal's Terminfo or Termcap entry, but sometimes those need help from terminal-specific Lisp files.  Emacs comes with terminal-specific files for many common terminals; their main purpose is to make entries in function-key-map beyond those that can be deduced from Termcap and Terminfo.  See Terminal-Specific.

 -- Variable: key-translation-map
     This variable is another keymap used just like function-key-map to translate input events into other events.  It differs from function-key-map in two ways:

       * key-translation-map goes to work after function-key-map is finished; it receives the results of translation by function-key-map.

       * Non-prefix bindings in key-translation-map override actual key bindings.  For example, if C-x f has a non-prefix binding in key-translation-map, that translation takes effect even though C-x f also has a key binding in the global map.

     Note however that actual key bindings can have an effect on key-translation-map, even though they are overridden by it. Indeed, actual key bindings override function-key-map and thus may alter the key sequence that key-translation-map receives. Clearly, it is better to avoid this type of situation.

     The intent of key-translation-map is for users to map one character set to another, including ordinary characters normally bound to self-insert-command.

You can use function-key-map or key-translation-map for more than simple aliases, by using a function, instead of a key sequence, as the ``translation'' of a key.  Then this function is called to compute the translation of that key.

The key translation function receives one argument, which is the prompt that was specified in read-key-sequence---or nil if the key sequence is being read by the editor command loop.  In most cases you can ignore the prompt value.

If the function reads input itself, it can have the effect of altering the event that follows.  For example, here's how to define C-c h to turn the character that follows into a Hyper character:

     (defun hyperify (prompt)
       (let ((e (read-event)))
         (vector (if (numberp e)
                     (logior (lsh 1 24) e)
                   (if (memq 'hyper (event-modifiers e))
                       e
                     (add-event-modifier "H-" e))))))

     (defun add-event-modifier (string e)
       (let ((symbol (if (symbolp e) e (car e))))
         (setq symbol (intern (concat string
                                      (symbol-name symbol))))

         (if (symbolp e)
             symbol
           (cons symbol (cdr e)))))

     (define-key function-key-map "\C-ch" 'hyperify)

Finally, if you have enabled keyboard character set decoding using set-keyboard-coding-system, decoding is done after the translations listed above.  See Terminal I/O Encoding.  In future Emacs versions, character set decoding may be done before the other translations.

Recording Input
---------------

 -- Function: recent-keys
     This function returns a vector containing the last 100 input events from the keyboard or mouse.  All input events are included, whether or not they were used as parts of key sequences.  Thus, you always get the last 100 input events, not counting events generated by keyboard macros. (These are excluded because they are less interesting for debugging; it should be enough to see the events that invoked the macros.)

     A call to clear-this-command-keys (see Command Loop Info) causes this function to return an empty vector immediately afterward.

 -- Command: open-dribble-file filename
     This function opens a dribble file named FILENAME.  When a dribble file is open, each input event from the keyboard or mouse (but not those from keyboard macros) is written in that file.  A non-character event is expressed using its printed representation surrounded by <...>.

     You close the dribble file by calling this function with an argument of nil.

     This function is normally used to record the input necessary to trigger an Emacs bug, for the sake of a bug report.

          (open-dribble-file "~/dribble")
               => nil

See also the open-termscript function (see Terminal Output).

Terminal Output
===============

The terminal output functions send output to a text terminal, or keep track of output sent to the terminal.  The variable baud-rate tells you what Emacs thinks is the output speed of the terminal.

 -- Variable: baud-rate
     This variable's value is the output speed of the terminal, as far as Emacs knows.  Setting this variable does not change the speed of actual data transmission, but the value is used for calculations such as padding.  It also affects decisions about whether to scroll part of the screen or repaint---even when using a window system.  (We designed it this way despite the fact that a window system has no true ``output speed'', to give you a way to tune these decisions.)

     The value is measured in baud.

If you are running across a network, and different parts of the network work at different baud rates, the value returned by Emacs may be different from the value used by your local terminal.  Some network protocols communicate the local terminal speed to the remote machine, so that Emacs and other programs can get the proper value, but others do not.  If Emacs has the wrong value, it makes decisions that are less than optimal.  To fix the problem, set baud-rate.

 -- Function: baud-rate
     This obsolete function returns the value of the variable baud-rate.

 -- Function: send-string-to-terminal string
     This function sends STRING to the terminal without alteration. Control characters in STRING have terminal-dependent effects. This function operates only on text terminals.

     One use of this function is to define function keys on terminals that have downloadable function key definitions.  For example, this is how (on certain terminals) to define function key 4 to move forward four characters (by transmitting the characters C-u C-f to the computer):

          (send-string-to-terminal "\eF4\^U\^F")
               => nil

 -- Command: open-termscript filename
     This function is used to open a termscript file that will record all the characters sent by Emacs to the terminal.  It returns nil.  Termscript files are useful for investigating problems where Emacs garbles the screen, problems that are due to incorrect Termcap entries or to undesirable settings of terminal options more often than to actual Emacs bugs.  Once you are certain which characters were actually output, you can determine reliably whether they correspond to the Termcap specifications in use.

     You close the termscript file by calling this function with an argument of nil.

     See also open-dribble-file in Recording Input.

          (open-termscript "../junk/termscript")
               => nil

Sound Output
============

To play sound using Emacs, use the function play-sound.  Only certain systems are supported; if you call play-sound on a system which cannot really do the job, it gives an error.  Emacs version 20 and earlier did not support sound at all.

The sound must be stored as a file in RIFF-WAVE format (.wav) or Sun Audio format (.au).

 -- Function: play-sound sound
     This function plays a specified sound.  The argument, SOUND, has the form (sound PROPERTIES...), where the PROPERTIES consist of alternating keywords (particular symbols recognized specially) and values corresponding to them.

     Here is a table of the keywords that are currently meaningful in SOUND, and their meanings:

     :file FILE
          This specifies the file containing the sound to play. If the file name is not absolute, it is expanded against the directory data-directory.

     :data DATA
          This specifies the sound to play without need to refer to a file.  The value, DATA, should be a string containing the same bytes as a sound file.  We recommend using a unibyte string.

     :volume VOLUME
          This specifies how loud to play the sound.  It should be a number in the range of 0 to 1.  The default is to use whatever volume has been specified before.

     :device DEVICE
          This specifies the system device on which to play the sound, as a string.  The default device is system-dependent.

     Before actually playing the sound, play-sound calls the functions in the list play-sound-functions. Each function is called with one argument, SOUND.

 -- Function: play-sound-file file &optional volume device
     This function is an alternative interface to playing a sound FILE specifying an optional VOLUME and DEVICE.

 -- Variable: play-sound-functions
     A list of functions to be called before playing a sound.  Each function is called with one argument, a property list that describes the sound.

Operating on X11 Keysyms
========================

To define system-specific X11 keysyms, set the variable system-key-alist.

 -- Variable: system-key-alist
     This variable's value should be an alist with one element for each system-specific keysym.  Each element has the form (CODE . SYMBOL), where CODE is the numeric keysym code (not including the ``vendor specific'' bit, -2**28), and SYMBOL is the name for the function key.

     For example (168 . mute-acute) defines a system-specific key (used by HP X servers) whose numeric code is -2**28 + 168.

     It is not crucial to exclude from the alist the keysyms of other X servers; those do no harm, as long as they don't conflict with the ones used by the X server actually in use.

     The variable is always local to the current terminal, and cannot be buffer-local.  See Multiple Displays.

You can specify which keysyms Emacs should use for the Meta, Alt, Hyper, and Super modifiers by setting these variables:

 -- Variable: x-alt-keysym
 -- Variable: x-meta-keysym
 -- Variable: x-hyper-keysym
 -- Variable: x-super-keysym
     The name of the keysym that should stand for the Alt modifier (respectively, for Meta, Hyper, and Super).  For example, here is how to swap the Meta and Alt modifiers within Emacs:

          (setq x-alt-keysym 'meta)
          (setq x-meta-keysym 'alt)

Batch Mode
==========

The command-line option -batch causes Emacs to run noninteractively.  In this mode, Emacs does not read commands from the terminal, it does not alter the terminal modes, and it does not expect to be outputting to an erasable screen.  The idea is that you specify Lisp programs to run; when they are finished, Emacs should exit.  The way to specify the programs to run is with -l FILE, which loads the library named FILE, or -f FUNCTION, which calls FUNCTION with no arguments, or --eval FORM.

Any Lisp program output that would normally go to the echo area, either using message, or using prin1, etc., with t as the stream, goes instead to Emacs's standard error descriptor when in batch mode.  Similarly, input that would normally come from the minibuffer is read from the standard input descriptor. Thus, Emacs behaves much like a noninteractive application program.  (The echo area output that Emacs itself normally generates, such as command echoing, is suppressed entirely.)

 -- Variable: noninteractive
     This variable is non-nil when Emacs is running in batch mode.

Session Management
==================

Emacs supports the X Session Management Protocol for suspension and restart of applications.  In the X Window System, a program called the session manager has the responsibility to keep track of the applications that are running.  During shutdown, the session manager asks applications to save their state, and delays the actual shutdown until they respond.  An application can also cancel the shutdown.

When the session manager restarts a suspended session, it directs these applications to individually reload their saved state.  It does this by specifying a special command-line argument that says what saved session to restore.  For Emacs, this argument is --smid SESSION.

 -- Variable: emacs-save-session-functions
     Emacs supports saving state by using a hook called emacs-save-session-functions.  Each function in this hook is called when the session manager tells Emacs that the window system is shutting down.  The functions are called with no arguments and with the current buffer set to a temporary buffer.  Each function can use insert to add Lisp code to this buffer.  At the end, Emacs saves the buffer in a file that a subsequent Emacs invocation will load in order to restart the saved session.

     If a function in emacs-save-session-functions returns non-nil, Emacs tells the session manager to cancel the shutdown.

Here is an example that just inserts some text into *scratch* when Emacs is restarted by the session manager.

     (add-hook 'emacs-save-session-functions 'save-yourself-test)

     (defun save-yourself-test ()
       (insert "(save-excursion
       (switch-to-buffer \"*scratch*\")
       (insert \"I am restored\"))")
       nil)