# HG changeset patch
# User Gary Kramlich <grim@reaperworld.com>
# Date 1122150497 0
# Node ID 616feca04ada9751c2c364b32137b838f7dc85d2
# Parent  1c5398ccbeb032b29bd7dca4c506f93544ba8c52
[gaim-migrate @ 13226]
I started this a long time ago, and decided to finish it.  This adds a AM_PATH_GAIM macro to aclocal.  Very useful for plugin developers.  It works alright so far, but isn't tolerant of an non major.minor.micro version being passed to it.  I'm still considering moving the meat of this to a compile test, but this will do it for now.

committer: Tailor Script <tailor@pidgin.im>

diff -r 1c5398ccbeb0 -r 616feca04ada Makefile.am
--- a/Makefile.am	Fri Jul 22 19:47:29 2005 +0000
+++ b/Makefile.am	Sat Jul 23 20:28:17 2005 +0000
@@ -38,7 +38,7 @@
 appsdir = $(datadir)/applications
 apps_DATA = gaim.desktop
 
-SUBDIRS = doc intl pixmaps plugins po sounds src
+SUBDIRS = doc intl m4macros pixmaps plugins po sounds src
 
 docs: Doxyfile
 if HAVE_DOXYGEN
diff -r 1c5398ccbeb0 -r 616feca04ada configure.ac
--- a/configure.ac	Fri Jul 22 19:47:29 2005 +0000
+++ b/configure.ac	Sat Jul 23 20:28:17 2005 +0000
@@ -1282,6 +1282,7 @@
 		   doc/gaim.1
 		   doc/gaim-remote.1
 		   intl/Makefile
+		   m4macros/Makefile
 		   pixmaps/Makefile
 		   pixmaps/smileys/Makefile
 		   pixmaps/smileys/default/Makefile
diff -r 1c5398ccbeb0 -r 616feca04ada m4macros/.cvsignore
--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/m4macros/.cvsignore	Sat Jul 23 20:28:17 2005 +0000
@@ -0,0 +1,2 @@
+Makefile
+Makefile.in
diff -r 1c5398ccbeb0 -r 616feca04ada m4macros/Makefile.am
--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/m4macros/Makefile.am	Sat Jul 23 20:28:17 2005 +0000
@@ -0,0 +1,6 @@
+installed_m4=gaim.m4
+
+EXTRA_DIT=$(installed_m4)
+
+m4datadir=$(datadir)/aclocal
+m4data_DATA=$(installed_m4)
diff -r 1c5398ccbeb0 -r 616feca04ada m4macros/gaim.m4
--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/m4macros/gaim.m4	Sat Jul 23 20:28:17 2005 +0000
@@ -0,0 +1,102 @@
+dnl ###########################################################################
+dnl # Configure paths for Gaim
+dnl # Gary Kramlich 2005
+dnl #
+dnl # Based off of glib-2.0.m4 by Owen Taylor
+dnl ###########################################################################
+
+dnl ###########################################################################
+dnl # AM_PATH_GAIM([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
+dnl #
+dnl # Test for gaim and define GAIM_CFLAGS, GAIM_LIBS, GAIM_DATADIR, and
+dnl # GAIM_LIBDIR
+dnl ###########################################################################
+AC_DEFUN([AM_PATH_GAIM],
+[dnl
+	AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
+
+	no_gaim=""
+
+	if test x"$PKG_CONFIG" != x"no" ; then
+		if $PKG_CONFIG --atleast-pkgconfig-version 0.7 ; then
+			:
+		else
+			echo "*** pkg-config is too old;  version 0.7 or newer is required."
+			no_gaim="yes"
+			PKG_CONFIG="no"
+		fi
+	else
+		no_gaim="yes"
+	fi
+
+	min_version=ifelse([$1], ,2.0.0,$1)
+	found_version=""
+	
+	AC_MSG_CHECKING(for gaim - version >= $min_version)
+
+	if test x"$no_gaim" = x"" ; then
+		GAIM_DATADIR=`$PKG_CONFIG --variable=datadir gaim`
+		GAIM_LIBDIR=`$PKG_CONFIG --variable=libdir gaim`
+
+		GAIM_CFLAGS=`$PKG_CONFIG --cflags gaim`
+		GAIM_LIBS=`$PKG_CONFIG --libs gaim`
+
+		gaim_version=`$PKG_CONFIG --modversion gaim`
+		gaim_major_version=`echo $gaim_version | cut -d. -f 1`
+		gaim_minor_version=`echo $gaim_version | cut -d. -f 2`
+		
+		dnl # stash the micro version in a temp variable.  Then stash
+		dnl # the numeric for it in gaim_micro_version and anything
+		dnl # else in gaim_extra_version.
+		gaim_micro_version_temp=`echo $gaim_version | cut -d. -f 3`
+		gaim_micro_version=`echo $gaim_micro_version_temp | sed 's/[[^0-9]]//g'`
+		gaim_extra_version=`echo $gaim_micro_version_temp | sed 's/[[0-9]]//g'`
+
+		dnl # get the major, minor, and macro that the user gave us
+		min_major_version=`echo $min_version | cut -d. -f 1`
+		min_minor_version=`echo $min_version | cut -d. -f 2`
+		min_micro_version=`echo $min_version | cut -d. -f 3`
+
+		dnl # check the users version against the version from pkg-config
+		if test $gaim_major_version -eq $min_major_version -a \
+			$gaim_minor_version -ge $min_minor_version -a \
+			$gaim_micro_version -ge $min_micro_version
+		then
+			:
+		else
+			no_gaim="yes"
+			found_version="$gaim_major_version.$gaim_minor_version.$gaim_micro_version$gaim_extra_version"
+		fi
+
+		dnl # Do we want a compile test here?
+	fi
+
+	if test x"$no_gaim" = x"" ; then
+		AC_MSG_RESULT(yes (version $gaim_major_version.$gaim_minor_version.$gaim_micro_version$gaim_extra_version))
+		ifelse([$2], , :, [$2])
+	else
+		AC_MSG_RESULT(no)
+		if test x"$PKG_CONFIG" = x"no" ; then
+			echo "*** A new enough version of pkg-config was not found."
+			echo "*** See http://www.freedesktop.org/software/pkgconfig/"
+		fi
+
+		if test x"found_version" != x"" ; then
+			echo "*** A new enough version of gaim was not found."
+			echo "*** You have version $found_version"
+			echo "*** See http://gaim.sf.net/"
+		fi
+		
+		GAIM_CFLAGS=""
+		GAIM_LIBS=""
+		GAIM_DATADIR=""
+		GAIM_LIBDIR=""
+
+		ifelse([$3], , :, [$3])
+	fi
+
+	AC_SUBST(GAIM_CFLAGS)
+	AC_SUBST(GAIM_LIBS)
+	AC_SUBST(GAIM_DATADIR)
+	AC_SUBST(GAIM_LIBDIR)
+])