Mercurial > emacs

changeset 97080:7c116c0a454b

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
(dired-isearch-filenames): New user option. (dired-isearch-orig-success-function): New internal variable. (dired-isearch-filenames-setup, dired-isearch-filenames-end) (dired-isearch-success-function): New functions. (dired-isearch-filenames, dired-isearch-filenames-regexp): New commands.
author Juri Linkov <juri@jurta.org>
date Tue, 29 Jul 2008 14:42:35 +0000
parents 22b04404b5d5
children 301f811043c1
files lisp/dired-aux.el
diffstat 1 files changed, 48 insertions(+), 0 deletions(-) [+]
line wrap: on
line diff
--- a/lisp/dired-aux.el	Tue Jul 29 14:42:07 2008 +0000
+++ b/lisp/dired-aux.el	Tue Jul 29 14:42:35 2008 +0000
@@ -2279,6 +2279,54 @@
 ;;;###end dired-ins.el
 
 
+;; Search only in file names in the Dired buffer.
+
+(defcustom dired-isearch-filenames nil
+  "*If non-nil, Isearch in Dired matches only file names."
+  :type '(choice (const :tag "No restrictions" nil)
+		 (const :tag "Isearch only in file names" dired-filename))
+  :group 'dired
+  :version "23.1")
+
+(defvar dired-isearch-orig-success-function nil)
+
+(defun dired-isearch-filenames-setup ()
+  "Set up isearch to search in Dired file names.
+Intended to be added to `isearch-mode-hook'."
+  (when dired-isearch-filenames
+    (setq dired-isearch-orig-success-function
+	  (default-value 'isearch-success-function))
+    (setq-default isearch-success-function 'dired-isearch-success-function)
+    (add-hook 'isearch-mode-end-hook 'dired-isearch-filenames-end nil t)))
+
+(defun dired-isearch-filenames-end ()
+  "Clean up the Dired file name search after terminating isearch."
+  (setq-default isearch-success-function dired-isearch-orig-success-function)
+  (remove-hook 'isearch-mode-end-hook 'dired-isearch-filenames-end t))
+
+(defun dired-isearch-success-function (beg end)
+  "Match only at visible regions with the text property `dired-filename'."
+  (and (isearch-success-function-default beg end)
+       (if dired-isearch-filenames
+	   (text-property-not-all (min beg end) (max beg end)
+				  'dired-filename nil)
+	 t)))
+
+;;;###autoload
+(defun dired-isearch-filenames ()
+  "Search for a string using Isearch only in file names in the Dired buffer."
+  (interactive)
+  (let ((dired-isearch-filenames t))
+    (isearch-forward)))
+
+;;;###autoload
+(defun dired-isearch-filenames-regexp ()
+  "Search for a regexp using Isearch only in file names in the Dired buffer."
+  (interactive)
+  (let ((dired-isearch-filenames t))
+    (isearch-forward-regexp)))
+
+
 ;; Functions for searching in tags style among marked files.
 
 ;;;###autoload