Mercurial > libavcodec.hg
comparison bfin/vp3_idct_bfin.S @ 5776:73ec16dbcbc1 libavcodec
blackfin optimized vp3 transform and infastructure for idct
author | mhoffman |
---|---|
date | Thu, 04 Oct 2007 20:47:12 +0000 |
parents | |
children | 78aa57eba353 |
comparison
equal
deleted
inserted
replaced
5775:38f220befc32 | 5776:73ec16dbcbc1 |
---|---|
1 /* | |
2 * vp3_idct BlackFin | |
3 * | |
4 * Copyright (C) 2007 Marc Hoffman <marc.hoffman@analog.com> | |
5 * | |
6 * This file is part of FFmpeg. | |
7 * | |
8 * FFmpeg is free software; you can redistribute it and/or | |
9 * modify it under the terms of the GNU Lesser General Public | |
10 * License as published by the Free Software Foundation; either | |
11 * version 2.1 of the License, or (at your option) any later version. | |
12 * | |
13 * FFmpeg is distributed in the hope that it will be useful, | |
14 * but WITHOUT ANY WARRANTY; without even the implied warranty of | |
15 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU | |
16 * Lesser General Public License for more details. | |
17 * | |
18 * You should have received a copy of the GNU Lesser General Public | |
19 * License along with FFmpeg; if not, write to the Free Software | |
20 * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA | |
21 */ | |
22 /* | |
23 This blackfin DSP code implements an 8x8 inverse type II DCT. | |
24 | |
25 Prototype : void ff_bfin_vp3_idct(DCTELEM *in) | |
26 | |
27 Registers Used : A0, A1, R0-R7, I0-I3, B0, B2, B3, M0-M2, L0-L3, P0-P5, LC0. | |
28 | |
29 */ | |
30 | |
31 #include "config_bfin.h" | |
32 | |
33 .section .l1.data.B,"aw",@progbits | |
34 | |
35 .align 4; | |
36 coefs: | |
37 .short 0x5a82; // C4 | |
38 .short 0x5a82; // C4 | |
39 .short 0x30FC; //cos(3pi/8) C6 | |
40 .short 0x7642; //cos(pi/8) C2 | |
41 .short 0x18F9; //cos(7pi/16) | |
42 .short 0x7D8A; //cos(pi/16) | |
43 .short 0x471D; //cos(5pi/16) | |
44 .short 0x6A6E; //cos(3pi/16) | |
45 .short 0x18F9; //cos(7pi/16) | |
46 .short 0x7D8A; //cos(pi/16) | |
47 | |
48 .section .l1.data.A | |
49 | |
50 vtmp: .space 256 | |
51 | |
52 #define TMP0 FP-8 | |
53 #define TMP1 FP-12 | |
54 #define TMP2 FP-16 | |
55 | |
56 | |
57 DEFUN(vp3_idct,mL1, | |
58 (DCTELEM *block)): | |
59 | |
60 /********************** Function Prologue *********************************/ | |
61 link 16; | |
62 [--SP] = (R7:4, P5:3); // Push the registers onto the stack. | |
63 B0 = R0; // Pointer to Input matrix | |
64 R1 = [P3+coefs@GOT17M4]; // Pointer to Coefficients | |
65 R2 = [P3+vtmp@GOT17M4]; // Pointer to Temporary matrix | |
66 B3 = R1; | |
67 B2 = R2; | |
68 L3 = 20; // L3 is used for making the coefficient array | |
69 // circular. | |
70 // MUST BE RESTORED TO ZERO at function exit. | |
71 M1 = 16 (X); // All these registers are initialized for | |
72 M3 = 8(X); // modifying address offsets. | |
73 | |
74 I0 = B0; // I0 points to Input Element (0, 0). | |
75 I2 = B0; // I2 points to Input Element (0, 0). | |
76 I2 += M3 || R0.H = W[I0]; | |
77 // Element 0 is read into R0.H | |
78 I1 = I2; // I1 points to input Element (0, 6). | |
79 I1 += 4 || R0.L = W[I2++]; | |
80 // I2 points to input Element (0, 4). | |
81 // Element 4 is read into R0.L. | |
82 P2 = 8 (X); | |
83 P3 = 32 (X); | |
84 P4 = -32 (X); | |
85 P5 = 98 (X); | |
86 R7 = 0x8000(Z); | |
87 I3 = B3; // I3 points to Coefficients | |
88 P0 = B2; // P0 points to array Element (0, 0) of temp | |
89 P1 = B2; | |
90 R7 = [I3++] || [TMP2]=R7; // Coefficient C4 is read into R7.H and R7.L. | |
91 MNOP; | |
92 NOP; | |
93 | |
94 /* | |
95 * A1 = Y0 * cos(pi/4) | |
96 * A0 = Y0 * cos(pi/4) | |
97 * A1 = A1 + Y4 * cos(pi/4) | |
98 * A0 = A0 - Y4 * cos(pi/4) | |
99 * load: | |
100 * R1=(Y2,Y6) | |
101 * R7=(C2,C6) | |
102 * res: | |
103 * R3=Y0, R2=Y4 | |
104 */ | |
105 A1=R7.H*R0.H, A0=R7.H*R0.H (IS) || I0+= 4 || R1.L=W[I1++]; | |
106 R3=(A1+=R7.H*R0.L), R2=(A0-=R7.H*R0.L) (IS) || R1.H=W[I0--] || R7=[I3++]; | |
107 | |
108 LSETUP (.0, .1) LC0 = P2; // perform 8 1d idcts | |
109 | |
110 P2 = 112 (X); | |
111 P1 = P1 + P2; // P1 points to element (7, 0) of temp buffer. | |
112 P2 = -94(X); | |
113 | |
114 .0: | |
115 /* | |
116 * A1 = Y2 * cos(3pi/8) | |
117 * A0 = Y2 * cos(pi/8) | |
118 * A1 = A1 - Y6 * cos(pi/8) | |
119 * A0 = A0 + Y6 * cos(3pi/8) | |
120 * R5 = (Y1,Y7) | |
121 * R7 = (C1,C7) | |
122 * res: | |
123 * R1=Y2, R0=Y6 | |
124 */ | |
125 A1=R7.L*R1.H, A0=R7.H*R1.H (IS) || I0+=4 || R5.H=W[I0]; | |
126 R1=(A1-=R7.H*R1.L), R0=(A0+=R7.L*R1.L) (IS) || R5.L=W[I1--] || R7=[I3++]; | |
127 /* | |
128 * Y0 = Y0 + Y6. | |
129 * Y4 = Y4 + Y2. | |
130 * Y2 = Y4 - Y2. | |
131 * Y6 = Y0 - Y6. | |
132 * R3 is saved | |
133 * R6.l=Y3 | |
134 * note: R3: Y0, R2: Y4, R1: Y2, R0: Y6 | |
135 */ | |
136 R3=R3+R0, R0=R3-R0; | |
137 R2=R2+R1, R1=R2-R1 || [TMP0]=R3 || R6.L=W[I0--]; | |
138 /* | |
139 * Compute the odd portion (1,3,5,7) even is done. | |
140 * | |
141 * Y1 = C7 * Y1 - C1 * Y7 + C3 * Y5 - C5 * Y3. | |
142 * Y7 = C1 * Y1 + C7 * Y7 + C5 * Y5 + C3 * Y3. | |
143 * Y5 = C5 * Y1 + C3 * Y7 + C7 * Y5 - C1 * Y3. | |
144 * Y3 = C3 * Y1 - C5 * Y7 - C1 * Y5 - C7 * Y3. | |
145 */ | |
146 // R5=(Y1,Y7) R6=(Y5,Y3) // R7=(C1,C7) | |
147 A1 =R7.L*R5.H, A0 =R7.H*R5.H (IS) || [TMP1]=R2 || R6.H=W[I2--]; | |
148 A1-=R7.H*R5.L, A0+=R7.L*R5.L (IS) || I0-=4 || R7=[I3++]; | |
149 A1+=R7.H*R6.H, A0+=R7.L*R6.H (IS) || I0+=M1; // R7=(C3,C5) | |
150 R3 =(A1-=R7.L*R6.L), R2 =(A0+=R7.H*R6.L) (IS); | |
151 A1 =R7.L*R5.H, A0 =R7.H*R5.H (IS) || R4=[TMP0]; | |
152 A1+=R7.H*R5.L, A0-=R7.L*R5.L (IS) || I1+=M1 || R7=[I3++]; // R7=(C1,C7) | |
153 A1+=R7.L*R6.H, A0-=R7.H*R6.H (IS); | |
154 R7 =(A1-=R7.H*R6.L), R6 =(A0-=R7.L*R6.L) (IS) || I2+=M1; | |
155 // R3=Y1, R2=Y7, R7=Y5, R6=Y3 | |
156 | |
157 /* Transpose write column. */ | |
158 R5.H=R4+R2 (RND12); // Y0=Y0+Y7 | |
159 R5.L=R4-R2 (RND12) || R4 = [TMP1]; // Y7=Y7-Y0 | |
160 R2.H=R1+R7 (RND12) || W[P0++P3]=R5.H; // Y2=Y2+Y5 st Y0 | |
161 R2.L=R1-R7 (RND12) || W[P1++P4]=R5.L || R7=[I3++]; // Y5=Y2-Y5 st Y7 | |
162 R5.H=R0-R3 (RND12) || W[P0++P3]=R2.H || R1.L=W[I1++]; // Y1=Y6-Y1 st Y2 | |
163 R5.L=R0+R3 (RND12) || W[P1++P4]=R2.L || R0.H=W[I0++]; // Y6=Y6+Y1 st Y5 | |
164 R3.H=R4-R6 (RND12) || W[P0++P3]=R5.H || R0.L=W[I2++]; // Y3=Y3-Y4 st Y1 | |
165 R3.L=R4+R6 (RND12) || W[P1++P4]=R5.L || R1.H=W[I0++]; // Y4=Y3+Y4 st Y6 | |
166 | |
167 /* pipeline loop start, + drain Y3, Y4 */ | |
168 A1=R7.H*R0.H, A0=R7.H*R0.H (IS) || W[P0++P2]= R3.H || R1.H = W[I0--]; | |
169 .1: R3=(A1+=R7.H*R0.L), R2=(A0-=R7.H*R0.L) (IS) || W[P1++P5]= R3.L || R7 = [I3++]; | |
170 | |
171 | |
172 | |
173 I0 = B2; // I0 points to Input Element (0, 0) | |
174 I2 = B2; // I2 points to Input Element (0, 0) | |
175 I2 += M3 || R0.H = W[I0]; | |
176 // Y0 is read in R0.H | |
177 I1 = I2; // I1 points to input Element (0, 6) | |
178 I1 += 4 || R0.L = W[I2++]; | |
179 // I2 points to input Element (0, 4) | |
180 // Y4 is read in R0.L | |
181 P2 = 8 (X); | |
182 I3 = B3; // I3 points to Coefficients | |
183 P0 = B0; // P0 points to array Element (0, 0) for writing | |
184 // output | |
185 P1 = B0; | |
186 R7 = [I3++]; // R7.H = C4 and R7.L = C4 | |
187 NOP; | |
188 | |
189 /* | |
190 * A1 = Y0 * cos(pi/4) | |
191 * A0 = Y0 * cos(pi/4) | |
192 * A1 = A1 + Y4 * cos(pi/4) | |
193 * A0 = A0 - Y4 * cos(pi/4) | |
194 * load: | |
195 * R1=(Y2,Y6) | |
196 * R7=(C2,C6) | |
197 * res: | |
198 * R3=Y0, R2=Y4 | |
199 */ | |
200 A1=R7.H*R0.H, A0=R7.H*R0.H (IS) || I0+=4 || R1.L=W[I1++]; | |
201 R3=(A1+=R7.H*R0.L), R2=(A0-=R7.H*R0.L) (IS) || R1.H=W[I0--] || R7=[I3++]; | |
202 | |
203 LSETUP (.2, .3) LC0 = P2; // peform 8 1d idcts | |
204 P2 = 112 (X); | |
205 P1 = P1 + P2; | |
206 P2 = -94(X); | |
207 | |
208 .2: | |
209 /* | |
210 * A1 = Y2 * cos(3pi/8) | |
211 * A0 = Y2 * cos(pi/8) | |
212 * A1 = A1 - Y6 * cos(pi/8) | |
213 * A0 = A0 + Y6 * cos(3pi/8) | |
214 * R5 = (Y1,Y7) | |
215 * R7 = (C1,C7) | |
216 * res: | |
217 * R1=Y2, R0=Y6 | |
218 */ | |
219 A1=R7.L*R1.H, A0=R7.H*R1.H (IS) || I0+=4 || R5.H=W[I0]; | |
220 R1=(A1-=R7.H*R1.L), R0=(A0+=R7.L*R1.L) (IS) || R5.L=W[I1--] || R7=[I3++]; | |
221 /* | |
222 * Y0 = Y0 + Y6. | |
223 * Y4 = Y4 + Y2. | |
224 * Y2 = Y4 - Y2. | |
225 * Y6 = Y0 - Y6. | |
226 * R3 is saved | |
227 * R6.l=Y3 | |
228 * note: R3: Y0, R2: Y4, R1: Y2, R0: Y6 | |
229 */ | |
230 R3=R3+R0, R0=R3-R0; | |
231 R2=R2+R1, R1=R2-R1 || [TMP0]=R3 || R6.L=W[I0--]; | |
232 /* | |
233 * Compute the odd portion (1,3,5,7) even is done. | |
234 * | |
235 * Y1 = C7 * Y1 - C1 * Y7 + C3 * Y5 - C5 * Y3. | |
236 * Y7 = C1 * Y1 + C7 * Y7 + C5 * Y5 + C3 * Y3. | |
237 * Y5 = C5 * Y1 + C3 * Y7 + C7 * Y5 - C1 * Y3. | |
238 * Y3 = C3 * Y1 - C5 * Y7 - C1 * Y5 - C7 * Y3. | |
239 */ | |
240 // R5=(Y1,Y7) R6=(Y5,Y3) // R7=(C1,C7) | |
241 A1 =R7.L*R5.H, A0 =R7.H*R5.H (IS) || [TMP1]=R2 || R6.H=W[I2--]; | |
242 A1-=R7.H*R5.L, A0+=R7.L*R5.L (IS) || I0-=4 || R7=[I3++]; | |
243 A1+=R7.H*R6.H, A0+=R7.L*R6.H (IS) || I0+=M1; // R7=(C3,C5) | |
244 R3 =(A1-=R7.L*R6.L), R2 =(A0+=R7.H*R6.L) (IS); | |
245 A1 =R7.L*R5.H, A0 =R7.H*R5.H (IS) || R4=[TMP0]; | |
246 A1+=R7.H*R5.L, A0-=R7.L*R5.L (IS) || I1+=M1 || R7=[I3++]; // R7=(C1,C7) | |
247 A1+=R7.L*R6.H, A0-=R7.H*R6.H (IS); | |
248 R7 =(A1-=R7.H*R6.L), R6 =(A0-=R7.L*R6.L) (IS) || I2+=M1; | |
249 // R3=Y1, R2=Y7, R7=Y5, R6=Y3 | |
250 | |
251 /* Transpose write column. */ | |
252 R5.H=R4+R2 (RND20); // Y0=Y0+Y7 | |
253 R5.L=R4-R2 (RND20) || R4 = [TMP1]; // Y7=Y7-Y0 | |
254 R5=R5>>>2(v); | |
255 R2.H=R1+R7 (RND20) || W[P0++P3]=R5.H; // Y2=Y2+Y5 st Y0 | |
256 R2.L=R1-R7 (RND20) || W[P1++P4]=R5.L || R7=[I3++]; // Y5=Y2-Y5 st Y7 | |
257 R2=R2>>>2(v); | |
258 R5.H=R0-R3 (RND20) || W[P0++P3]=R2.H || R1.L=W[I1++]; // Y1=Y6-Y1 st Y2 | |
259 R5.L=R0+R3 (RND20) || W[P1++P4]=R2.L || R0.H=W[I0++]; // Y6=Y6+Y1 st Y5 | |
260 R5=R5>>>2(v); | |
261 R3.H=R4-R6 (RND20) || W[P0++P3]=R5.H || R0.L=W[I2++]; // Y3=Y3-Y4 st Y1 | |
262 R3.L=R4+R6 (RND20) || W[P1++P4]=R5.L || R1.H=W[I0++]; // Y4=Y3+Y4 st Y6 | |
263 R3=R3>>>2(v); | |
264 /* pipeline loop start, + drain Y3, Y4 */ | |
265 A1=R7.H*R0.H, A0=R7.H*R0.H (IS) || W[P0++P2]= R3.H || R1.H = W[I0--]; | |
266 .3: R3=(A1+=R7.H*R0.L), R2=(A0-=R7.H*R0.L) (IS) || W[P1++P5]= R3.L || R7 = [I3++]; | |
267 | |
268 L3 = 0; | |
269 (R7:4,P5:3)=[SP++]; | |
270 unlink; | |
271 RTS; | |
272 DEFUN_END(vp3_idct) | |
273 | |
274 |