changeset 14967:5c431b2e0f95

entered into RCS

--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/msdos/sed1v2.inp	Wed Apr 10 00:53:52 1996 +0000
@@ -0,0 +1,25 @@
+# -sed1v2.inp-----------------------------------------------------------
+# Configuration script for src/makefile under DJGPP v2.x
+# ----------------------------------------------------------------------
+s/^#.*//
+s/^[ \f\t][ \f\t]*$//
+s/^ /	/
+s/\.h\.in/.h-in/
+/^	\.\/temacs/i\
+	stubedit temacs.exe minstack=40k
+/^MAKE *=/s/^/# /
+/^SHELL *=/s/^/# /
+/^srcdir *=/s/@[^@\n]*@/./
+/^VPATH *=/s/@[^@\n]*@/./
+/^CC *=/s/@[^@\n]*@/gcc/
+/^CPP *=/s/@[^@\n]*@/gcc -e/
+/^CFLAGS *=/s/@[^@\n]*@/-O2 -g/
+/^LN_S *=/s/@[^@\n]*@/ln -s/
+/^M_FILE *=/s!@[^@\n]*@!m/intel386.h!
+/^S_FILE *=/s!@[^@\n]*@!s/msdos.h!
+/^@SET_MAKE@$/s/@SET_MAKE@//
+/^.\${libsrc}make-docfile.*>/s!make-docfile!make-docfile -o ../etc/DOC!
+/^.\${libsrc}make-doc/s!>.*$!!
+/^[ 	]*$/d
+/^temacs:/s/prefix-args//
+/^	#/d

--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/msdos/sed3v2.inp	Wed Apr 10 00:53:52 1996 +0000
@@ -0,0 +1,25 @@
+# -sed3v2.inp-------------------------------------------------------------
+# Configuration script for lib-src/makefile under DJGPP v2
+# ----------------------------------------------------------------------
+/^# DIST: /d
+/^SHELL *=/s/^/# /
+/^CC *=/s/=.*$/=gcc/
+# Actually, here we should patch in the exact version number, but only
+# [ce]tags uses it.  Don't pass it.  This is more update-resistant.
+/-DVERSION=/s/-DVERSION="\\"\${version}\\""//
+/^configname *=/s/=.*$/=msdos/
+/^archlibdir *=/s!=.*$!=/emacs/bin!
+/^bindir *=/s!=.*$!=/emacs/bin!
+/^libdir *=/s!=.*$!=/emacs/bin!
+/^srcdir *=/s!=.*$!=.!
+/^VPATH *=/s!=.*$!=.!
+/^CFLAGS *=/s!=.*$!=-O2 -g!
+/^C_SWITCH_SYSTEM *=/s!=.*$!=-DMSDOS!
+/^LOADLIBES *=/s!=.*$!=!
+/^ALLOCA *=/s!=.*$!=alloca.o!
+/^INSTALLABLES/s/emacsclient *//
+s!^	\./!	!
+/^UTILITIES=/s/ wakeup//
+/^UTILITIES=/s/ movemail//
+/^UTILITIES=/s/ emacsserver//
+/^UTILITIES=/s/ timer//