Mercurial > pidgin

diff m4/ac_var_timezone_externals.m4 @ 3194:fdd20785e1e1

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
[gaim-migrate @ 3211] jabber.c Repaired iso8601_to_time() to work properly for HAVE_TIMEZONE. (jseymour) Removed signon time code as it didn't produce the desired results (faceprint). configure.ac configure.in Added AC_VAR_TIMEZONE_EXTERNALS macro for HAVE_TIMEZONE, HAVE_ALTZONE and HAVE_DAYLIGHT defines. (jseymour) Fixed socklen_t (fingolfin) c_var_timezone_externals.m4 Added file. (jseymour) committer: Tailor Script <tailor@pidgin.im>
author Jim Seymour <jseymour>
date Fri, 03 May 2002 01:09:49 +0000
parents
children 75912ec1a1cb
line wrap: on
line diff
--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/m4/ac_var_timezone_externals.m4	Fri May 03 01:09:49 2002 +0000
@@ -0,0 +1,38 @@
+
+# Define 'timezone', 'altzone' and 'daylight'
+# http://www.gnu.org/software/ac-archive/Miscellaneous/ac_var_timezone_externals.html
+# Use instead of `AC_STRUCT_TIMEZONE' to determine whether the
+# the external timezone variables `timezone', `altzone' and `daylight' exist,
+# defining `HAVE_TIMEZONE', `HAVE_ALTZONE' and `HAVE_DAYLIGHT' respectively
+# (as well as gaining the macros defined by `AC_STRUCT_TIMEZONE').
+# Mark R.Bannister <markb@freedomware.co.uk>
+AC_DEFUN([AC_VAR_TIMEZONE_EXTERNALS],
+[  AC_REQUIRE([AC_STRUCT_TIMEZONE])dnl
+   AC_CACHE_CHECK(for timezone external, mb_cv_var_timezone,
+   [  AC_TRY_LINK([#include <time.h>], [return (int)timezone;],
+         mb_cv_var_timezone=yes,
+         mb_cv_var_timezone=no)
+   ])
+   AC_CACHE_CHECK(for altzone external, mb_cv_var_altzone,
+   [  AC_TRY_LINK([#include <time.h>], [return (int)altzone;],
+         mb_cv_var_altzone=yes,
+         mb_cv_var_altzone=no)
+   ])
+   AC_CACHE_CHECK(for daylight external, mb_cv_var_daylight,
+   [  AC_TRY_LINK([#include <time.h>], [return (int)daylight;],
+         mb_cv_var_daylight=yes,
+         mb_cv_var_daylight=no)
+   ])
+   if test $mb_cv_var_timezone = yes; then
+      AC_DEFINE([HAVE_TIMEZONE], 1,
+              [Define if you have the external `timezone' variable.])
+   fi
+   if test $mb_cv_var_altzone = yes; then
+      AC_DEFINE([HAVE_ALTZONE], 1,
+              [Define if you have the external `altzone' variable.])
+   fi
+   if test $mb_cv_var_daylight = yes; then
+      AC_DEFINE([HAVE_DAYLIGHT], 1,
+              [Define if you have the external `daylight' variable.])
+   fi
+])